I_ALLWDORDTYPPERSLSORG

CDS View

Allowed Order Types per Sales Org

I_ALLWDORDTYPPERSLSORG is a CDS View in S/4HANA. Allowed Order Types per Sales Org. It contains 8 fields. 3 CDS views read from this table.

Used by 3 CDS view(s) 8 fields

CDS Views using this table (3)

ViewTypeJoinVDMDescription
I_AllwdCustRetTypePerSlsOrg view_entity from COMPOSITE Allowed Return Type Per Sales Org
I_AllwdOrdTypPerSlsOrgVH view from COMPOSITE Allowed Order types per Sales Org VH
P_AllwdOrdTypPerSlsOrg view left_outer CONSUMPTION Allowed Return Types per Sales Org

Fields (8)

KeyField CDS FieldsUsed in Views
KEY DistributionChannel DistributionChannel 2
KEY Division Division 2
KEY SalesDocumentType SalesDocumentType 2
KEY SalesOrganization SalesOrganization 2
_DistributionChannel _DistributionChannel 1
_Division _Division 1
_SalesDocumentType _SalesDocumentType 1
_SalesOrganization _SalesOrganization 1 
@ClientHandling.algorithm: #SESSION_VARIABLE 
@VDM.viewType: #COMPOSITE
@AccessControl.authorizationCheck: #NOT_REQUIRED

@AbapCatalog: {
  sqlViewName: 'IALLWDORDTYP',
  preserveKey:true,
  compiler.compareFilter: true
}

@ObjectModel: {
  usageType: {
    serviceQuality: #A,
    sizeCategory : #S,
    dataClass: #MASTER
  }, 
  supportedCapabilities: [ #SQL_DATA_SOURCE,
                           #CDS_MODELING_DATA_SOURCE,
                           #CDS_MODELING_ASSOCIATION_TARGET ]
}

@Metadata.ignorePropagatedAnnotations:true
@EndUserText.label: 'Allowed Order Types per Sales Org'

define view I_AllwdOrdTypPerSlsOrg
  as select from I_MaintainedOrdTypePerSlsOrg as MaintainedOrdTypePerSlsOrg
  
  // Associations  

  association [0..1] to I_SalesOrganization   as _SalesOrganization   on $projection.SalesOrganization = _SalesOrganization.SalesOrganization
  association [0..1] to I_DistributionChannel as _DistributionChannel on $projection.DistributionChannel = _DistributionChannel.DistributionChannel
  association [0..1] to I_SalesDocumentType   as _SalesDocumentType   on $projection.SalesDocumentType = _SalesDocumentType.SalesDocumentType
  association [0..1] to I_Division            as _Division            on $projection.Division = _Division.Division
{
      @ObjectModel.foreignKey.association: '_SalesOrganization'
  key MaintainedOrdTypePerSlsOrg.SalesOrganization as SalesOrganization,
  
      @ObjectModel.foreignKey.association: '_DistributionChannel'
  key MaintainedOrdTypePerSlsOrg.DistributionChannel as DistributionChannel,
  
      @ObjectModel.foreignKey.association:'_Division'
  key MaintainedOrdTypePerSlsOrg.Division as Division,
  
      @ObjectModel.foreignKey.association:'_SalesDocumentType'
  key MaintainedOrdTypePerSlsOrg.SalesDocumentType as SalesDocumentType,
  
      _SalesOrganization,
      _DistributionChannel,
      _SalesDocumentType,
      _Division
}      
 
  union

  select from I_MaintainedOrdTypePerSlsOrg as MaintainedOrdTypePerSlsOrg  
  inner join I_SalesArea as SalesArea on MaintainedOrdTypePerSlsOrg.SalesOrganization   = SalesArea.RefSlsOrgForSlsDocType
                                     and MaintainedOrdTypePerSlsOrg.DistributionChannel = SalesArea.RefDistrChnlForSlsDocType
                                     and MaintainedOrdTypePerSlsOrg.Division            = SalesArea.RefDivisionForSlsDocType            
                  
  // Associations  

  association [0..1] to I_SalesOrganization   as _SalesOrganization   on $projection.SalesOrganization   = _SalesOrganization.SalesOrganization
  association [0..1] to I_DistributionChannel as _DistributionChannel on $projection.DistributionChannel = _DistributionChannel.DistributionChannel
  association [0..1] to I_SalesDocumentType   as _SalesDocumentType   on $projection.SalesDocumentType   = _SalesDocumentType.SalesDocumentType
  association [0..1] to I_Division            as _Division            on $projection.Division            = _Division.Division
{
      @ObjectModel.foreignKey.association: '_SalesOrganization'
  key SalesArea.SalesOrganization as SalesOrganization,
  
      @ObjectModel.foreignKey.association: '_DistributionChannel'
  key SalesArea.DistributionChannel as DistributionChannel,
  
      @ObjectModel.foreignKey.association:'_Division'
  key SalesArea.Division as Division,
  
      @ObjectModel.foreignKey.association:'_SalesDocumentType'
  key MaintainedOrdTypePerSlsOrg.SalesDocumentType as SalesDocumentType,
  
      _SalesOrganization,
      _DistributionChannel,
      _SalesDocumentType,
      _Division
}

Learn More