I_CHANGEMSTROBJECTMGMTRECORDTP

CDS View

Change Number Object Management Record (Transactional Proc.)

I_CHANGEMSTROBJECTMGMTRECORDTP is a CDS View in S/4HANA. Change Number Object Management Record (Transactional Proc.). 2 CDS views read from this table.

Used by 2 CDS view(s)

CDS Views using this table (2)

ViewTypeJoinVDMDescription
A_ChangeMstrObjectMgmtRecord view_entity from CONSUMPTION Change Number Object Management Records
I_ChgMstrObjectMgmtRecordTP_2 view_entity projection TRANSACTIONAL Change Number Object Management Record TP 
@AccessControl.authorizationCheck: #CHECK

@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.dataClass: #MASTER

@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type:#SAP_INTERNAL_API

@EndUserText.label: 'Change Number Object Management Record (Transactional Proc.)'
define view entity I_ChangeMstrObjectMgmtRecordTP
  as select from I_ChangeMstrObjectMgmtRecord

  association        to parent I_ChangeMasterTP as _ChangeMaster        on  $projection.ChangeNumber = _ChangeMaster.ChangeNumber

  /*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ] }*/
  association [0..1] to I_ChangeMasterAltDateTP as _ChangeMasterAltDate on  $projection.ChangeNumber                  = _ChangeMasterAltDate.ChangeNumber
                                                                        and $projection.ChgNmbrAlternativeDateCounter = _ChangeMasterAltDate.ChgNmbrAlternativeDateCounter
{
  key  ChangeNumber,

  key  cast(
       case ChangeNumberObjectType
          when '02' then 'MaterialBOM'
          when '31' then 'DocumentInfoRecord'
          when '41' then 'Material'
       end as sbo_bo_type )        as SAPObjectType,

  key  ObjMgmtRecdObjectInternalID as SAPObjectTechnicalID,

       cast('' as char90)          as SAPObjectReadableID,

       @Consumption.hidden: true
       ObjMgmtRecdObject,

       _ChangeMasterAltDate.ChgNmbrAlternativeDateID,

       ObjMgmtRecdDescription,

       ObjMgmtRecdItemUUID,

       ObjMgmtRecdLastChangedAt,

       ObjMgmtRecdLastChangedBy,

       ObjMgmtRecdCreationDate,

       ObjMgmtRecdCreatedBy,

       ObjMgmtRecdObjLastChangedAt,

       ObjMgmtRecdObjLastChangedBy,


       ObjMgmtRecdObjIsLockedForChg,

       ObjMgmtRecdObjIsBaselined,

       ObjMgmtRecdObjIsPlanned,

       ObjMgmtRecdObjRevisionLevel,

       @Consumption.hidden: true
       ChangeNumberObjectType,

       @Consumption.hidden: true
       I_ChangeMstrObjectMgmtRecord.ChgNmbrAlternativeDateCounter,

       // for ETag handling

       _ChangeMaster.ChangeNumberLastChgdDateTime,

       _ChangeMaster,
       _ChangeMasterAltDate
}
// restrict for supported object types

where
     ChangeNumberObjectType = '41'
  or ChangeNumberObjectType = '31'
  or ChangeNumberObjectType = '02'

Learn More