I_CABUSPARTINVCENHCDFORDSPCRCY

CDS View

Enhanced BP Invoice for Display Currency

I_CABUSPARTINVCENHCDFORDSPCRCY is a CDS View in S/4HANA. Enhanced BP Invoice for Display Currency. 2 CDS views read from this table.

Used by 2 CDS view(s)

CDS Views using this table (2)

ViewTypeJoinVDMDescription
A_CABusPartInvcEnhcdForDspCrcy view_entity from COMPOSITE Enhanced BP Invoice for Display Currency
A_CABusPartInvoice view_entity from COMPOSITE Business Partner Invoice 
@VDM.viewType: #COMPOSITE

@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.serviceQuality: #C

@AccessControl.authorizationCheck: #NOT_REQUIRED

@EndUserText.label: 'Enhanced BP Invoice for Display Currency'

define view entity I_CABusPartInvcEnhcdForDspCrcy
  with parameters
    P_DisplayCurrency : waers_kk

  as select from P_CABusPartInvcItemSumForDC
                 (P_DisplayCurrency : $parameters.P_DisplayCurrency)

  association [0..1] to I_CABusPartInvoiceStatus as _BusPartnerInvoiceStatus on $projection.CABusPartnerInvoiceStatus = _BusPartnerInvoiceStatus.CABusPartnerInvoiceStatus

{
      @ObjectModel.foreignKey.association: '_BusPartnerInvoice'
  key CABusPartnerInvoiceUUID,

      @ObjectModel.foreignKey.association: '_BusPartnerInvoiceStatus'
      case 
        when OpenAmountInDisplayCrcy = 0 
          then cast('02' as inv_status_dc_kk)  //paid

        when CAReleasedAmtInDisplayCurrency = OpenAmountInDisplayCrcy
         and CAClearingAmountInDisplayCrcy = 0 
          then cast('04' as inv_status_dc_kk)  //released

        when CAClearingAmountInDisplayCrcy = 0
          then cast('01' as inv_status_dc_kk)  //open

        else cast('03' as inv_status_dc_kk)    //partly paid/released

      end as CABusPartnerInvoiceStatus, 

      //header data

      @ObjectModel.foreignKey.association: '_DocCtnRefType'
      CADocumentContainerRefType,
      CADocumentContainerReference,
      CreationDate,
      CreationTime,

      //amounts

      @ObjectModel.foreignKey.association: '_DisplayCurrency'
      DisplayCurrency,
      @Semantics.amount.currencyCode: 'DisplayCurrency'
      CAInvoiceAmountInDisplayCrcy,
      @Semantics.amount.currencyCode: 'DisplayCurrency'
      OpenAmountInDisplayCrcy,
      @Semantics.amount.currencyCode: 'DisplayCurrency'
      CashDiscountAmountInDspCrcy,
      @Semantics.amount.currencyCode: 'DisplayCurrency'
      CAEligibleAmountForCshDiscInDC,
      @Semantics.amount.currencyCode: 'DisplayCurrency'
      CAReleasedAmtInDisplayCurrency,
      @Semantics.amount.currencyCode: 'DisplayCurrency'
      CAClearingAmountInDisplayCrcy,
      
      /* Associations */
      _BusPartnerInvoiceStatus,
      //P_CABusPartInvcItemSumForDC

      _BusPartnerInvoice,
      _DocCtnRefType,
      _DisplayCurrency
}

Learn More