I_CHANGERECORDREFSTDBOMTP

CDS View

Change Record Ref Object Std BOM - TP

I_CHANGERECORDREFSTDBOMTP is a CDS View in S/4HANA. Change Record Ref Object Std BOM - TP. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
C_ChgRecdRefStdBOM view from CONSUMPTION Change Record Reference Object Std BOM 
@AbapCatalog.sqlViewName: 'ICHGRDREFSTDBMTP'
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.compiler.compareFilter: true
@EndUserText.label: 'Change Record Ref Object Std BOM - TP'
@VDM.viewType: #TRANSACTIONAL
@ObjectModel.transactionalProcessingEnabled: true
@ObjectModel: {
semanticKey: [ 'StandardObject','Plant','BillOfMaterialVariantUsage','BillOfMaterialVariant'],
                writeDraftPersistence: 'PLMCRREFSTDBOM_D',
                createEnabled,
                deleteEnabled,
                updateEnabled
              }

@ObjectModel.usageType: {serviceQuality: #C,
                         dataClass: #MIXED,
                         sizeCategory: #XXL}
@AbapCatalog.preserveKey:true
define view I_ChangeRecordRefStdBOMTP
  as select from           I_ChangeRecdRefStdBOMBsc as reference_bom

    left outer to one join I_StandardBOMLink        as BOMLink on  reference_bom.ChgRecRefInternalKey1 = BOMLink.BillOfMaterialCategory
                                                               and reference_bom.ChgRecRefInternalKey2 = BOMLink.BillOfMaterial
                                                               and reference_bom.ChgRecRefInternalKey3 = BOMLink.BillOfMaterialVariant

  association [1..1] to I_ChangeRecordDraftTP as _ChangeRecordTP  on $projection.ChangeRecordUUID = _ChangeRecordTP.ChangeRecordUUID
    association [0..1] to E_ChgRecdRefStdBOMBsc as _StdBOMExtension on $projection.ChangeRecordReferenceUUID = _StdBOMExtension.ChangeRecordReferenceUUID
{

  key        ChangeRecordReferenceUUID,

             @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
             case
               when BOMLink.StandardObject is null then cast(substring( reference_bom.ChangeRecordReference, 1, 18) as stobj)
               else cast(BOMLink.StandardObject as stobj)
               end                                                      as StandardObject,

             @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
             case
              when BOMLink.Plant is null then  cast(substring( reference_bom.ChangeRecordReference, 19, 4) as werks_d)
              else cast(BOMLink.Plant as werks_d)
              end                                                       as Plant,

             @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
             case
              when BOMLink.BillOfMaterialVariantUsage is null then cast (substring( reference_bom.ChangeRecordReference, 23, 1) as stlan)
              else cast(BOMLink.BillOfMaterialVariantUsage as stlan)
              end                                                       as BillOfMaterialVariantUsage,

             @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
             case
              when BOMLink.BillOfMaterialVariant is null then cast(substring( reference_bom.ChangeRecordReference, 24, 2) as stalt)
              else cast(BOMLink.BillOfMaterialVariant as stalt)

              end                                                       as BillOfMaterialVariant,
             ChangeRecordUUID,

             ChangeRecordReferenceType,
             ChangeRecordReferenceSubtype,
             ChangeRecordReference,
             ParentChangeRecordRefUUID,
             IsMainReference,
             BillOfMaterialCategory,
             ChgRecdReasonForChange,
             ExpdCompltnDte,
             ChgRecdAuthznGrpText,
             ChgRecdNmbrChgSts, 
             
             reference_bom.ChangeNumber,
             @Semantics.user.createdBy: true
             reference_bom.CreatedByUser,
             reference_bom.CreationDateTime,
             @Semantics.user.lastChangedBy: true
             reference_bom.LastChangedByUser,
             reference_bom.LastChangeDateTime,

             @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
             ChangeRecordItemRelevance,
             ChangeRecordVirtualRefInd,

             //For BOM Navigation

             cast( BOMLink.BillOfMaterial as cs_stlnr preserving type ) as BillOfMaterial,
             reference_bom.ChangeRecordRefObjectUUID,
             @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
             ChangeRecordItemProcgStatus,
             @ObjectModel.readOnly: true
             reference_bom.ChgRecdCurrentItemProcgStatus,
             @ObjectModel.readOnly: true
             ChgRecdItmTgtSts,
             @ObjectModel.readOnly: true
             ChgRecdItmDSgntr,
             @ObjectModel.association.type:  [ #TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT ]
             _ChangeRecordTP

}
where
  ChangeRecordReferenceType = 'SBM'

Learn More