I_CHARCATTRIBSELECTEDSETCODE

CDS View

Selected Set Code for Charc Attribute

I_CHARCATTRIBSELECTEDSETCODE is a CDS View in S/4HANA. Selected Set Code for Charc Attribute. It contains 10 fields. 4 CDS views read from this table.

Used by 4 CDS view(s) 10 fields

CDS Views using this table (4)

ViewTypeJoinVDMDescription
A_CharcAttribSeldSetCode view_entity from BASIC Characteristic Attribute Selected Set Codes and Code Groups
A_CharcAttribSeldSetCodeT view_entity from BASIC Characteristic Attribute Selected Set Code Texts
C_CharcAttribCodeGroupVH view_entity inner CONSUMPTION Characteristic Attribute Code Group
C_Chargroupcode_Valuehelp view inner CONSUMPTION Selection for group and code

Fields (10)

KeyField CDS FieldsUsed in Views
KEY CharacteristicAttributeCode CharacteristicAttributeCode 4
KEY CharacteristicAttributeCodeGrp CharacteristicAttributeCodeGrp 4
KEY SelectedCodeSet SelectedCodeSet 2
KEY SelectedCodeSetPlant SelectedCodeSetPlant 2
CharcAttribSeldSetCodeChgdBy CharcAttribSeldSetCodeChgdBy 1
CharcAttribSeldSetCodeChgdOn CharcAttribSeldSetCodeChgdOn 1
CharcAttribSeldSetCodeCrtedBy CharcAttribSeldSetCodeCrtedBy 1
CharcAttribSeldSetCodeCrtedOn CharcAttribSeldSetCodeCrtedOn 1
CharcAttributeValuation CharcAttributeValuation,InspectionValuationResult 3
DefectClass DefectClass 1 
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Selected Set Code for Charc Attribute'
@VDM: {
    viewType: #BASIC,
    lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@ObjectModel.supportedCapabilities:
    [ #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET ]
@ObjectModel.usageType: {
    dataClass: #CUSTOMIZING,
    sizeCategory: #S,
    serviceQuality: #A
}
@Metadata.ignorePropagatedAnnotations: true
define view entity I_CharcAttribSelectedSetCode as select from qpac 
   association [0..1] to I_CharcAttributeCodeGrp as _CharcAttributeCodeGrp
      on $projection.CharacteristicAttributeCodeGrp = _CharcAttributeCodeGrp.CharacteristicAttributeCodeGrp
      
   association [0..1] to I_CharcAttributeCode as _CharcAttributeCode
      on  $projection.CharacteristicAttributeCodeGrp = _CharcAttributeCode.CharacteristicAttributeCodeGrp
      and $projection.CharacteristicAttributeCode  = _CharcAttributeCode.CharacteristicAttributeCode
      
   association [0..1] to I_Indicator as _CodeIsInactive
      on $projection.CodeIsInactive = _CodeIsInactive.IndicatorValue

// Required for authority checks

   association [0..1] to I_CharcAttribSelectedCodeSet as _CharcAttribSelectedCodeSet
      on  $projection.SelectedCodeSetPlant = _CharcAttribSelectedCodeSet.SelectedCodeSetPlant
      and $projection.SelectedCodeSet      = _CharcAttribSelectedCodeSet.SelectedCodeSet

{
    key qpac.werks      as SelectedCodeSetPlant,
    //key katalogart as CharacteristicAttributeCatalog,

    key qpac.auswahlmge as SelectedCodeSet,
    key qpac.codegruppe as CharacteristicAttributeCodeGrp, 
    key qpac.code       as CharacteristicAttributeCode,
    //  key qpcd.version --> is always 1 so we could leave out   

    qpac.bewertung      as CharcAttributeValuation,
    qpac.geloescht      as CodeIsInactive,
    qpac.fehlklasse     as DefectClass,
    
    @Semantics.user.createdBy: true
    qpac.ersteller      as CharcAttribSeldSetCodeCrtedBy,
    @Semantics.businessDate.at: true
    qpac.e_datum        as CharcAttribSeldSetCodeCrtedOn,
    @Semantics.user.lastChangedBy: true
    qpac.aenderer       as CharcAttribSeldSetCodeChgdBy,
    @Semantics.businessDate.at: true
    qpac.a_datum        as CharcAttribSeldSetCodeChgdOn,
        
    /* Associations */
    _CharcAttributeCodeGrp,
    _CharcAttributeCode,
    _CodeIsInactive,
    _CharcAttribSelectedCodeSet
}
where katalogart = '1' and qpac.versionam = '000001'

Learn More