I_CASUBTRANSACTION

CDS View

Document Subtransaction

I_CASUBTRANSACTION is a CDS View in S/4HANA. Document Subtransaction. It contains 2 fields. 2 CDS views read from this table.

Used by 2 CDS view(s) 2 fields

CDS Views using this table (2)

ViewTypeJoinVDMDescription
C_CASubTransactionValueHelp view from CONSUMPTION Teilvorgang Wertehilfe
P_CANotDisputedDocumentSum view inner COMPOSITE Not Disputed Document

Fields (2)

KeyField CDS FieldsUsed in Views
KEY CAMainTransaction CAMainTransaction 1
KEY CASubTransaction CASubTransaction 1 
@AccessControl.authorizationCheck: #NOT_REQUIRED

@EndUserText.label: 'Document Subtransaction'

@Analytics: { dataCategory: #DIMENSION,
              dataExtraction.enabled: true }

@Metadata.ignorePropagatedAnnotations: true

@ObjectModel: { modelingPattern: #ANALYTICAL_DIMENSION,
                representativeKey: 'CASubTransaction',
                sapObjectNodeType.name: 'ContrAcctgSubtransaction',
                supportedCapabilities: [ #ANALYTICAL_DIMENSION,
                                         #CDS_MODELING_ASSOCIATION_TARGET,
                                         #CDS_MODELING_DATA_SOURCE,
                                         #SQL_DATA_SOURCE,
                                         #EXTRACTION_DATA_SOURCE ],
                usageType: { dataClass: #CUSTOMIZING,
                             serviceQuality: #A,
                             sizeCategory: #S } }

@VDM.viewType: #BASIC

define view entity I_CASubTransaction
  as select from tfktvo

  association [1..1] to I_CAApplicationArea    as _CAApplicationArea         on  $projection.CAApplicationArea = _CAApplicationArea.CAApplicationArea
  association [1..1] to I_CAMainTransaction    as _CAMainTransaction         on  $projection.CAApplicationArea = _CAMainTransaction.CAApplicationArea
                                                                             and $projection.CAMainTransaction = _CAMainTransaction.CAMainTransaction
  association [0..1] to I_CAMainTransaction    as _CAReversalMainTransaction on  $projection.CAApplicationArea            = _CAReversalMainTransaction.CAApplicationArea
                                                                             and $projection.CAMainTransactionForReversal = _CAReversalMainTransaction.CAMainTransaction
  association [0..1] to I_CASubTransaction     as _CAReversalSubTransaction  on  $projection.CAApplicationArea            = _CAReversalSubTransaction.CAApplicationArea
                                                                             and $projection.CAMainTransactionForReversal = _CAReversalSubTransaction.CAMainTransaction
                                                                             and $projection.CASubTransactionForReversal  = _CAReversalSubTransaction.CASubTransaction
  association [0..*] to I_CASubTransactionText as _Text                      on  $projection.CAApplicationArea = _Text.CAApplicationArea
                                                                             and $projection.CAMainTransaction = _Text.CAMainTransaction
                                                                             and $projection.CASubTransaction  = _Text.CASubTransaction
{
      @ObjectModel.foreignKey.association: '_CAApplicationArea'
  key tfktvo.applk     as CAApplicationArea,
      @ObjectModel.foreignKey.association: '_CAMainTransaction'
  key tfktvo.hvorg     as CAMainTransaction,
      @ObjectModel.text.association: '_Text'
  key tfktvo.tvorg     as CASubTransaction,

      @ObjectModel.foreignKey.association: '_CAReversalMainTransaction'
      tfktvo.hvorg_rev as CAMainTransactionForReversal,
      @ObjectModel.foreignKey.association: '_CAReversalSubTransaction'
      tfktvo.tvorg_rev as CASubTransactionForReversal,
      tfktvo.faetp     as CADueDateDeterminationRule,
      tfktvo.qsvtp     as CAWithholdingTaxAmountType,
      tfktvo.rladdr    as CARuleForAddlReceivables,
      tfktvo.xpayt     as CAIsPaymentTransaction,
      /*
            hvorg_spl,
            tvorg_spl,
            xnega,
      */

      /* Associations */
      _CAApplicationArea,
      _CAMainTransaction,
      _CAReversalMainTransaction,
      _CAReversalSubTransaction,
      _Text,

      /* deprecated fields */
      @API.element.releaseState: #DEPRECATED
      @API.element.successor: '_CAApplicationArea'
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: '_CAApplicationArea'
      _CAApplicationArea as _ApplArea, 

      @API.element.releaseState: #DEPRECATED
      @API.element.successor: '_CAMainTransaction'
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: '_CAMainTransaction'
      _CAMainTransaction as _MainTransaction,

      @API.element.releaseState: #DEPRECATED
      @API.element.successor: '_CAReversalMainTransaction'
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: '_CAReversalMainTransaction'
      _CAReversalMainTransaction as _MainTransactionRev,

      @API.element.releaseState: #DEPRECATED
      @API.element.successor: '_CAReversalSubTransaction'
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: '_CAReversalSubTransaction'
      _CAReversalSubTransaction as _SubTransactionRev
}
where
  applk = 'C'

Learn More