I_BPADDLCUSTEMAILADDRESSTP

CDS View

BO view for email for MLTAS customers

I_BPADDLCUSTEMAILADDRESSTP is a CDS View in S/4HANA. BO view for email for MLTAS customers. It contains 8 fields. 1 CDS views read from this table.

Used by 1 CDS view(s) 8 fields

CDS Views using this table (1)

ViewTypeJoinVDMDescription
C_BPAddlCustEmailAddress view from CONSUMPTION C view for email address of mlt customer

Fields (8)

KeyField CDS FieldsUsed in Views
KEY AddressID AddressID 1
KEY BusinessPartner BusinessPartner 1
KEY Customer Customer 1
KEY OrdinalNumber OrdinalNumber 1
AddressCommunicationRemarkText AddressCommunicationRemarkText 1
EmailAddress EmailAddress 1
IsDefaultEmailAddress IsDefaultEmailAddress 1
IsHomeEmailAddress IsHomeEmailAddress 1 
@AbapCatalog.sqlViewName: 'IBPADDCEATP'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'BO view for email for MLTAS customers'

@VDM.viewType: #TRANSACTIONAL
@ObjectModel.writeEnabled: true
@ObjectModel.createEnabled

@ObjectModel.deleteEnabled
@ObjectModel.updateEnabled
@Search.searchable: true
@ObjectModel.semanticKey: ['BusinessPartner', 'Customer', 'AddressID', 'OrdinalNumber' ]
@AccessControl.personalData.blocking: #REQUIRED

@ObjectModel.writeDraftPersistence: 'BPADDCEA_D'
@ObjectModel.draftEnabled:true

@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #MASTER
@Consumption.dbHints: [ 'USE_HEX_PLAN' ]
define view I_BPAddlCustEmailAddressTP as select from I_BPEmailAddress as BPEmailAddress inner join I_BPMultipleAssignment as BPMultipleAssignment on BPEmailAddress.AddressID = BPMultipleAssignment.AddressNumber inner join I_Customer as Customer on BPMultipleAssignment.BPObjectID = Customer.Customer

association [1..1] to I_BusinessPartnerTP as _BusinessPartner on  $projection.BusinessPartner = _BusinessPartner.BusinessPartner
association [1..1] to I_BPAdditionalCustomerTP as _BPAdditionalCustomer on  $projection.BusinessPartner = _BPAdditionalCustomer.BusinessPartner
                                                                            and $projection.Customer = _BPAdditionalCustomer.Customer
{
      key BPMultipleAssignment.BusinessPartner,
      key Customer.Customer as Customer,
      key BPEmailAddress.AddressID,
      key BPEmailAddress.OrdinalNumber,
      BPEmailAddress.IsDefaultEmailAddress,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
      BPEmailAddress.EmailAddress, 
      BPEmailAddress.IsHomeEmailAddress,
      BPEmailAddress._AddressCommunicationRemark.CommunicationRemarkText as AddressCommunicationRemarkText,
     // cast('' as ad_remark2 ) as AddressCommunicationRemarkText,

      @ObjectModel.association.type: [#TO_COMPOSITION_ROOT]
      _BusinessPartner,
      @ObjectModel.association.type: [#TO_COMPOSITION_PARENT]
      _BPAdditionalCustomer
}
where BPMultipleAssignment.IsStandardAssignment <> 'X' and BPMultipleAssignment.BPAssignmentCategory = 'CUST'

Learn More