I_CASUBTRANSACTIONTEXT

CDS View

Document Subtransaction - Text

I_CASUBTRANSACTIONTEXT is a CDS View in S/4HANA. Document Subtransaction - Text. It contains 1 fields. 1 CDS views read from this table.

Used by 1 CDS view(s) 1 fields

CDS Views using this table (1)

ViewTypeJoinVDMDescription
P_GR_CustomerLedgerBasicItem view_entity inner COMPOSITE Greece Customer Ledger Basic Item

Fields (1)

KeyField CDS FieldsUsed in Views
CASubTransactionName CASubTransactionName 1 
@AccessControl.authorizationCheck: #NOT_REQUIRED

@EndUserText.label: 'Document Subtransaction - Text'

@Metadata.ignorePropagatedAnnotations: true

@Analytics.dataExtraction.enabled : true

@ObjectModel: { dataCategory: #TEXT,
                modelingPattern: #LANGUAGE_DEPENDENT_TEXT,
                representativeKey: 'CASubTransaction',
                supportedCapabilities: [ #CDS_MODELING_ASSOCIATION_TARGET,
                                         #CDS_MODELING_DATA_SOURCE,
                                         #LANGUAGE_DEPENDENT_TEXT,
                                         #SQL_DATA_SOURCE,
                                         #EXTRACTION_DATA_SOURCE  ],
                usageType: { dataClass: #CUSTOMIZING,
                             serviceQuality: #A,
                             sizeCategory: #S } }

@VDM.viewType: #BASIC

define view entity I_CASubTransactionText
  as select from tfktvot

  association [1..1] to I_CAApplicationArea as _CAApplicationArea on  $projection.CAApplicationArea = _CAApplicationArea.CAApplicationArea
  association [1..1] to I_CAMainTransaction as _CAMainTransaction on  $projection.CAApplicationArea = _CAMainTransaction.CAApplicationArea
                                                                  and $projection.CAMainTransaction = _CAMainTransaction.CAMainTransaction
  association [0..1] to I_Language          as _Language          on  $projection.Language = _Language.Language

{
      @ObjectModel.foreignKey.association: '_CAApplicationArea'
  key applk                                           as CAApplicationArea,
      @ObjectModel.foreignKey.association: '_CAMainTransaction'
  key hvorg                                           as CAMainTransaction,
  key tvorg                                           as CASubTransaction,
      @Semantics.language
      @ObjectModel.foreignKey.association: '_Language'
  key spras                                           as Language,

      @Semantics.text
      cast( txt30 as tvorg_text_kk  preserving type ) as CASubTransactionName,

      _CAApplicationArea,
      _CAMainTransaction,
      _Language,

      /* deprecated fields */
      @API.element.releaseState: #DEPRECATED
      @API.element.successor: '_CAApplicationArea'
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: '_CAApplicationArea'
      _CAApplicationArea                              as _ApplArea,

      @API.element.releaseState: #DEPRECATED
      @API.element.successor: '_CAMainTransaction'
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: '_CAMainTransaction'
      _CAMainTransaction                              as _MainTransaction
}

Learn More