I_BOOOPERATIONPRTCHANGESTATE
BOO Operation Production Resource/Tool Change State
I_BOOOPERATIONPRTCHANGESTATE is a CDS View in S/4HANA. BOO Operation Production Resource/Tool Change State. It contains 57 fields. 8 CDS views read from this table.
CDS Views using this table (8)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| I_BOOOpDocumentPRTChangeState | view | from | COMPOSITE | BOO Operation Document Production Resource/Tool Change State |
| I_BOOOpEquipmentPRTChangeState | view | from | COMPOSITE | BOO Operation Equipment Prod. Resource/Tool Change State |
| I_BOOOpMaterialPRTChangeState | view | from | COMPOSITE | BOO Operation Material Production Resource/Tool Change State |
| I_BOOOpMiscPRTChangeState | view | from | COMPOSITE | BOO Operation Misc Production Resource/Tool Change State |
| I_InspPlanOpPRT | view_entity | from | COMPOSITE | Inspection Plan Production Res Tool View |
| I_MaintTaskListOpPRT | view_entity | from | COMPOSITE | Maint. Task List Operation PRT |
| I_MfgBOOOpProdnRsceToolChgSt | view | from | BASIC | Mfg BOO Op Prodn Rsce Tool Change State |
| I_MfgWorkInstructionPRTDocLink | view | inner | BASIC | Documents linked to a PRT assigned to OA |
Fields (57)
| Key | Field | CDS Fields | Used in Views |
|---|---|---|---|
| KEY | BillOfOperationsGroup | BillOfOperationsGroup | 5 |
| KEY | BillOfOperationsSequence | BillOfOperationsSequence | 5 |
| KEY | BillOfOperationsType | BillOfOperationsType | 5 |
| KEY | BillOfOperationsVariant | BillOfOperationsVariant | 5 |
| KEY | BOOOperationInternalID | BOOOperationInternalID | 5 |
| KEY | BOOOperationPRTInternalID | BOOOpDocumentPRTInternalID,BOOOpEquipmentPRTInternalID,BOOOperationPRTInternalID,BOOOpMaterialPRTInternalID,BOOOpMiscPRTInternalID | 5 |
| KEY | BOOOperationPRTIntVersCounter | BOOOpDocumentPRTIntVersCounter,BOOOpEquipPRTIntVersCounter,BOOOperationPRTIntVersCounter,BOOOpMaterialPRTIntVersCounter,BOOOpMiscPRTIntVersCounter | 6 |
| _BillOfOperations | _BillOfOperations | 4 | |
| _BillOfOperationsGroup | _BillOfOperationsGroup | 4 | |
| _BillOfOperationsOperation | _BillOfOperationsOperation | 4 | |
| _BillOfOperationsSequence | _BillOfOperationsSequence | 4 | |
| _BillOfOperationsType | _BillOfOperationsType | 4 | |
| _BOOOperationInternalID | _BOOOperationInternalID | 4 | |
| _BOOOperationPRTInternalID | _BOOOperationPRTInternalID | 4 | |
| _ChangeMaster | _ChangeMaster | 4 | |
| _CreatedByUser | _CreatedByUser | 4 | |
| _EndDateOffsetDurationUnit | _EndDateOffsetDurationUnit | 4 | |
| _EndDateOffsetReferenceCode | _EndDateOffsetReferenceCode | 4 | |
| _LastChangedByUser | _LastChangedByUser | 4 | |
| _ProdnResourceToolUsageUnit | _ProdnResourceToolUsageUnit | 4 | |
| _ProdnRsceToolControlProfile | _ProdnRsceToolControlProfile | 4 | |
| _ProdnRsceToolMasterData | _ProdnRsceToolMasterData | 4 | |
| _ProdnRsceToolStandardText | _ProdnRsceToolStandardText | 4 | |
| _ProdnRsceToolTotQtyCalcFmla | _ProdnRsceToolTotQtyCalcFmla | 4 | |
| _ProdnRsceToolUsageQtyCalcFmla | _ProdnRsceToolUsageQtyCalcFmla | 4 | |
| _ProductionResourceToolUnit | _ProductionResourceToolUnit | 4 | |
| _ProductionResourceType | _ProductionResourceType | 4 | |
| _StartDateOffsetDurationUnit | _StartDateOffsetDurationUnit | 4 | |
| _StartDateOffsetReferenceCode | _StartDateOffsetReferenceCode | 4 | |
| BillOfOperationsVersion | BillOfOperationsVersion | 4 | |
| ChangeNumber | ChangeNumber | 5 | |
| CreatedByUser | CreatedByUser | 5 | |
| CreationDate | CreationDate | 5 | |
| EndDateOffsetDuration | EndDateOffsetDuration | 5 | |
| EndDateOffsetDurationUnit | EndDateOffsetDurationUnit | 5 | |
| EndDateOffsetReferenceCode | EndDateOffsetReferenceCode | 5 | |
| IsDeleted | IsDeleted | 1 | |
| IsImplicitlyDeleted | IsImplicitlyDeleted | 1 | |
| LastChangeDate | LastChangeDate | 5 | |
| LastChangedByUser | LastChangedByUser | 5 | |
| ProdnRsceToolControlProfile | ProdnRsceToolControlProfile | 5 | |
| ProdnRsceToolItemNumber | ProdnRsceToolItemNumber | 5 | |
| ProdnRsceToolStandardTextCode | ProdnRsceToolStandardTextCode | 5 | |
| ProdnRsceToolStandardWorkQty | ProdnRsceToolStandardWorkQty | 5 | |
| ProdnRsceToolStdWorkQtyUnit | ProdnRsceToolStdWorkQtyUnit | 5 | |
| ProdnRsceToolText | ProdnRsceToolText | 5 | |
| ProdnRsceToolTotQtyCalcFormula | ProdnRsceToolTotQtyCalcFormula | 5 | |
| ProdnRsceToolUsageQtyCalcFmla | ProdnRsceToolUsageQtyCalcFmla | 5 | |
| ProdnRsceToolUsageQuantity | ProdnRsceToolUsageQuantity | 5 | |
| ProdnRsceToolUsageQuantityUnit | ProdnRsceToolUsageQuantityUnit | 5 | |
| ProductionResourceInternalID | ProductionResourceInternalID | 5 | |
| ProductionResourceType | ProductionResourceType | 5 | |
| StartDateOffsetDuration | StartDateOffsetDuration | 5 | |
| StartDateOffsetDurationUnit | StartDateOffsetDurationUnit | 5 | |
| StartDateOffsetReferenceCode | StartDateOffsetReferenceCode | 5 | |
| ValidityEndDate | ValidityEndDate | 1 | |
| ValidityStartDate | ValidityStartDate | 5 |
@AbapCatalog.sqlViewName: 'IPPBOOOPPRTCS'
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.privilegedAssociations: ['_CreatedByUser', '_LastChangedByUser']
@VDM.viewType: #BASIC
@Analytics: {dataCategory: #DIMENSION}
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.representativeKey: 'BOOOperationPRTIntVersCounter'
@AbapCatalog.compiler.compareFilter: true
@ObjectModel.usageType: { serviceQuality: #B, sizeCategory: #M, dataClass: #MASTER }
@Search.searchable: true
@EndUserText.label: 'BOO Operation Production Resource/Tool Change State'
@Metadata.allowExtensions: true
define view I_BOOOperationPRTChangeState
as select from plfh
association [1..1] to I_BillOfOperationsType as _BillOfOperationsType on $projection.BillOfOperationsType = _BillOfOperationsType.BillOfOperationsType
association [1..1] to I_BillOfOperationsGroup as _BillOfOperationsGroup on $projection.BillOfOperationsType = _BillOfOperationsGroup.BillOfOperationsType
and $projection.BillOfOperationsGroup = _BillOfOperationsGroup.BillOfOperationsGroup
association [1..1] to I_BillOfOperations as _BillOfOperations on $projection.BillOfOperationsType = _BillOfOperations.BillOfOperationsType
and $projection.BillOfOperationsGroup = _BillOfOperations.BillOfOperationsGroup
and $projection.BillOfOperationsVariant = _BillOfOperations.BillOfOperationsVariant
association [1..1] to I_BOOOperationInternalID as _BOOOperationInternalID on $projection.BillOfOperationsType = _BOOOperationInternalID.BillOfOperationsType
and $projection.BillOfOperationsGroup = _BOOOperationInternalID.BillOfOperationsGroup
and $projection.BOOOperationInternalID = _BOOOperationInternalID.BOOOperationInternalID
association [1..1] to I_BillOfOperationsSequence as _BillOfOperationsSequence on $projection.BillOfOperationsType = _BillOfOperationsSequence.BillOfOperationsType
and $projection.BillOfOperationsGroup = _BillOfOperationsSequence.BillOfOperationsGroup
and $projection.BillOfOperationsVariant = _BillOfOperationsSequence.BillOfOperationsVariant
and $projection.BillOfOperationsSequence = _BillOfOperationsSequence.BillOfOperationsSequence
association [1..1] to I_BillOfOperationsOperation as _BillOfOperationsOperation on $projection.BillOfOperationsType = _BillOfOperationsOperation.BillOfOperationsType
and $projection.BillOfOperationsGroup = _BillOfOperationsOperation.BillOfOperationsGroup
and $projection.BillOfOperationsVariant = _BillOfOperationsOperation.BillOfOperationsVariant
and $projection.BillOfOperationsSequence = _BillOfOperationsOperation.BillOfOperationsSequence
and $projection.BOOOperationInternalID = _BillOfOperationsOperation.BOOOperationInternalID
association [1..1] to I_BOOOperationPRTInternalID as _BOOOperationPRTInternalID on $projection.BillOfOperationsType = _BOOOperationPRTInternalID.BillOfOperationsType
and $projection.BillOfOperationsGroup = _BOOOperationPRTInternalID.BillOfOperationsGroup
and $projection.BillOfOperationsVariant = _BOOOperationPRTInternalID.BillOfOperationsVariant
and $projection.BillOfOperationsSequence = _BOOOperationPRTInternalID.BillOfOperationsSequence
and $projection.BOOOperationInternalID = _BOOOperationPRTInternalID.BOOOperationInternalID
and $projection.BOOOperationPRTInternalID = _BOOOperationPRTInternalID.BOOOperationPRTInternalID
association [1..1] to I_UnitOfMeasure as _ProductionResourceToolUnit on $projection.ProdnRsceToolStdWorkQtyUnit = _ProductionResourceToolUnit.UnitOfMeasure
association [1..1] to I_UnitOfMeasure as _ProdnResourceToolUsageUnit on $projection.ProdnRsceToolUsageQuantityUnit = _ProdnResourceToolUsageUnit.UnitOfMeasure
/*+[hideWarning] { "IDS" : [ "CALCULATED_FIELD_CHECK" ] } */
association [1..1] to I_ProductionResourceType as _ProductionResourceType on $projection.ProductionResourceType = _ProductionResourceType.ProductionResourceType
association [1..1] to I_ProdnRsceToolMasterData as _ProdnRsceToolMasterData on $projection.ProductionResourceType = _ProdnRsceToolMasterData.ProductionResourceType
and $projection.ProductionResourceInternalID = _ProdnRsceToolMasterData.ProductionResourceInternalID
association [1..1] to I_ProdnRsceToolStandardText as _ProdnRsceToolStandardText on $projection.ProdnRsceToolStandardTextCode = _ProdnRsceToolStandardText.ProdnRsceToolStandardTextCode
association [0..1] to I_ProdnRsceToolControlProfile as _ProdnRsceToolControlProfile on $projection.ProdnRsceToolControlProfile = _ProdnRsceToolControlProfile.ProdnRsceToolControlProfile
association [1..1] to I_ProdnRsceToolQtyCalcFormula as _ProdnRsceToolTotQtyCalcFmla on $projection.ProdnRsceToolTotQtyCalcFormula = _ProdnRsceToolTotQtyCalcFmla.ProdnRsceToolQtyCalcFormula
association [1..1] to I_ProdnRsceToolQtyCalcFormula as _ProdnRsceToolUsageQtyCalcFmla on $projection.ProdnRsceToolUsageQtyCalcFmla = _ProdnRsceToolUsageQtyCalcFmla.ProdnRsceToolQtyCalcFormula
association [1..1] to I_OperationDateOffsetRefCode as _StartDateOffsetReferenceCode on $projection.StartDateOffsetReferenceCode = _StartDateOffsetReferenceCode.OperationDateOffsetRefCode
association [1..1] to I_OperationDateOffsetRefCode as _EndDateOffsetReferenceCode on $projection.EndDateOffsetReferenceCode = _EndDateOffsetReferenceCode.OperationDateOffsetRefCode
association [0..1] to I_UnitOfMeasure as _StartDateOffsetDurationUnit on $projection.StartDateOffsetDurationUnit = _StartDateOffsetDurationUnit.UnitOfMeasure
association [0..1] to I_UnitOfMeasure as _EndDateOffsetDurationUnit on $projection.EndDateOffsetDurationUnit = _EndDateOffsetDurationUnit.UnitOfMeasure
association [1..1] to I_User as _CreatedByUser on $projection.CreatedByUser = _CreatedByUser.UserID
association [0..1] to I_User as _LastChangedByUser on $projection.LastChangedByUser = _LastChangedByUser.UserID
association [0..1] to I_ChangeMaster as _ChangeMaster on $projection.ChangeNumber = _ChangeMaster.ChangeNumber
{
@ObjectModel.foreignKey.association: '_BillOfOperationsType'
key plfh.plnty as BillOfOperationsType,
@ObjectModel.foreignKey.association: '_BillOfOperationsGroup'
@Search: {defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8}
key plfh.plnnr as BillOfOperationsGroup,
@ObjectModel.foreignKey.association: '_BillOfOperations'
key plfh.plnal as BillOfOperationsVariant,
@ObjectModel.foreignKey.association: '_BillOfOperationsSequence'
key plfh.plnfl as BillOfOperationsSequence,
@ObjectModel.foreignKey.association: '_BOOOperationInternalID'
key plfh.plnkn as BOOOperationInternalID,
@ObjectModel.foreignKey.association: '_BOOOperationPRTInternalID'
key plfh.pzlfh as BOOOperationPRTInternalID,
-- Representative key
key plfh.zaehl as BOOOperationPRTIntVersCounter,
plfh.versn as BillOfOperationsVersion,
// External key
plfh.psnfh as ProdnRsceToolItemNumber,
@ObjectModel.foreignKey.association: '_ProductionResourceType'
plfh.objty as ProductionResourceType,
@ObjectModel.foreignKey.association: '_ProdnRsceToolMasterData'
plfh.objid as ProductionResourceInternalID,
@ObjectModel.foreignKey.association: '_ProdnRsceToolControlProfile'
plfh.steuf as ProdnRsceToolControlProfile,
// Text
@ObjectModel.foreignKey.association: '_ProdnRsceToolStandardText'
plfh.ktsch as ProdnRsceToolStandardTextCode,
@Search: {defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8}
@Semantics.text: true
plfh.txtz1 as ProdnRsceToolText,
// Admin
@Semantics.systemDate.createdAt: true
datui as CreationDate,
-- @ObjectModel.foreignKey.association: '_CreatedByUser'
@Semantics.user.createdBy: true
cast(plfh.useri as vdm_createdbyuserid preserving type) as CreatedByUser,
@Semantics.systemDate.lastChangedAt: true
datuc as LastChangeDate,
-- @ObjectModel.foreignKey.association: '_LastChangedByUser'
@Semantics.user.lastChangedBy: true
cast(plfh.userc as vdm_lastchangedbyuserid preserving type) as LastChangedByUser,
@ObjectModel.foreignKey.association: '_ChangeMaster'
plfh.aennr as ChangeNumber,
@Semantics.businessDate.from: true
plfh.datuv as ValidityStartDate,
@Semantics.businessDate.to: true
plfh.valid_to as ValidityEndDate,
plfh.loekz as IsDeleted,
plfh.loekz_inherited as IsImplicitlyDeleted,
@ObjectModel.foreignKey.association: '_ProductionResourceToolUnit'
@Semantics.unitOfMeasure: true
plfh.mgeinh as ProdnRsceToolStdWorkQtyUnit,
@Semantics.quantity.unitOfMeasure: 'ProdnRsceToolStdWorkQtyUnit'
@DefaultAggregation: #SUM
plfh.mgvgw as ProdnRsceToolStandardWorkQty,
@ObjectModel.foreignKey.association: '_ProdnRsceToolTotQtyCalcFmla'
plfh.mgform as ProdnRsceToolTotQtyCalcFormula,
@ObjectModel.foreignKey.association: '_ProdnResourceToolUsageUnit'
@Semantics.unitOfMeasure: true
plfh.eweinh as ProdnRsceToolUsageQuantityUnit,
@Semantics.quantity.unitOfMeasure: 'ProdnRsceToolUsageQuantityUnit'
@DefaultAggregation: #SUM
plfh.ewvgw as ProdnRsceToolUsageQuantity,
@ObjectModel.foreignKey.association: '_ProdnRsceToolUsageQtyCalcFmla'
plfh.ewform as ProdnRsceToolUsageQtyCalcFmla,
@ObjectModel.foreignKey.association: '_StartDateOffsetReferenceCode'
plfh.bzoffb as StartDateOffsetReferenceCode,
@ObjectModel.foreignKey.association: '_StartDateOffsetDurationUnit'
@Semantics.unitOfMeasure: true
plfh.ehoffb as StartDateOffsetDurationUnit,
@Semantics.quantity.unitOfMeasure: 'StartDateOffsetDurationUnit'
@DefaultAggregation: #SUM
plfh.offstb as StartDateOffsetDuration,
@ObjectModel.foreignKey.association: '_EndDateOffsetReferenceCode'
plfh.bzoffe as EndDateOffsetReferenceCode,
@ObjectModel.foreignKey.association: '_EndDateOffsetDurationUnit'
@Semantics.unitOfMeasure: true
plfh.ehoffe as EndDateOffsetDurationUnit,
@Semantics.quantity.unitOfMeasure: 'EndDateOffsetDurationUnit'
@DefaultAggregation: #SUM
plfh.offste as EndDateOffsetDuration,
// Associations
_BillOfOperationsType,
_BillOfOperationsGroup,
_BillOfOperations,
_BOOOperationInternalID,
_BillOfOperationsOperation,
_BillOfOperationsSequence,
_BOOOperationPRTInternalID,
_ProductionResourceType,
_ProdnRsceToolMasterData,
_ProdnRsceToolControlProfile,
_ProdnRsceToolTotQtyCalcFmla,
_ProdnRsceToolUsageQtyCalcFmla,
_ProdnRsceToolStandardText,
_ProductionResourceToolUnit,
_ProdnResourceToolUsageUnit,
_StartDateOffsetReferenceCode,
_StartDateOffsetDurationUnit,
_EndDateOffsetReferenceCode,
_EndDateOffsetDurationUnit,
_CreatedByUser,
_LastChangedByUser,
_ChangeMaster
}