I_CLRGINFORELATIONFORACCTGDOC

CDS View

Clearing Information for Accounting

I_CLRGINFORELATIONFORACCTGDOC is a CDS View in S/4HANA. Clearing Information for Accounting. It contains 11 fields. 17 CDS views read from this table.

Used by 17 CDS view(s) 11 fields

CDS Views using this table (17)

ViewTypeJoinVDMDescription
C_EG_ClrgReferenceDocumentType view from CONSUMPTION Clearing Information for Accounting Egypt
C_MX_JrnlEntrWithRelatedDocsLg view inner CONSUMPTION Audit Trail in Journal Entries Report
C_PT_SAFTPaymentDocValueC view_entity inner CONSUMPTION Total Amount of Payment Document - Cube
C_PT_SAFTPaymentOrderRefer view_entity inner CONSUMPTION Originating Document of the Payment
C_PT_SAFTPaytDocHeaderCube view_entity inner CONSUMPTION Payment Header for SAFT PT - Cube
C_QA_ClrgReferenceDocumentType view from CONSUMPTION Clearing Reference Document Type
I_PT_SAFTBillgPaytCust view_entity inner COMPOSITE Customer from Payment Document
I_PT_SAFTPaymentHeader view inner COMPOSITE SAF-T PT Payment Header
I_PT_SAFTPaymentItem view inner COMPOSITE SAF-T PT Payment Item
P_AR_SuplrPaymentPartialFull view_entity inner CONSUMPTION Argentina Supplier Payment - Partial & Full Payments
P_PT_PAYORGON view from COMPOSITE Private Payment Org On
P_PT_PAYORGON view left_outer COMPOSITE Private Payment Org On
P_PT_SAFTPAYMENTLINE view_entity inner COMPOSITE Payment Lines for SAF-T PT
P_RU_BusPartnerClearing view from CONSUMPTION Business Partner Clearing
P_RU_DownPaymentClearing view from CONSUMPTION Down Payment Clearing
P_SK_StRpVATCSClearingInfo view from COMPOSITE SK VAT Control Statement Clearing Info
P_SK_StRpVATCSClearingInfo view inner COMPOSITE SK VAT Control Statement Clearing Info

Fields (11)

