I_BILLOFOPERATIONS

CDS View

Bill of Operations

I_BILLOFOPERATIONS is a CDS View in S/4HANA. Bill of Operations. It contains 23 fields. 25 CDS views read from this table.

Used by 25 CDS view(s) 23 fields

CDS Views using this table (25)

ViewTypeJoinVDMDescription
C_ChangeRecordInspectionPlanVH view_entity from CONSUMPTION Inspection Plan Value Help
C_ChangeRecordInspPlanMatVH view_entity from CONSUMPTION Inspection Plan Value Help by Material
C_ChangeRecordMasterRcpVH view_entity from CONSUMPTION Master Recipe Value Help
C_ChangeRecordPlngRtgVH view from CONSUMPTION Planning Routing Value Help
C_ChangeRecordProdnRoutingVH view_entity from CONSUMPTION Production Routing Value Help
C_ChgRecdEquipTskListMatVH view_entity from CONSUMPTION Material for Equipment Task List
C_ChgRecdEquipTskListVH view_entity from CONSUMPTION Equipment Task List
C_ChgRecdFuncLocTskListMatVH view_entity from CONSUMPTION Material for Functional Loc Task List
C_ChgRecdFuncLocTskListVH view_entity from CONSUMPTION Functional Location Task List
C_ChgRecdMaintTskListMatVH view_entity from CONSUMPTION Material for Maintenance Task List
C_ChgRecdMaintTskListVH view_entity from CONSUMPTION Maintenance Task List
C_ChgRecdRateRtgTskListMatVH view from CONSUMPTION Material for Rate Rtg Task List
C_ChgRecdRateRtgTskListVH view from CONSUMPTION Rate Routing Task List
C_ChgRecdRefCutPlngPrflMatVH view from CONSUMPTION Material for Cut Planning Profile
C_ChgRecdRefCutPlngPrflVH view from CONSUMPTION Cut Planning Profile task List
C_ChgRecdRefOpSetTskListMatVH view from CONSUMPTION Material for Ref Op Set Task List
C_ChgRecdRefOpSetTskListVH view from CONSUMPTION Ref Op Set Task List
C_ChgRecdRefRateRtgTskListVH view_entity from CONSUMPTION Ref rate Routing Task List
C_RefRateRtgTskListMatVH view_entity from CONSUMPTION Material for Ref Rate Routing Task List
I_BillOfOperationsStdVH view from COMPOSITE Bill of Operations
I_InspectionPlan view_entity from BASIC Inspection Plan
I_MaintenanceTaskList view from COMPOSITE Maintenance Task List
I_MfgBillOfOperations view from BASIC Manufacturing Bill of Operations
I_ProductionRoutingVersion view_entity inner COMPOSITE Production Routing Version
R_MaintenanceTaskListTP view_entity from TRANSACTIONAL TaskList Root View

Fields (23)

