I_ASSETSORTEDKEYFIGURESETSPEC

CDS View

Sorted Fixed Asset Key Figure Set Specification

I_ASSETSORTEDKEYFIGURESETSPEC is a CDS View in S/4HANA. Sorted Fixed Asset Key Figure Set Specification. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
I_AssetKeyFigureHierarchyNode view left_outer BASIC Fixed Asset Key Figure Hierarchy Node 
@AbapCatalog: {sqlViewName: 'IASTSRTKEYFSTSPC', preserveKey: true}
@Analytics: { dataCategory: #DIMENSION }
@EndUserText.label: 'Sorted Fixed Asset Key Figure Set Specification'
@VDM.viewType: #BASIC
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ObjectModel: { representativeKey: 'AssetAccountingSortedKeyFigure',
                usageType.serviceQuality: #A,
                usageType.sizeCategory: #S,
                usageType.dataClass: #CUSTOMIZING,
                modelingPattern: #ANALYTICAL_DIMENSION,
                supportedCapabilities: [#ANALYTICAL_DIMENSION, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET, #SQL_DATA_SOURCE]
              }
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true

/*+[hideWarning] { "IDS" : [ "KEY_CHECK" ] }*/
define view I_AssetSortedKeyFigureSetSpec
  as select from I_AssetKeyFigureSetSpec
    inner join   I_AssetKeyFigureSet on I_AssetKeyFigureSetSpec.AssetAccountingKeyFigureSet = I_AssetKeyFigureSet.AssetAccountingKeyFigureSet

  association [0..1] to I_AssetKeyFigureSet           as _AssetKeyFigureSet           on  $projection.AssetAccountingKeyFigureSet = _AssetKeyFigureSet.AssetAccountingKeyFigureSet
  association [0..1] to I_AssetKeyFigure              as _AssetKeyFigure              on  $projection.AssetAccountingKeyFigure = _AssetKeyFigure.AssetAccountingKeyFigure
  association [0..*] to I_AssetKeyFigureHierarchyNode as _AssetKeyFigureHierarchyNode on  $projection.AssetAccountingKeyFigureSet    = _AssetKeyFigureHierarchyNode.AssetAccountingKeyFigureSet
                                                                                      and $projection.AssetAccountingSortedKeyFigure = _AssetKeyFigureHierarchyNode.AssetAccountingSortedKeyFigure
  association [0..*] to I_AssetKeyFigureSetSpecText   as _Text                        on  $projection.AssetAccountingKeyFigureSet = _Text.AssetAccountingKeyFigureSet
                                                                                      and $projection.AssetAccountingKeyFigure    = _Text.AssetAccountingKeyFigure
{
      @ObjectModel.foreignKey.association: '_AssetKeyFigureSet'
  key I_AssetKeyFigureSetSpec.AssetAccountingKeyFigureSet,
      @ObjectModel.hierarchy.association: '_AssetKeyFigureHierarchyNode'
      @ObjectModel.text.element: 'AssetAccountingKeyFigureText'
  key AssetAccountingSortedKeyFigure,
      @ObjectModel.foreignKey.association: '_AssetKeyFigure'
      AssetAccountingKeyFigure,
      AssetAcctgKeyFigureSortSqnc,
      ZeroBalAmountKeyFigureIsHidden,
      @Semantics.text: true
      _Text[1:Language = $session.system_language].AssetAccountingKeyFigureText,

      _AssetKeyFigureSet,
      _AssetKeyFigure,
      _AssetKeyFigureHierarchyNode
}
where
        I_AssetKeyFigureSet.AssetAcctgKeyFigSetAnlytlCntxt  =  '01' //Asset History Sheet

  or    I_AssetKeyFigureSet.AssetAcctgKeyFigSetAnlytlCntxt  =  '02' //Asset Balances

  or(
        I_AssetKeyFigureSet.AssetAcctgKeyFigSetAnlytlCntxt  =  '05' //Globalization

    and I_AssetKeyFigureSetSpec.AssetAcctgKeyFigureSortSqnc <> '000000'
  )

Learn More