I_CHEMICALBASICINFO

CDS View

Chemical Basic Information

I_CHEMICALBASICINFO is a CDS View in S/4HANA. Chemical Basic Information. It contains 1 fields. 2 CDS views read from this table.

Used by 2 CDS view(s) 1 fields

CDS Views using this table (2)

ViewTypeJoinVDMDescription
I_EHSSubject view inner COMPOSITE Subject
I_EHSSubjectText view inner COMPOSITE Subject text

Fields (1)

KeyField CDS FieldsUsed in Views
CASNumber CASNumber 1 
@EndUserText.label: 'Chemical Basic Information'
@Analytics: { dataCategory:#DIMENSION , dataExtraction.enabled:true }
@VDM.viewType: #BASIC
@ObjectModel.representativeKey: 'ChemicalBasicInfoUUID'
@AccessControl.authorizationCheck: #CHECK
@AbapCatalog.sqlViewName: 'ICHMBINFO'
@AbapCatalog.compiler.compareFilter: true


// Client handling by session 

@ClientHandling.algorithm: #SESSION_VARIABLE
                         
// used for BOBF Master Data Object

@ObjectModel.usageType:{ serviceQuality: #C,        // < 15 msec   

                         sizeCategory:  #L,         // < 10.000.000

                         dataClass: #MASTER } 
                         
@AbapCatalog.preserveKey:true     
@Metadata.allowExtensions:true                     
                                                  
define view I_ChemicalBasicInfo as select from ehfndd_chm_binfo

   association [0..1] to I_User             as _CreatedByUser     on $projection.CreatedByUser         = _CreatedByUser.UserID 
   association [0..1] to I_User             as _LastChangedByUser on $projection.LastChangedByUser     = _LastChangedByUser.UserID 
   association [0..*] to I_ChemicalNameText as _ChemicalName      on $projection.ChemicalBasicInfoUUID = _ChemicalName.ChemicalBasicInfoUUID
                                                                 and $projection.ChemicalUUID          = _ChemicalName.ChemicalUUID
   
   association [0..*] to I_ChemicalSynonym  as _ChemicalSynonym   on $projection.ChemicalBasicInfoUUID = _ChemicalSynonym.ChemicalBasicInfoUUID
//                                                                 and $projection.ChemicalUUID          = _ChemicalSynonym.ChemicalUUID

                                                                 
  /*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ] }*/
   association [1..1] to I_ChemicalRevision as _ChemicalRevision on $projection.ChemicalRevisionUUID = _ChemicalRevision.ChemicalRevisionUUID
//                                                                 and $projection.ChemicalUUID          = _ChemicalRevision.ChemicalUUID


{
    key db_key                                                                as ChemicalBasicInfoUUID,
  
    parent_key                                                                as ChemicalRevisionUUID,
    root_key                                                                  as ChemicalUUID,
    
    _ChemicalName, 
    _ChemicalSynonym,
    _ChemicalRevision,
    

    cas_number                                                                as CASNumber,
    
    molec_formula                                                             as MolecularFormula,
    cast( state_of_matter as ehfnd_chm_state_of_matter_cnc preserving type )  as StateOfMatter,
    cast( color as ehfnd_chm_color_code_nc preserving type )                  as ChemicalColor,
    cast( odor as ehfnd_chm_odor_code_nc preserving type )                    as ChemicalOdor,
    cast( form as ehfnd_chm_form_code_nc preserving type )                    as ChemicalForm,
    cast( is_sara_ehs as ehfnd_chm_is_sara_ehs_nc preserving type )           as US_EPCRAIsExtremelyHzdsSubst,
    
    

    // Admin data    

    datetime_cr                                                               as CreationDateTime,
    user_id_cr                                                                as CreatedByUser,
    _CreatedByUser,
    datetime_ch                                                               as LastChangeDateTime,
    user_id_ch                                                                as LastChangedByUser,
    _LastChangedByUser
    
}

Learn More