I_CLFNCLASSHIERCHARCFORKEYDATE

CDS View

Clfn Cl Hier Characteristic For Key Date

I_CLFNCLASSHIERCHARCFORKEYDATE is a CDS View in S/4HANA. Clfn Cl Hier Characteristic For Key Date. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
I_ClfnClassCharcForKeyDate view from COMPOSITE Charc of Clfn Class for Key Date 
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.sqlViewName: 'INGCCLS10'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Clfn Cl Hier Characteristic For Key Date'
@VDM.viewType: #COMPOSITE
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API

@ObjectModel.usageType.sizeCategory: #M
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.dataClass: #MASTER
define view I_ClfnClassHierCharcForKeyDate
  with parameters
    @Consumption.hidden: true
    @Environment.systemField: #SYSTEM_DATE
    P_KeyDate : sydate
  as select from I_ClfnClassSuperiorForKeyDate( P_KeyDate : $parameters.P_KeyDate )  as ClassSuperior
      inner join I_ClfnClassCharcBasic       as ClassCharcBasic
        on  ClassCharcBasic.ClassInternalID         = ClassSuperior.AncestorClassInternalID
  // use I_ClfnCharcBasic view

  //   - to filter out characteristic which are not valid on the given date and also

  //   - to keep the serviceQuality as good as possible

      inner join I_ClfnCharcBasic            as Characteristic
        on  Characteristic.CharcInternalID          = ClassCharcBasic.CharcInternalID

      association [0..1] to I_ClfnClass as _Class
        on $projection.ClassInternalID = _Class.ClassInternalID
{
  key ClassSuperior.ClassInternalID,
  key ClassSuperior.AncestorClassInternalID,
  key ClassCharcBasic.CharcInternalID,
      ClassCharcBasic.CharcPositionNumber,
      ClassSuperior.ClassType,
      ClassSuperior.Class,
      ClassSuperior.AncestorClass,
      ClassSuperior.ClassClassfctnAuthGrp,
      Characteristic.Characteristic,
      ClassCharcBasic.OverwrittenCharcInternalID,
      ClassCharcBasic.ClfnOrganizationalArea,
      ClassCharcBasic.ChangeNumber,
//      ClassCharcBasic.CharcCodeLetter,

      ClassCharcBasic.CharcOriginText,
//      ClassCharcBasic.CharcStandardCodeLetter,

      ClassCharcBasic.CharcIsPrintRelevant,
      ClassCharcBasic.CharcIsSearchRelevant,
      ClassCharcBasic.CharcIsDisplayRelevant,
      ClassCharcBasic.CharcIsProposalRelevant,
      ClassCharcBasic.CharcIsPrptnOrProdUnitRelevant,
      ClassCharcBasic.ValidityStartDate,
      ClassCharcBasic.ValidityEndDate,
      case when ClassSuperior.ClassInternalID = ClassCharcBasic.ClassInternalID
        then ''
        else 'X'
      end as CharcIsInherited,

      _Class
}
  where ClassCharcBasic.ValidityStartDate      <= $parameters.P_KeyDate
    and ClassCharcBasic.ValidityEndDate        >= $parameters.P_KeyDate
    and ClassCharcBasic.IsDeleted               =  ''
    and Characteristic.ValidityStartDate       <= $parameters.P_KeyDate
    and Characteristic.ValidityEndDate         >= $parameters.P_KeyDate
    and Characteristic.IsDeleted                =  ''

Learn More