I_BANKADDRESS

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Bank Address'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #L,
  dataClass: #MIXED
}
@VDM.viewType: #COMPOSITE
define view entity I_BankAddress
  as select from           I_Bank_2                  as Bank
    left outer to one join I_BankOrganizationAddress as Address on  Bank.AddressID                    = Address.AddressID
                                                                and Address.AddressPersonID           is initial
                                                                and Address.AddressRepresentationCode is initial

  association [0..1] to I_Region              as _Region            on  $projection.Region  = _Region.Region
                                                                    and $projection.Country = _Region.Country

  association [1..*] to I_BankScriptedAddress as _BankScriptVariant on  $projection.BankCountry    = _BankScriptVariant.BankCountry
                                                                    and $projection.BankInternalID = _BankScriptVariant.BankInternalID
{
  key Bank.BankCountry,
  key Bank.BankInternalID,


      cast( concat(Address.AddresseeName1, Address.AddresseeName2)
          as bf_bank_name_in_local_script preserving type ) as LongBankName, //char80

      cast( concat(Address.AddresseeName3, Address.AddresseeName4)
        as bf_bank_branch_in_local_script preserving type ) as LongBankBranch, //char80


      //      cast(bnk_long_name_concat(

      //           name1  => Address.AddresseeName1,

      //           name2  => Address.AddresseeName2 ) as bf_bank_name_in_local_script preserving type )   as LongBankName,

      //      cast(bnk_long_name_concat(

      //           name1  => Address.AddresseeName3,

      //           name2  => Address.AddresseeName4 ) as bf_bank_branch_in_local_script preserving type ) as LongBankBranch,


      case
        when ( Address.StreetName is null or Address.StreetName is initial ) then Bank.ShortStreetName
        else Address.StreetName
      end                                                   as StreetName,

      Address.HouseNumber,
      Address.HouseNumberSupplementText,

      case
        when ( Address.CityName is null or Address.CityName is initial ) then Bank.ShortCityName
        else Address.CityName
      end                                                   as CityName,

      Address.PostalCode,
      @ObjectModel.foreignKey.association: '_Country'
      Address.Country,

      @ObjectModel.foreignKey.association: '_Region'
      case
        when ( Address.Region is null or Address.Region is initial ) then Bank.Region
        else Address.Region
      end                                                   as Region,

      Address.AddressObjectType,
      @Semantics.language: true
      @ObjectModel.foreignKey.association: '_CorrespondenceLanguage'
      Address.CorrespondenceLanguage,
      Address.PrfrdCommMediumType,
      Address.AddresseeFullName,
      Address.DistrictName,
      Address.VillageName,
      Address.CompanyPostalCode,
      Address.StreetAddrNonDeliverableReason,
      Address.StreetPrefixName1,
      Address.StreetPrefixName2,
      Address.StreetSuffixName1,
      Address.StreetSuffixName2,
      Address.Building,
      Address.Floor,
      Address.RoomNumber,
      @ObjectModel.foreignKey.association: '_FormOfAddress'
      Address.FormOfAddress,
      Address.TaxJurisdiction,
      Address.TransportZone,
      Address.AddressSearchTerm1,
      Address.AddressSearchTerm2,
      Address.POBox,
      Address.POBoxAddrNonDeliverableReason,
      Address.POBoxIsWithoutNumber,
      Address.POBoxPostalCode,
      Address.POBoxLobbyName,
      Address.POBoxDeviatingCityName,
      Address.POBoxDeviatingRegion,
      Address.POBoxDeviatingCountry,
      Address.CareOfName,
      Address.DeliveryServiceTypeCode,
      Address.DeliveryServiceNumber,
      Address.AddressTimeZone,
      Address.SecondaryRegionName,
      Address.TertiaryRegionName,
      Address.AddressRepresentationCode,
      Address.AddressID,
      Address.AddressPersonID,

      Address._Country,
      Address._FormOfAddress,
      Address._AddressRepresentationCode,
      Address._CorrespondenceLanguage,
      Address._AddressObjectType,
      Address._AddressPersonName,
      Address._CurrentDfltEmailAddress,
      Address._CurrentDfltFaxNumber,
      Address._CurrentDfltLandlinePhoneNmbr,
      Address._CurrentDfltMobilePhoneNumber,
      Address._DeliveryServiceTypeCode,
      Address._EmailAddress,
      Address._FaxNumber,
      Address._MainWebsiteURL,
      Address._PhoneNumber,
      Address._POBoxAddrNonDeliverableReason,
      Address._POBoxDeviatingCountry,
      Address._POBoxDeviatingRegion,
      Address._PrfrdCommMediumType,
      Address._StreetAddrNonDeliverableRsn,
      Address._TimeZone,
      Address._TransportationZone,
      Address._UniformResourceIdentifier,

      _BankScriptVariant,
      _Region
}