I_BILLOFOPVERSIONDEFECTCODE

CDS View

Version BOO Defect Code Assignment

I_BILLOFOPVERSIONDEFECTCODE is a CDS View in S/4HANA. Version BOO Defect Code Assignment. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
C_ReworkBOOVersionDefectCode view left_outer CONSUMPTION Rework Version BOO Defect Code Assgnmnt 
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #BASIC 
@Analytics: {dataCategory: #DIMENSION}
@Metadata.allowExtensions: true
@ObjectModel.usageType: { serviceQuality: #A, sizeCategory: #M, dataClass: #MASTER }
@ObjectModel.representativeKey: 'BillOfOperationsVersion'
@EndUserText.label: 'Version BOO Defect Code Assignment'
define view entity I_BillOfOpVersionDefectCode
  as select from mpe_rtg_defect

  association [1..1] to I_BillOfOperationsType  as _BillOfOperationsType  on  $projection.BillOfOperationsType    = _BillOfOperationsType.BillOfOperationsType
  association [1..1] to I_BillOfOperationsGroup as _BillOfOperationsGroup on  $projection.BillOfOperationsType    = _BillOfOperationsGroup.BillOfOperationsType
                                                                          and $projection.BillOfOperationsGroup   = _BillOfOperationsGroup.BillOfOperationsGroup
  association [1..1] to I_BillOfOperations      as _BillOfOperations      on  $projection.BillOfOperationsType    = _BillOfOperations.BillOfOperationsType
                                                                          and $projection.BillOfOperationsGroup   = _BillOfOperations.BillOfOperationsGroup
                                                                          and $projection.BillOfOperationsVariant = _BillOfOperations.BillOfOperationsVariant
  association [1..1] to I_DefectCodeGroup       as _DefectCodeGroup       on  $projection.DefectCodeGroup         = _DefectCodeGroup.DefectCodeGroup
  association [1..1] to I_DefectCode            as _DefectCode            on  $projection.DefectCodeGroup         = _DefectCode.DefectCodeGroup
                                                                          and $projection.DefectCode              = _DefectCode.DefectCode
    
  association [1..1] to I_User                  as _CreatedByUser         on  $projection.CreatedByUser           = _CreatedByUser.UserID
  association [0..1] to I_User                  as _LastChangedByUser     on  $projection.LastChangedByUser       = _LastChangedByUser.UserID

{
      @ObjectModel.foreignKey.association: '_BillOfOperationsType'
  key plnty                                                       as   BillOfOperationsType,
      @ObjectModel.foreignKey.association: '_BillOfOperationsGroup'
  key plnnr                                                       as   BillOfOperationsGroup,
      @ObjectModel.foreignKey.association: '_BillOfOperations'
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_BillOfOperationsStdVH', element: 'BillOfOperationsVariant' } } ]
  key plnal                                                       as   BillOfOperationsVariant,
  key versn                                                       as   BillOfOperationsVersion,

      //--[ GENERATED:012:GlBfhyFV7kY4h7jYW0xcqG

      @Consumption.valueHelpDefinition: [ 
        { entity:  { name:    'I_DefectCodeGroupStdVH',
                     element: 'DefectCodeGroup' }
        }]
      // ]--GENERATED

   @ObjectModel.foreignKey.association: '_DefectCodeGroup'
   key cast( codegruppe as vdm_qfegrp preserving type )  as DefectCodeGroup,
   @ObjectModel.foreignKey.association: '_DefectCode'  
   key cast( code       as vdm_qfecod preserving type )  as DefectCode,

      -- Administrative Data
      @Semantics.user.createdBy: true
      cast(created_by as vdm_createdbyuserid preserving type)     as   CreatedByUser,
      @Semantics.systemDateTime.createdAt: true
      created_at                                                  as   CreationDateTime,
      @Semantics.user.lastChangedBy: true
      cast(changed_by as vdm_lastchangedbyuserid preserving type) as   LastChangedByUser,
      @Semantics.systemDateTime.lastChangedAt: true
      changed_at                                                  as   LastChangeDateTime,

      // **************************** Associations *****************************


      _DefectCodeGroup,
      _DefectCode,
      _BillOfOperations,
      _BillOfOperationsGroup,
      _BillOfOperationsType,
      _CreatedByUser,
      _LastChangedByUser
} where katalogart = '9' // Defects

Learn More