I_BUSINESSPARTNERBANK_2

CDS View

Core View: Business Partner Bank

I_BUSINESSPARTNERBANK_2 is a CDS View in S/4HANA. Core View: Business Partner Bank. It contains 12 fields. 6 CDS views read from this table.

Used by 6 CDS view(s) 12 fields

CDS Views using this table (6)

ViewTypeJoinVDMDescription
I_BusinessPartnerBankGov view union_all COMPOSITE Business Partner Bank (Governance)
I_BusinessPartnerBankTP_2 view_entity from TRANSACTIONAL Transactional View for BP bank details with RAP
I_CAContractPartnerBank view_entity from COMPOSITE Contract Account Partner Bank
I_CAContractPartnerBankIdnVH view_entity from COMPOSITE Search help Bank Identification
R_WorkAssignmentBankAccountTP view_entity from TRANSACTIONAL TP View for Bank Accounts for Workforce Person
R_WrkAssignmentBankAccountTP_2 view_entity from TRANSACTIONAL TP View for Bank Accounts for Workforce Person

Fields (12)

KeyField CDS FieldsUsed in Views
KEY BankIdentification BankIdentification 2
KEY BusinessPartner BusinessPartner,WorkAssignmentBusinessPartner 2
BankAccount BankAccount 2
BankAccountHolderName BankAccountHolderName 2
BankAccountName BankAccountName 2
BankControlKey BankControlKey 2
BankCountryKey BankCountryKey 2
BankName BankName 2
BankNumber Bank 2
BPBankIsProtected BPBankIsProtected 2
IBAN IBAN 2
SWIFTCode SWIFTCode 2 
@AbapCatalog.sqlViewName: 'IBUPABANK2'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@VDM.viewType: #BASIC
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #MASTER
@EndUserText.label: 'Core View: Business Partner Bank'
@Consumption.dbHints: [ 'USE_HEX_PLAN' ]
define view I_BusinessPartnerBank_2
  as select from but0bk as BusinessPartnerBank

  association [1..1] to I_BusinessPartner        as _BusinessPartner on  $projection.BusinessPartner = _BusinessPartner.BusinessPartner

  association [1..1] to I_BankForBusinessPartner as _Bank            on  $projection.BankNumber     = _Bank.BankInternalID
                                                                     and $projection.BankCountryKey = _Bank.BankCountry

  association [1..1] to I_BusinessPartnerIBAN    as _IBAN            on  $projection.BankAccount    = _IBAN.BankAccount
                                                                     and $projection.BankNumber     = _IBAN.Bank
                                                                     and $projection.BankCountryKey = _IBAN.BankCountry
                                                                     and $projection.BankControlKey = _IBAN.BankControlKey                                                 
{
  key BusinessPartnerBank.partner       as BusinessPartner,
  key BusinessPartnerBank.bkvid         as BankIdentification,
      BusinessPartnerBank.banks         as BankCountryKey,
      _Bank.BankName                    as BankName,
      BusinessPartnerBank.bankl         as BankNumber,
      _Bank.SWIFTCode                   as SWIFTCode,
      BusinessPartnerBank.bkont         as BankControlKey,
      BusinessPartnerBank.koinh         as BankAccountHolderName,
      BusinessPartnerBank.accname       as BankAccountName,
      BusinessPartnerBank.bk_valid_from as ValidityStartDate,
      BusinessPartnerBank.bk_valid_to   as ValidityEndDate,
      case BusinessPartnerBank.bankn
        when ''
          then BusinessPartnerBank.iban
        else
          _IBAN.IBAN
      end                               as IBAN,
      _IBAN.IBANValidityStartDate       as IBANValidityStartDate,
      BusinessPartnerBank.bankn         as BankAccount,
      BusinessPartnerBank.bkref         as BankAccountReferenceText,
      BusinessPartnerBank.xezer         as CollectionAuthInd,
      BusinessPartnerBank.bkext         as BusinessPartnerExternalBankID,
      BusinessPartnerBank.bk_move_date  as BPBankDetailsChangeDate,
      BusinessPartnerBank.move_bkvid    as BPBankDetailsChangeTargetID,
      BusinessPartnerBank.protect       as BPBankIsProtected,
      _Bank.CityName                    as CityName,
      _Bank,
      _IBAN,
      _BusinessPartner,
      _BusinessPartner.AuthorizationGroup
}

Learn More