KeyField CDS FieldsUsed in Views
KEY BillOfOperationsGroup BillOfOperationsGroup,TaskListGroup 4
KEY BillOfOperationsType BillOfOperationsType,TaskListType 5
KEY BillOfOperationsVariant BillOfOperationsVariant,TaskListGroupCounter 4
_BillOfOperationsVersionType _BillOfOperationsVersionType 1
BillOfOperationIsExecutedInMES BillOfOperationIsExecutedInMES 1
BillOfOperationsIsTrnsfdToERP BillOfOperationsIsTrnsfdToERP 1
BillOfOperationsSubtype BillOfOperationsSubtype 1
BillOfOperationsVariantDesc BillOfOperationsVariantDesc 1
BillOfOperationsVersionType BillOfOperationsVersionType 2
HasChangeNumber HasChangeNumber 1
HasParameterEffectivity HasParameterEffectivity 1
IsMarkedForDeletion IsMarkedForDeletion 1
LastChangeDate LastChangeDate 2
LastChangedByUser LastChangedByUser 2
LastChangeTime LastChangeTime 1
LastUsageDate LastUsageDate 1
NumberOfUsages NumberOfUsages 1
ProdnProcgIsFlexible ProdnProcgIsFlexible 1
RoutingIsReworkRouting RoutingIsReworkRouting 1
ShopFloorRoutingTemplateOwner ShopFloorRoutingTemplateOwner 1
ShopFloorRoutingTemplateType ShopFloorRoutingTemplateType 1
ShopFloorRtgTemplateCategory ShopFloorRtgTemplateCategory 1
ShopFloorRtgTemplateSubType ShopFloorRtgTemplateSubType 1 
@AbapCatalog.sqlViewName: 'IPPBILLOFOPER'
@ObjectModel.compositionRoot: true
@AccessControl.authorizationCheck: #MANDATORY
@VDM.viewType: #BASIC
@Analytics: {dataCategory: #DIMENSION}
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.representativeKey: 'BillOfOperationsVariant'
@AbapCatalog.compiler.compareFilter: true
@EndUserText.label: 'Bill of Operations'
@ObjectModel.usageType: { serviceQuality: #A, sizeCategory: #M, dataClass: #MASTER }
@Analytics.dataExtraction.enabled: true
@ObjectModel.sapObjectNodeType.name: 'ProductionRouting'
@Metadata.allowExtensions: true
//@AbapCatalog.preserveKey:true

@ObjectModel.supportedCapabilities:[#ANALYTICAL_DIMENSION,#CDS_MODELING_ASSOCIATION_TARGET,#EXTRACTION_DATA_SOURCE]
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION

define view I_BillOfOperations
  as select from plkz

  association [1..1] to I_BillOfOperationsType        as _BillOfOperationsType        on  $projection.BillOfOperationsType = _BillOfOperationsType.BillOfOperationsType
  association [0..1] to I_BillOfOperationsVersionType as _BillOfOperationsVersionType on  $projection.BillOfOperationsVersionType = _BillOfOperationsVersionType.BillOfOperationsVersionType
  association [1..1] to I_BillOfOperationsGroup       as _BillOfOperationsGroup       on  $projection.BillOfOperationsType  = _BillOfOperationsGroup.BillOfOperationsType
                                                                                      and $projection.BillOfOperationsGroup = _BillOfOperationsGroup.BillOfOperationsGroup
  -- to child: Change State of Root
  association [1..*] to I_BillOfOperationsChangeState as _BillOfOperationsChangeState on  $projection.BillOfOperationsType    = _BillOfOperationsChangeState.BillOfOperationsType
                                                                                      and $projection.BillOfOperationsGroup   = _BillOfOperationsChangeState.BillOfOperationsGroup
                                                                                      and $projection.BillOfOperationsVariant = _BillOfOperationsChangeState.BillOfOperationsVariant
  -- to child: Sequences
  association [1..*] to I_BillOfOperationsSequence    as _BillOfOperationsSequence    on  $projection.BillOfOperationsType    = _BillOfOperationsSequence.BillOfOperationsType
                                                                                      and $projection.BillOfOperationsGroup   = _BillOfOperationsSequence.BillOfOperationsGroup
                                                                                      and $projection.BillOfOperationsVariant = _BillOfOperationsSequence.BillOfOperationsVariant

  -- to child: Material to BOO assignment
  association [1..*] to I_BOOMaterialAssignment       as _BOOMaterialAssignment       on  $projection.BillOfOperationsType    = _BOOMaterialAssignment.BillOfOperationsType
                                                                                      and $projection.BillOfOperationsGroup   = _BOOMaterialAssignment.BillOfOperationsGroup
                                                                                      and $projection.BillOfOperationsVariant = _BOOMaterialAssignment.BillOfOperationsVariant



{
      @ObjectModel.foreignKey.association: '_BillOfOperationsType'
  key plkz.plnty                                                  as BillOfOperationsType,

      @ObjectModel.foreignKey.association: '_BillOfOperationsGroup'
  key plkz.plnnr                                                  as BillOfOperationsGroup,
  key plkz.plnal                                                  as BillOfOperationsVariant,

      @ObjectModel.foreignKey.association: '_BillOfOperationsVersionType'
      plkz.subtype                                                as BillOfOperationsVersionType,

      plkz.subtype                                                as BillOfOperationsSubtype, //kept for compatibility reasons


      plkz.abdat                                                  as LastUsageDate,
      plkz.abanz                                                  as NumberOfUsages,

      plkz.flg_ecm                                                as HasChangeNumber,
      plkz.flg_ecm_par                                            as HasParameterEffectivity,

      -- Administrative Data
      @Semantics.systemDate.lastChangedAt: true
      plkz.aedat                                                  as LastChangeDate,
      plkz.aeuzeit                                                as LastChangeTime,
      @Semantics.user.lastChangedBy: true
      cast(plkz.aenam as vdm_lastchangedbyuserid preserving type) as LastChangedByUser,
      plkz.delkz                                                  as IsMarkedForDeletion,
      
      plkz.altext                                                 as BillOfOperationsVariantDesc,

      plkz.rework                                                 as RoutingIsReworkRouting,
      plkz.relaxed                                                as ProdnProcgIsFlexible,
      @Semantics.booleanIndicator:true
      plkz.execution_in_me                                        as BillOfOperationIsExecutedInMES,
      @Semantics.booleanIndicator:true
      plkz.erp_integration                                        as BillOfOperationsIsTrnsfdToERP,
      
      plkz.reference_template_category                            as ShopFloorRtgTemplateCategory,
      plkz.reference_template_type                                as ShopFloorRoutingTemplateType,
      plkz.reference_template_subtype                             as ShopFloorRtgTemplateSubType,
      plkz.reference_template_owner                               as ShopFloorRoutingTemplateOwner,

      // **************************** Associations *****************************


      _BOOMaterialAssignment,
      _BillOfOperationsChangeState,
      _BillOfOperationsGroup,
      _BillOfOperationsSequence,
      _BillOfOperationsType,
      _BillOfOperationsVersionType
}

Learn More