I_CAPAYMENTMETHOD

CDS View

Payment Method

I_CAPAYMENTMETHOD is a CDS View in S/4HANA. Payment Method. 4 CDS views read from this table.

Used by 4 CDS view(s)

CDS Views using this table (4)

ViewTypeJoinVDMDescription
C_CAPaymentMethodVH view from CONSUMPTION Zahlungsmethode
I_CAIncomingPaymentMethod view_entity from COMPOSITE Incoming Payment Method
I_CAOutgoingPaymentMethod view_entity from COMPOSITE Outgoing Payment Method
I_CAPaymentMethodValueHelp view from COMPOSITE Wertehilfe für Zahlweg 
@AccessControl.authorizationCheck: #NOT_REQUIRED

@EndUserText.label: 'Payment Method'

@Metadata.ignorePropagatedAnnotations: true

@ObjectModel: { modelingPattern: #NONE,
                representativeKey: 'CAPaymentMethod',
                sapObjectNodeType.name: 'ContrAcctgPaymentMethod',
                supportedCapabilities: [ #CDS_MODELING_ASSOCIATION_TARGET,
                                         #CDS_MODELING_DATA_SOURCE,
                                         #SQL_DATA_SOURCE ],
                usageType: { dataClass: #CUSTOMIZING,
                             serviceQuality: #A,
                             sizeCategory: #S } }

@VDM.viewType: #BASIC

define view entity I_CAPaymentMethod
  as select from tfk042z

  association [0..*] to I_CAPaymentMethodText as _Text    on  $projection.Country         = _Text.Country
                                                          and $projection.CAPaymentMethod = _Text.CAPaymentMethod
  association [1..1] to I_Country             as _Country on  $projection.Country = _Country.Country

{
      @ObjectModel.foreignKey.association: '_Country'
  key land1 as Country,
      @ObjectModel.text.association: '_Text'
  key zlsch as CAPaymentMethod,

      xbkkt as BankDetailsOfBPAreRequired,
      xstra as AddressDetailsAreRequired,
      xeinz as IsPaytMethForIncomingPayments,
      xpgir as CAIsPaytMethForPostOffcBkAcct,
      xschk as ChequeIsCreatedWithPaytMeth,
      xeuro as IsPaytMethForEUInternalTransf,
      xverr as CAPaymentMethodProcessingType,
      formi as CAPaymentMediumFormat,
      formz as CAPaytMediumFormatSupplement,
      xnopo as CAPaymentOrderIsCreated,
      xebpp as CAPaytMethForBillerDirect,
      xesrd as CAIsPaytSlipWithRefNmbrProced,
      xaddr as CAPaytMethAddressIsNotRequired,
      bolty as BR_CABoletoAssignmentType,
      ddaty as CAPaymentMethodNotificationCat,
      xiban as ContrAcctgIBANOrSWIFTRqmtCode,
      xsepa as CASEPAMandateIsRequired,
      pnopt as CASEPAPrenotificationIsCreated,
      rtpty as CARealTimePaymentCategory,

      /* associations */
      _Text,
      _Country,

      /* deprecated fields */
      @API.element.releaseState: #DEPRECATED
      @API.element.successor: 'CAPaytMediumFormatSupplement'
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'CAPaytMediumFormatSupplement'
      formz as CASuplmntForPaytMediumFormat,

      @API.element.releaseState: #DEPRECATED
      @API.element.successor: 'ContrAcctgIBANOrSWIFTRqmtCode'
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'ContrAcctgIBANOrSWIFTRqmtCode'
      xiban as CAIBANAndOrSwiftCodeIsRequired
}

Learn More