I_ASSETMULTIPLECREATION
Asset Multiple Creation
I_ASSETMULTIPLECREATION is a CDS View in S/4HANA. Asset Multiple Creation. 1 CDS views read from this table.
CDS Views using this table (1)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| I_AssetMultipleCreationTP | view | from | TRANSACTIONAL | Asset Multiple Creation - TP |
@AbapCatalog.sqlViewName: 'IASTMULTICREATE'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Asset Multiple Creation'
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #BASIC
@ObjectModel: {
usageType.serviceQuality: #A,
usageType.sizeCategory: #S,
usageType.dataClass: #MASTER
}
define view I_AssetMultipleCreation
as select from faat_md_multi as Multi
association [1..1] to I_CompanyCode as _CompanyCode on $projection.CompanyCode = _CompanyCode.CompanyCode
association [1..1] to I_MasterFixedAsset as _MasterFixedAsset on $projection.CompanyCode = _MasterFixedAsset.CompanyCode
and $projection.MasterFixedAsset = _MasterFixedAsset.MasterFixedAsset
association [1..1] to I_FixedAsset as _FixedAsset on $projection.CompanyCode = _FixedAsset.CompanyCode
and $projection.MasterFixedAsset = _FixedAsset.MasterFixedAsset
and $projection.FixedAsset = _FixedAsset.FixedAsset
association [0..1] to I_AssetClass as _AssetClass on $projection.AssetClass = _AssetClass.AssetClass
association [0..1] to I_AssetAcctDetermination as _AssetAccountDetermination on $projection.AssetAccountDetermination = _AssetAccountDetermination.AssetAccountDetermination
association [0..1] to I_Supplier as _Supplier on $projection.Supplier = _Supplier.Supplier
association [0..1] to I_Country as _AssetCountryOfOrigin on $projection.AssetCountryOfOrigin = _AssetCountryOfOrigin.Country
association [0..1] to I_Currency as _OriginalAcquisitionCurrency on $projection.OriginalAcquisitionCurrency = _OriginalAcquisitionCurrency.Currency
association [0..1] to I_Globalcompany as _PartnerCompany on $projection.PartnerCompany = _PartnerCompany.Company
association [0..1] to I_InternalOrder as _InvestmentOrder on $projection.InvestmentOrder = _InvestmentOrder.InternalOrder
association [0..1] to I_InvestmentReason as _InvestmentReason on $projection.InvestmentReason = _InvestmentReason.InvestmentReason
association [0..1] to I_EnvrnmtlInvestmentReason as _EnvrnmtlInvestmentReason on $projection.EnvrnmtlInvestmentReason = _EnvrnmtlInvestmentReason.EnvrnmtlInvestmentReason
association [0..1] to I_FixedAssetGroup as _FixedAssetGroup on $projection.FixedAssetGroup = _FixedAssetGroup.FixedAssetGroup
association [0..1] to I_FixedAssetPropertyType as _FixedAssetPropertyType on $projection.FixedAssetPropertyType = _FixedAssetPropertyType.FixedAssetPropertyType
association [0..1] to I_UnitOfMeasure as _UnitOfMeasure on $projection.BaseUnit = _UnitOfMeasure.UnitOfMeasure
association [0..1] to I_BusinessArea as _BusinessArea on $projection.BusinessArea = _BusinessArea.BusinessArea
association [0..1] to I_InternalOrder as _InternalOrder on $projection.InternalOrder = _InternalOrder.InternalOrder
association [0..1] to I_FunctionalArea as _FunctionalArea on $projection.FunctionalArea = _FunctionalArea.FunctionalArea
association [0..1] to I_Segment as _Segment on $projection.Segment = _Segment.Segment
association [0..1] to I_Plant as _Plant on $projection.Plant = _Plant.Plant
association [0..1] to I_Location as _AssetLocation on $projection.AssetLocation = _AssetLocation.Location
and $projection.Plant = _AssetLocation.Plant
association [0..1] to I_Employment as _Employment on $projection.PersonnelNumber = _Employment.EmploymentInternalID
{
@ObjectModel.foreignKey.association: '_CompanyCode'
key comp_code as CompanyCode,
@ObjectModel.foreignKey.association: '_MasterFixedAsset'
key asset_no as MasterFixedAsset,
@ObjectModel.foreignKey.association: '_FixedAsset'
key asset_subno as FixedAsset,
key row_index as RowIndex,
//Root fields
@ObjectModel.foreignKey.association: '_AssetClass'
asset_class as AssetClass, //S4CE_F001
@ObjectModel.foreignKey.association: '_AssetAccountDetermination'
gl_account_det as AssetAccountDetermination, //S4CE_F002
// lifecycle_status as assetlifecyclestatus, //S4CE_F004 -- Always Read-Only
// completeness_status as assetcompletenessstatus, //S4CE_F005 -- Always Read-Only
// cast(Multi.is_historical_managed as aneqk) as hashistory, //S4CE_F008 -- Ready Only in UI
// is_blocked as accountisblockedforposting, //S4CE_F009 -- Always Read-Only
// validity_date as assetcreationvaliditydate, //S4CE_F010 -- Hidden in UI
@Semantics.text:true
description as FixedAssetDescription, //S4CE_F011
@Semantics.text:true
add_description as AssetAdditionalDescription, //S4CE_F012
@Semantics.unitOfMeasure:true
@ObjectModel.foreignKey.association: '_UnitOfMeasure'
base_unit as BaseUnit, //S4CE_F013
purchase_order_date as FixedAssetOrderDate, //S4CE_F014
serial_number as AssetSerialNumber, //S4CE_F015
inventory_number as Inventory, //S4CE_F016
legacy_asset_no as LegacyMasterFixedAsset, //S4CE_F017
legacy_asset_subno as LegacyFixedAsset, //S4CE_F017
legacy_comp_code as LegacyFixedAssetCompanyCode, //S4CE_F017
// legacy_transfer_date as legacydatatransferdate, //S4CE_F018 -- Always Read-Only
// legacy_transfer_seq_no as legacydatatransfersequence, //S4CE_F018 -- Always Read-Only
inventory_indicator as InventoryIsCounted, //S4CE_F019
inventory_date as LastInventoryDate, //S4CE_F020
inventory_note as InventoryNote, //S4CE_F020
@ObjectModel.foreignKey.association: '_InvestmentReason'
invest_reason as InvestmentReason, //S4CE_F202
@ObjectModel.foreignKey.association: '_EnvrnmtlInvestmentReason'
environmental_investment as EnvrnmtlInvestmentReason, //S4CE_F203
@ObjectModel.foreignKey.association: '_InvestmentOrder'
investment_io_origin as InvestmentOrder, //S4CE_F204
cast(Multi.investment_wbs_origin as fis_wbsint_no_conv) as InvestmentProjectWBSElement, //S4CE_F205
asset_acquired_used as AssetIsAcquiredUsed, //S4CE_F206
@ObjectModel.foreignKey.association: '_Supplier'
supplier_no as Supplier, //S4CE_F206
original_asset as OriginalMasterFixedAsset, //S4CE_F207
original_subasset as OriginalFixedAsset, //S4CE_F207
original_acq_date as OriginalFixedAssetValueDate, //S4CE_F207
@Semantics.amount.currencyCode: 'OriginalAcquisitionCurrency'
original_acq_value as OriginalAcquisitionAmount, //S4CE_F208
@Semantics.currencyCode: true
@ObjectModel.foreignKey.association: '_OriginalAcquisitionCurrency'
original_acq_value_curr as OriginalAcquisitionCurrency, //S4CE_F208
@Semantics.fiscal.year: true
original_acq_year as OriginalAcquisitionFiscalYear, //S4CE_F208
inhouse_prod_percent as InHouseProdnPercent, //S4CE_F209
asset_type_name as AssetTypeName, //S4CE_F210
manufacturer as AssetManufacturerName, //S4CE_F210
@ObjectModel.foreignKey.association: '_AssetCountryOfOrigin'
origin_country as AssetCountryOfOrigin, //S4CE_F210
@ObjectModel.foreignKey.association: '_PartnerCompany'
trade_id as PartnerCompany, //S4CE_F211
property_key as PropertyClass, //S4CE_F301
@ObjectModel.foreignKey.association: '_FixedAssetPropertyType'
property_ind as FixedAssetPropertyType, //S4CE_F302
land_tax_office as LocalTaxOffice, //S4CE_F303
conveyance_date as ConveyanceDate, //S4CE_F304
assessment_date as LastAssessmentNoticeDate, //S4CE_F305
assessment_tax_number as NoticeOfAssessmentTaxID, //S4CE_F306
land_municipality as Municipality, //S4CE_F307
land_register_map_no as LandRegisterMap, //S4CE_F308
land_plot_number as LandPlot, //S4CE_F309
land_register_volume as LandRegisterVolume, //S4CE_F310
land_register_entry_number as LandRegisterEntrySequence, //S4CE_F311
land_register_of as LandRegisterDate, //S4CE_F312
land_register_entry as LandRegisterEntryDate, //S4CE_F313
@Semantics.quantity.unitOfMeasure: 'AreaSizeUnit'
surface_area as AreaSize, //S4CE_F314
@Semantics.unitOfMeasure: true
surface_area_unit as AreaSizeUnit, //S4CE_F314
@ObjectModel.foreignKey.association: '_FixedAssetGroup'
asset_super_no as FixedAssetGroup,
land_register_page as LandRegisterPage,
real_estate_asset as AssetIsRealEstate,
lease_company as LeaseSupplier,
lease_agreement_no as LeaseAgreement,
lease_agreement_date as LeaseAgreementDate,
lease_notice_date as LeaseTermEndDate,
lease_start_date as LeaseTermStartDate,
lease_years as LeaseDurationInFiscalYears,
lease_periods as LeaseDurationInFiscalPeriods,
lease_type as LeaseType,
lease_data_text as LeasedAssetNote,
last_reorg_date as LastReorganizationDate,
object_nr as ObjectInternalID,
//TDD fields
tax_jurisdiction as TaxJurisdiction, //S4CE_F130
cost_center as CostCenter, //S4CE_F132
@ObjectModel.foreignKey.association: '_InternalOrder'
internal_order as InternalOrder, //S4CE_F134
cast(Multi.wbs_element as fis_wbsint_no_conv) as WBSElementInternalID, //S4CE_F135
activity_type as CostCtrActivityType, //S4CE_F136
profit_center as ProfitCenter, //S4CE_F138
@ObjectModel.foreignKey.association: '_Segment'
segment as Segment, //S4CE_F139
funds_center as FundsCenter, //S4CE_F141
cast(Multi.real_estate_key as recaimkeyfi ) as RealEstateObject, //S4CE_F143
@ObjectModel.foreignKey.association: '_Plant'
plant as Plant, //S4CE_F146
@ObjectModel.foreignKey.association: '_AssetLocation'
location as AssetLocation, //S4CE_F147
room as Room, //S4CE_F148
car_license_plate as VehicleLicensePlateNumber, //S4CE_F149
@ObjectModel.foreignKey.association: '_BusinessArea'
@VDM.lifecycle: {status: #DEPRECATED}
business_area as BusinessArea,
fund as Fund,
grant_id as GrantID,
@ObjectModel.foreignKey.association: '_FunctionalArea'
functional_area as FunctionalArea,
budget_period as BudgetPeriod,
responsible_cost_center as ResponsibleCostCenter,
@ObjectModel.foreignKey.association: '_Employment'
personnel_number as PersonnelNumber,
business_place as BusinessPlace,
//LD fields
capitalization_date as AssetCapitalizationDate, //S4CE_F401
// acquisition_date as acquisitionvaluedate, //S4CE_F402 -- Always Read-Only
// acquisition_period as firstacquisitionfiscalperiod, //S4CE_F402 -- Always Read-Only
// acquisition_year as firstacquisitionfiscalyear, //S4CE_F402 -- Always Read-Only
deactivation_date as AssetDeactivationDate, //S4CE_F403
// Association
_CompanyCode,
_MasterFixedAsset,
_FixedAsset,
_AssetClass,
_AssetAccountDetermination,
_Supplier,
_AssetCountryOfOrigin,
_OriginalAcquisitionCurrency,
_PartnerCompany,
_InvestmentOrder,
_InvestmentReason,
_EnvrnmtlInvestmentReason,
_FixedAssetGroup,
_FixedAssetPropertyType,
_UnitOfMeasure,
_BusinessArea,
_InternalOrder,
_FunctionalArea,
_Segment,
_Plant,
_AssetLocation,
_Employment
}