I_CHGRECDREFCUTPLNGPRFLTP

CDS View

Change Recd Ref Cut Plan Profile - TP

I_CHGRECDREFCUTPLNGPRFLTP is a CDS View in S/4HANA. Change Recd Ref Cut Plan Profile - TP. It contains 3 fields. 1 CDS views read from this table.

Used by 1 CDS view(s) 3 fields

CDS Views using this table (1)

ViewTypeJoinVDMDescription
C_ChgRecdRefCutPlngPrfl view from CONSUMPTION Change Recrd Obj Cut Planning profile

Fields (3)

KeyField CDS FieldsUsed in Views
BillOfOperationsGroup BillOfOperationsGroup 1
BillOfOperationsType BillOfOperationsType 1
BillOfOperationsVariant BillOfOperationsVariant 1 
@AbapCatalog.sqlViewName: 'ICRREFCPPTP'
@AbapCatalog.compiler.compareFilter: true
@EndUserText.label: 'Change Recd Ref Cut Plan Profile - TP'
@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.viewType: #TRANSACTIONAL

@ObjectModel: { semanticKey: ['BillOfOperationsType','BillOfOperationsGroup','BillOfOperationsVariant'],
                writeDraftPersistence: 'PLMCRREFCPP_D',
                createEnabled,
                deleteEnabled,
                updateEnabled
              }
@AccessControl.personalData.blocking: #REQUIRED
@ObjectModel.usageType: {serviceQuality: #C,
                         dataClass: #MIXED,
                         sizeCategory: #L}
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.preserveKey:true
define view I_ChgRecdRefCutPlngPrflTP
  as select from           I_ChgRecdRefCutPlngPrflBsc as CutPlngPrflTaskListReference
    left outer to one join I_BillOfOperations         as CutPlngPrflTaskList on  CutPlngPrflTaskListReference.ChgRecRefInternalKey1 = CutPlngPrflTaskList.BillOfOperationsType
                                                                             and CutPlngPrflTaskListReference.ChgRecRefInternalKey2 = CutPlngPrflTaskList.BillOfOperationsGroup
                                                                             and CutPlngPrflTaskListReference.ChgRecRefInternalKey3 = CutPlngPrflTaskList.BillOfOperationsVariant

  association [1..1] to I_ChangeRecordDraftTP      as _ChangeRecordTP               on $projection.ChangeRecordUUID = _ChangeRecordTP.ChangeRecordUUID
  association [0..1] to E_ChgRecdRefCutPlngPrflBsc as _CutPlngPrflTaskListExtension on $projection.ChangeRecordReferenceUUID = _CutPlngPrflTaskListExtension.ChangeRecordReferenceUUID
{
  key   CutPlngPrflTaskListReference.ChangeRecordReferenceUUID,
        case
           when CutPlngPrflTaskList.BillOfOperationsType is null then cast(SUBSTRING( CutPlngPrflTaskListReference.ChangeRecordReference, 1, 1) as plnty)
           else cast(CutPlngPrflTaskList.BillOfOperationsType as plnty)
           end                          as BillOfOperationsType,

        @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
        case
        when CutPlngPrflTaskList.BillOfOperationsGroup is null then  cast(SUBSTRING( CutPlngPrflTaskListReference.ChangeRecordReference, 2, 9) as plnnr)
        else cast(CutPlngPrflTaskList.BillOfOperationsGroup as plnnr)
        end                             as BillOfOperationsGroup,

        @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
        case
         when CutPlngPrflTaskList.BillOfOperationsVariant is null then cast (SUBSTRING( CutPlngPrflTaskListReference.ChangeRecordReference, 10, 2) as plnal)
         else cast(CutPlngPrflTaskList.BillOfOperationsVariant as plnal)
         end                            as BillOfOperationsVariant,

        //  deprecated,should not be used

        cast ('00000000' as cim_count ) as BOOInternalVersionCounter,
        // deprecated,  should not be used

        cast ('00000000' as plantext )  as BillOfOperationsDesc,

        CutPlngPrflTaskListReference.ChangeRecordUUID,
        CutPlngPrflTaskListReference.ChangeRecordReferenceType,
        CutPlngPrflTaskListReference.ChangeRecordReferenceSubtype,
        CutPlngPrflTaskListReference.ChangeRecordRefObjectUUID,
        CutPlngPrflTaskListReference.ChangeRecordReference,
        CutPlngPrflTaskListReference.ParentChangeRecordRefUUID,
        CutPlngPrflTaskListReference.IsMainReference,
        ChgRecdReasonForChange,
        ExpdCompltnDte,
        ChgRecdAuthznGrpText,
        ChgRecdNmbrChgSts,

        @Semantics.user.createdBy: true
        @ObjectModel.readOnly: true
        CutPlngPrflTaskListReference.CreatedByUser,
        CutPlngPrflTaskListReference.CreationDateTime,
        @Semantics.user.lastChangedBy: true
        @ObjectModel.readOnly: true
        CutPlngPrflTaskListReference.LastChangedByUser,
        CutPlngPrflTaskListReference.LastChangeDateTime,
        @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
        CutPlngPrflTaskListReference.ChangeRecordItemRelevance,
        CutPlngPrflTaskListReference.ChangeRecordVirtualRefInd,
        @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
        CutPlngPrflTaskListReference.ChangeRecordItemProcgStatus,
        @ObjectModel.readOnly: true
        CutPlngPrflTaskListReference.ChgRecdCurrentItemProcgStatus,
        CutPlngPrflTaskListReference.ChangeNumber,
        @ObjectModel.readOnly: true
        CutPlngPrflTaskListReference.ChgRecdItmTgtSts,
        @ObjectModel.readOnly: true
        CutPlngPrflTaskListReference.ChgRecdItmDSgntr,
        @ObjectModel.association.type:  [ #TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT ]
        _ChangeRecordTP
}
where
     CutPlngPrflTaskList.BillOfOperationsType = '3'
  or CutPlngPrflTaskList.BillOfOperationsType is null

Learn More