KeyField CDS FieldsUsed in Views
KEY AccountingDocument AccountingDocument,DownPayment 4
KEY AccountingDocumentItem DownPaymentItem,RelatedDocumentItemNumber 2
KEY ClearingAccountingDocument ClearingAccountingDocument 3
KEY ClearingFiscalYear ClearingFiscalYear,FiscalYear 3
KEY ClearingInfoCompanyCode ClearingCompanyCode,ClearingInfoCompanyCode 3
KEY ClearingInformationIndex ClearingInformationIndex,DocumentItemNumber 6
KEY CompanyCode CompanyCode,DownPaymentCompanyCode 2
CompanyCodeCurrency CompanyCurrency 2
DebitCreditCode DownPaymentDebitCreditCode 1
FiscalYear DownPaymentFiscalYear,FiscalYear 3
TransactionCurrency TransactionCurrency 2 
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #BASIC
@Analytics: {dataCategory: #DIMENSION, dataExtraction.enabled: true}
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.representativeKey: 'ClearingAccountingDocument'
@ObjectModel.compositionRoot: true
@AbapCatalog.buffering.status: #NOT_ALLOWED
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@AbapCatalog: {
  sqlViewName: 'ICLEARINGINFO',
  compiler.compareFilter: true
}
@EndUserText.label: 'Clearing Information for Accounting'
@Metadata.allowExtensions: true
@AbapCatalog.preserveKey: true
define view I_ClrgInfoRelationForAcctgDoc as select from bse_clr

  association [1..1] to I_CompanyCode as _ClearingInfoCompanyCode on $projection.ClearingInfoCompanyCode = _ClearingInfoCompanyCode.CompanyCode
  association [1..1] to I_CompanyCode as _CompanyCode    on $projection.CompanyCode    = _CompanyCode.CompanyCode
  
  association [0..1] to I_AccountingDocument as _ClearingDocument   on $projection.ClearingAccountingDocument = _ClearingDocument.AccountingDocument
                                                                   and $projection.ClearingInfoCompanyCode    = _ClearingDocument.CompanyCode
                                                                   and $projection.ClearingFiscalYear         = _ClearingDocument.FiscalYear
                                                              
// please do not use!  ...  is now deprecated ... is wrong if clearing document and original document are in different fiscal years ... please use new  _JournalEntry                                                                    

  association [0..1] to I_AccountingDocument as _AccountingDocument on $projection.AccountingDocument      = _AccountingDocument.AccountingDocument
                                                                   and $projection.ClearingInfoCompanyCode = _AccountingDocument.CompanyCode
                                                                   and $projection.ClearingFiscalYear      = _AccountingDocument.FiscalYear  
                                                                   
  association [0..1] to I_JournalEntry      as _JournalEntry       on  $projection.CompanyCode        = _JournalEntry.CompanyCode
                                                                   and $projection.FiscalYear         = _JournalEntry.FiscalYear
                                                                   and $projection.AccountingDocument = _JournalEntry.AccountingDocument                                                                                              
   
  association [0..1] to I_FiscalYearForCompanyCode as _ClearingFiscalYear on $projection.ClearingFiscalYear      = _ClearingFiscalYear.FiscalYear
                                                                        and $projection.ClearingInfoCompanyCode = _ClearingFiscalYear.CompanyCode
  association [0..1] to I_FiscalYearForCompanyCode as _FiscalYear    on $projection.FiscalYear              = _FiscalYear.FiscalYear
                                                                    and $projection.CompanyCode             = _FiscalYear.CompanyCode
  
  association [0..1] to I_Currency as _Currency       on $projection.companycodecurrency = _Currency.Currency
  
  association [0..1] to I_DebitCreditCode as _DebitCreditCode on $projection.DebitCreditCode = _DebitCreditCode.DebitCreditCode
                                                                 
  
{
  key bukrs_clr as ClearingInfoCompanyCode, 
  key belnr_clr as ClearingAccountingDocument,
  key gjahr_clr as ClearingFiscalYear, 
  key index_clr as ClearingInformationIndex,
  agzei as ClearingItem,
  agbuz as DownPaymentItem,
//  agbuz as SetLineNumber,  

  waers as TransactionCurrency, 
  clrin as ClearingInformationType, 
  bukrs as CompanyCode, 
  belnr as AccountingDocument, 
  gjahr as FiscalYear, 
  buzei as AccountingDocumentItem,
  shkzg as DebitCreditCode, 
  _ClearingDocument.CompanyCodeCurrency,
  _ClearingDocument.AdditionalCurrency1,
  _ClearingDocument.AdditionalCurrency2,
  
  @Semantics.amount.currencyCode: 'CompanyCodeCurrency' 
  dmbtr as AmountInCompanyCodeCurrency,
  @Semantics.amount.currencyCode: 'AdditionalCurrency1' 
  dmbe2 as AmountInAdditionalCurrency1, 
  @Semantics.amount.currencyCode: 'AdditionalCurrency2' 
  dmbe3 as AmountInAdditionalCurrency2, 
  @Semantics.amount.currencyCode: 'TransactionCurrency'
  wrbtr as AmountInTransactionCurrency, 
  @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
  difhw as DifferenceAmtInCoCodeCrcy,
  @Semantics.amount.currencyCode: 'AdditionalCurrency1'
  difh2 as DiffAmtInAdditionalCurrency1,
  @Semantics.amount.currencyCode: 'AdditionalCurrency2'
  difh3 as DiffAmtInAdditionalCurrency2,
  @Semantics.amount.currencyCode: 'TransactionCurrency'
  diffw as DifferenceAmtInTransCrcy,
  @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
  sknto as CashDiscountAmtInCoCodeCrcy, 
  @Semantics.amount.currencyCode: 'AdditionalCurrency1'
  sknt2 as CashDiscountAmtInAddlCrcy1, 
  @Semantics.amount.currencyCode: 'AdditionalCurrency2'
  sknt3 as CashDiscountAmtInAddlCrcy2,
  @Semantics.amount.currencyCode: 'TransactionCurrency'
  wskto as CashDiscountAmount,
  @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
  bdiff as ValuationDiffAmtInCoCodeCrcy,
  @Semantics.amount.currencyCode: 'AdditionalCurrency1'
  bdif2 as ValuationDiffAmtInAddlCrcy1, 
  @Semantics.amount.currencyCode: 'AdditionalCurrency2'
  bdif3 as ValuationDiffAmtInAddlCrcy2, 
  @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
  rdiff as ExchRateDiffAmtInCoCodeCrcy, 
  @Semantics.amount.currencyCode: 'AdditionalCurrency1'
  rdif2 as ExchRateDiffAmtInAddlCrcy1,
  @Semantics.amount.currencyCode: 'AdditionalCurrency2'
  rdif3 as ExchRateDiffAmtInAddlCrcy2,
  koart as AccountType, 
  umskz as SpecialGLCode,
  
  _ClearingInfoCompanyCode,
  _CompanyCode,
  _ClearingDocument,
@API.element.releaseState: #DEPRECATED
@API.element.successor:    '_JournalEntry'
@VDM.lifecycle.status:     #DEPRECATED
@VDM.lifecycle.successor:  '_JournalEntry'
  _AccountingDocument,
  _JournalEntry,
  _ClearingFiscalYear,
  _FiscalYear,
  _Currency,
  _DebitCreditCode
}

Learn More