I_BANKSCRIPTEDADDRESS

CDS View

Bank Scripted Address

I_BANKSCRIPTEDADDRESS is a CDS View in S/4HANA. Bank Scripted Address. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
R_BankScriptedAddressTP view_entity from TRANSACTIONAL Bank Scripted Address 
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Bank Scripted Address'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #S,
  dataClass: #MIXED
}
@VDM.viewType: #COMPOSITE 
define view entity I_BankScriptedAddress
  as select from I_Bank_2                  as Bank
    inner join   I_BankOrganizationAddress as Address on  Address.AddressID                 = Bank.AddressID
                                                      and Address.AddressPersonID           is initial
                                                      and Address.AddressRepresentationCode is not initial
{
  key Bank.BankCountry,
  key Bank.BankInternalID,
  key Address.AddressRepresentationCode,
      @ObjectModel.editableFieldFor: 'AddressRepresentationCode'
      Address.AddressID,
      Address.AddressPersonID, 
      Address.AddressObjectType,
      @Semantics.language: true
      @ObjectModel.foreignKey.association: '_CorrespondenceLanguage'
      Address.CorrespondenceLanguage,
      Address.PrfrdCommMediumType,
      Address.AddresseeFullName,

      cast( concat(Address.AddresseeName1, Address.AddresseeName2)
        as bf_bank_name_in_local_script preserving type )   as LongBankName,   
      cast( concat(Address.AddresseeName3, Address.AddresseeName4)
        as bf_bank_branch_in_local_script preserving type ) as LongBankBranch, 

      Address.CityName,
      Address.DistrictName,
      Address.VillageName,
      Address.PostalCode,
      Address.CompanyPostalCode,
      Address.StreetName,
      Address.StreetAddrNonDeliverableReason,
      Address.StreetPrefixName1,
      Address.StreetPrefixName2,
      Address.StreetSuffixName1,
      Address.StreetSuffixName2,
      Address.HouseNumber,
      Address.HouseNumberSupplementText,
      Address.Building,
      Address.Floor,
      Address.RoomNumber,
      @ObjectModel.foreignKey.association: '_Country'
      Address.Country,
      @ObjectModel.foreignKey.association: '_Region'
      Address.Region,
      @ObjectModel.foreignKey.association: '_FormOfAddress'
      Address.FormOfAddress,
      Address.TaxJurisdiction,
      Address.TransportZone,
      Address.AddressSearchTerm1,
      Address.AddressSearchTerm2,

      Address.POBox,
      Address.POBoxAddrNonDeliverableReason,
      Address.POBoxIsWithoutNumber,
      Address.POBoxPostalCode,
      Address.POBoxLobbyName,
      Address.POBoxDeviatingCityName,
      Address.POBoxDeviatingRegion,
      Address.POBoxDeviatingCountry,
      Address.CareOfName,
      Address.DeliveryServiceTypeCode,
      Address.DeliveryServiceNumber,
      Address.AddressTimeZone,
      Address.SecondaryRegionName,
      Address.TertiaryRegionName,

      Address._CurrentDfltEmailAddress,
      Address._CurrentDfltLandlinePhoneNmbr,
      Address._CurrentDfltMobilePhoneNumber,
      Address._CurrentDfltFaxNumber,
      Address._Region,
      Address._Country,
      Address._FormOfAddress,
      Address._AddressRepresentationCode,
      Address._CorrespondenceLanguage
}

Learn More