I_BUSINESSPARTNERDEFAULTADDR

CDS View

Business Partner Default Address

I_BUSINESSPARTNERDEFAULTADDR is a CDS View in S/4HANA. Business Partner Default Address. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
P_BusinessPartnerDefaultAddr view_entity from CONSUMPTION Business Partner Default Address 
@EndUserText.label: 'Business Partner Default Address' //same as DDL description

@Analytics.dataCategory: #DIMENSION //or #CUBE or #FACT

@VDM.viewType: #BASIC
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.representativeKey: 'BusinessPartner'
@AbapCatalog.sqlViewName: 'IBPDEFADDR'
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #MASTER
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.personalData.blocking: #REQUIRED
@Metadata.allowExtensions: true
@AccessControl.privilegedAssociations:  [ '_Address', '_AddressDefaultRepresentation', '_AddrOrgNamePostalAddress' ]
@Consumption.dbHints: [ 'USE_HEX_PLAN' ]
define view I_BusinessPartnerDefaultAddr
  as select from but020
    inner join   but021_fs on  but020.partner       = but021_fs.partner
                           and but020.addrnumber    = but021_fs.addrnumber
    //                                             and but020.addr_valid_from = but021_fs.valid_from

                           and but020.addr_valid_to = but021_fs.valid_to // to get current default address use view I_BPCurrentDefaultAddress

                           and but021_fs.adr_kind   = 'XXDEFAULT'
                           and but020.nation        = ''

  association [1..1] to I_BusinessPartner    as _BusinessPartner              on  $projection.BusinessPartner = _BusinessPartner.BusinessPartner

  association [1..1] to I_Address            as _Address                      on  $projection.BusinessPartnerAddressID = _Address.AddressID

  association [0..1] to I_BPProtectedAddress as _BPProtectedAddress           on  $projection.BusinessPartner          = _BPProtectedAddress.BusinessPartner
                                                                              and $projection.BusinessPartnerAddressID = _BPProtectedAddress.AddressID

  association [0..1] to I_Address_2          as _AddressDefaultRepresentation on  $projection.BusinessPartnerAddressID                    = _AddressDefaultRepresentation.AddressID
                                                                              and _AddressDefaultRepresentation.AddressRepresentationCode is initial
  association [0..1] to I_AddrOrgNamePostalAddress as _AddrOrgNamePostalAddress on  $projection.BusinessPartnerAddressID = _AddrOrgNamePostalAddress.AddressID
                                                                              and _AddrOrgNamePostalAddress.AddressRepresentationCode is initial                                                                          

{
  key but020.partner                                       as BusinessPartner,
      @ObjectModel.foreignKey.association: '_Address'
  key but021_fs.addrnumber                                 as BusinessPartnerAddressID,
      @ Semantics.businessDate.from:true
      but020.addr_valid_from                               as ValidityStartDate,
      @ Semantics.businessDate.to:true
      but020.addr_valid_to                                 as ValidityEndDate,
      but021_fs.xdfadu                                     as IsStandardAddress,
      _BusinessPartner.PersonNumber                        as PersonNumber,
      //commented for I_Address_2 adoption

      // _Address.PrfrdCommMediumType    as  PrfrdCommMediumType,

      //    _Address.CorrespondenceLanguage as  CorrespondenceLanguage,

      //addded for I_Address_2 adoption

      _AddressDefaultRepresentation.PrfrdCommMediumType    as PrfrdCommMediumType,
      _AddressDefaultRepresentation.CorrespondenceLanguage as CorrespondenceLanguage,
      _Address,
      _BusinessPartner.AuthorizationGroup,
      _BusinessPartner,
      _BPProtectedAddress,
      // I_Address_2 adoption

      _AddressDefaultRepresentation,
      _AddrOrgNamePostalAddress
}

Learn More