I_CLOSINGTASKEXECUTIONGROUP
Closing Task Execution Group
I_CLOSINGTASKEXECUTIONGROUP is a CDS View in S/4HANA. Closing Task Execution Group. 2 CDS views read from this table.
CDS Views using this table (2)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| C_ClosingTaskExecutionGroup | view | from | CONSUMPTION | Closing Task Execution Group - Cons. View |
| I_ClsgTaskLatestExecutionGroup | view | from | COMPOSITE | Closing Task Latest Execution Group |
@AbapCatalog: {sqlViewName: 'ICLSGTASKEXECG', preserveKey: true}
@Analytics.dataCategory: #DIMENSION
@EndUserText.label: 'Closing Task Execution Group'
@VDM.viewType: #BASIC
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ObjectModel: { representativeKey: 'ClosingTaskExecutionGroupUUID',
usageType.serviceQuality: #A,
usageType.sizeCategory: #L,
usageType.dataClass: #MASTER }
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
define view I_ClosingTaskExecutionGroup
as select from fcco_group_exec
association [1..1] to I_ClosingTaskList as _ClosingTaskList on $projection.ClosingTemplate = _ClosingTaskList.ClosingTemplate
and $projection.ClosingTaskListInstance = _ClosingTaskList.ClosingTaskListInstance
and $projection.FinancialTaskListContextType = _ClosingTaskList.FinancialTaskListContextType
association [1..1] to I_ClosingTask as _ClosingTask on $projection.ClosingTemplate = _ClosingTask.ClosingTemplate
and $projection.ClosingTaskListInstance = _ClosingTask.ClosingTaskListInstance
and $projection.FinancialTaskListContextType = _ClosingTask.FinancialTaskListContextType
and $projection.ClosingTask = _ClosingTask.ClosingTask
association [1..1] to I_ClosingTemplate as _ClosingTemplate on $projection.ClosingTemplate = _ClosingTemplate.ClosingTemplate
and $projection.FinancialTaskListContextType = _ClosingTemplate.FinancialTaskListContextType
association [1..1] to I_FinTaskListContextType as _FinTaskListContextType on $projection.FinancialTaskListContextType = _FinTaskListContextType.FinancialTaskListContextType
association [0..*] to I_ClosingTaskExecution as _ClosingTaskExecution on $projection.ClosingTemplate = _ClosingTaskExecution.ClosingTemplate
and $projection.ClosingTaskListInstance = _ClosingTaskExecution.ClosingTaskListInstance
and $projection.FinancialTaskListContextType = _ClosingTaskExecution.FinancialTaskListContextType
and $projection.ClosingTask = _ClosingTaskExecution.ClosingTask
and $projection.ClosingTaskExecutionGroupUUID = _ClosingTaskExecution.ClosingTaskExecutionGroupUUID
{
@ObjectModel.foreignKey.association: '_ClosingTemplate'
key profile as ClosingTemplate,
@ObjectModel.foreignKey.association: '_ClosingTaskList'
key instance as ClosingTaskListInstance,
@ObjectModel.foreignKey.association: '_FinTaskListContextType'
key flavor as FinancialTaskListContextType,
@ObjectModel.foreignKey.association: '_ClosingTask'
key item as ClosingTask,
key exec_grp_uuid as ClosingTaskExecutionGroupUUID,
created_by as CreatedByUser,
created_on as CreationDateTime,
last_changed_by as LastChangedByUser,
last_changed_on as LastChangeDateTime,
life_cycle_status as ClosingTaskLifecycleStatus,
combined_status as ClosingTaskStatus,
duration as ApplJobDurationInSeconds,
btc_start_on as ApplicationJobStartDateTime,
btc_end_on as ApplicationJobEndDateTime,
text as ClsgTaskStatusChgReasonDesc,
manual_changed as ClsgTaskStatusIsChgdManually,
is_current as IsCurrentClosingTaskExecution,
is_testrun as IsApplicationJobTestRun,
btc_planned_start_on as ApplJobPlannedStartDateTime,
approval_text as ReviewComment,
num_of_executions as NumberOfClosingTaskExecutions,
@ObjectModel.association.type: [ #TO_COMPOSITION_ROOT ]
_ClosingTaskList,
_ClosingTemplate,
_FinTaskListContextType,
@ObjectModel.association.type: [ #TO_COMPOSITION_PARENT ]
_ClosingTask,
_ClosingTaskExecution
}