I_BLOCKFUNCFORENTPROJECT

CDS View

Basic view for block function calculation

I_BLOCKFUNCFORENTPROJECT is a CDS View in S/4HANA. Basic view for block function calculation. It contains 2 fields. 3 CDS views read from this table.

Used by 3 CDS view(s) 2 fields

CDS Views using this table (3)

ViewTypeJoinVDMDescription
I_EntProjectBlockFunctionTP view from TRANSACTIONAL Transactional processing for Block Function
R_EntProjectBlockFunctionTP view from COMPOSITE Transactional Processing for proj block function
R_EntProjectBlockFunctionTP_2 view_entity from TRANSACTIONAL Trans. Proc. for proj block function

Fields (2)

KeyField CDS FieldsUsed in Views
KEY ProjectUUID ProjectUUID 2
ParentObjectUUID ParentObjectUUID 2 
@AbapCatalog.sqlViewName: 'IROJBLOCKFUNC'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@AccessControl.personalData.blocking:  #BLOCKED_DATA_EXCLUDED
@VDM: {
    viewType: #COMPOSITE
}
@ObjectModel: {

   usageType: {
     serviceQuality:  #C,
     dataClass:       #MIXED,
     sizeCategory:    #L
    }
}
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Basic view for block function calculation'
define view I_BlockFuncForEntProject
  as select from           R_EnterpriseProject     as Project
    left outer to one join I_EntProjElmntBlockFunc as EntProjTimeRecgIsBlkd          on  Project.ProjectSummaryTaskUUID                 = EntProjTimeRecgIsBlkd.ParentObjectUUID
                                                                                     and EntProjTimeRecgIsBlkd.EntProjElementFunctionID = 'S001'
    left outer to one join I_EntProjElmntBlockFunc as EntProjStaffExpensePostgIsBlkd on  Project.ProjectSummaryTaskUUID                          = EntProjStaffExpensePostgIsBlkd.ParentObjectUUID
                                                                                     and EntProjStaffExpensePostgIsBlkd.EntProjElementFunctionID = 'S003'
    left outer to one join I_EntProjElmntBlockFunc as EntProjServicePostingIsBlkd    on  Project.ProjectSummaryTaskUUID                       = EntProjServicePostingIsBlkd.ParentObjectUUID
                                                                                     and EntProjServicePostingIsBlkd.EntProjElementFunctionID = 'S002'
    left outer to one join I_EntProjElmntBlockFunc as EntProjOtherExpensePostgIsBlkd on  Project.ProjectSummaryTaskUUID                          = EntProjOtherExpensePostgIsBlkd.ParentObjectUUID
                                                                                     and EntProjOtherExpensePostgIsBlkd.EntProjElementFunctionID = 'S004'
    left outer to one join I_EntProjElmntBlockFunc as EntProjProcurementIsBlkd       on  Project.ProjectSummaryTaskUUID                    = EntProjProcurementIsBlkd.ParentObjectUUID
                                                                                     and EntProjProcurementIsBlkd.EntProjElementFunctionID = 'S005'

{


  key  Project.ProjectUUID,
       Project.ProjectSummaryTaskUUID as ParentObjectUUID,

       case
           when EntProjTimeRecgIsBlkd.EntProjElementFunctionIsBlkd is null
                     then ' '
                 else EntProjTimeRecgIsBlkd.EntProjElementFunctionIsBlkd
             end                      as EntProjTimeRecgIsBlkd,


       case
       when EntProjStaffExpensePostgIsBlkd.EntProjElementFunctionIsBlkd is null
           then ' '
       else EntProjStaffExpensePostgIsBlkd.EntProjElementFunctionIsBlkd
       end                            as EntProjStaffExpensePostgIsBlkd,

       case
       when EntProjServicePostingIsBlkd.EntProjElementFunctionIsBlkd is null
           then ' '
       else EntProjServicePostingIsBlkd.EntProjElementFunctionIsBlkd
       end                            as EntProjServicePostingIsBlkd,

       case
       when EntProjOtherExpensePostgIsBlkd.EntProjElementFunctionIsBlkd is null
           then ' '
       else EntProjOtherExpensePostgIsBlkd.EntProjElementFunctionIsBlkd
       end                            as EntProjOtherExpensePostgIsBlkd,

       case
       when EntProjProcurementIsBlkd.EntProjElementFunctionIsBlkd is null
          then ' '
       else EntProjProcurementIsBlkd.EntProjElementFunctionIsBlkd
       end                            as EntProjPurchasingIsBlkd

}
where
  Project.ProjectCategory <> '7';

Learn More