I_CNSLDTNADDLMD

@AbapCatalog: {
  sqlViewName: 'ICCADDLMD',
  preserveKey:true,
  compiler.compareFilter: true
  }

@AccessControl.authorizationCheck: #PRIVILEGED_ONLY
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true

@ObjectModel:{
  usageType: {
    dataClass: #MASTER,
    serviceQuality: #A,
    sizeCategory: #L},
  representativeKey: 'CnsldtnAddlMstrDataUUID'
}
@VDM:{
  viewType: #BASIC
  }
@EndUserText.label: 'Consolidation Additional Master Data'

define view I_CnsldtnAddlMD
  as select from fincs_addlmd     as _Source

//    inner join   fincs_addlcharcx as _Configuration on _Source.cnsldtnaddlcharcuuid = hextobin(

//      _Configuration.cnsldtnaddlcharcuuid

//    )  

      
    inner join   fincs_addlcharcx as _Configuration on _Configuration.cnsldtnaddlcharcuuid = bintohex(
      _Source.cnsldtnaddlcharcuuid        
    )

  association [0..*] to I_CnsldtnAddlMDT as _Text on $projection.CnsldtnAddlMstrDataUUID = _Text.CnsldtnAddlMstrDataUUID

{

      @ObjectModel.text.association: '_Text'
  key _Source.cnsldtnaddlmstrdatauuid                                      as CnsldtnAddlMstrDataUUID,

      _Source.cnsldtnaddlmstrdatauuid                                      as AdditionalMasterDataUUID,

      _Source.cnsldtnaddlcharcuuid                                         as AdditionalCharacteristicUUID,

      _Configuration.cnsldtnaddlcharcfldname                               as AdditionalCharcFieldName,

      _Source.additionalmasterdatacode                                     as AdditionalMasterDataCode,

      _Source.additionalmdsuprordfieldvalue                                as AdditionalMDSuprordFieldValue,

      _Text[1: Language=$session.system_language].AdditionalMasterDataText as AdditionalMasterDataText,

      @Semantics.systemDateTime.createdAt
      _Source.creationdatetime                                             as CreationDateTime,

      _Text
}