I_ADVNCDRETSMGMTPROCEXECSTATUS

CDS View

ARM Process Execution Status

I_ADVNCDRETSMGMTPROCEXECSTATUS is a CDS View in S/4HANA. ARM Process Execution Status. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
I_CustomerReturnProcessStep view union COMPOSITE Returns Order Item Process Step 
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality:  #C
@ObjectModel.usageType.sizeCategory: #L
@VDM.viewType: #COMPOSITE
@AccessControl: {
  authorizationCheck:#NOT_REQUIRED,
  personalData.blocking: #('TRANSACTIONAL_DATA')
  }
@AbapCatalog: {
  sqlViewName: 'IARMPROCEXECSTS',
  compiler.compareFilter: true
  }
@EndUserText.label: 'ARM Process Execution Status'

define view I_AdvncdRetsMgmtProcExecStatus
  as select from           I_AdvncdRetsMgmtCmpltProcSts as ProcgSts
    left outer to one join I_AdvncdRetsMgmtProcExecuted as Executed on  ProcgSts.RetsMgmtProcess                   = Executed.RetsMgmtProcess
                                                                    and ProcgSts.ReturnsDocument                   = Executed.ReturnsDocument
                                                                    and ProcgSts.RetsMgmtProcessItem               = Executed.RetsMgmtProcessItem
                                                                    and ProcgSts.RetsMgmtProcItmQtySplit           = Executed.RetsMgmtProcItmQtySplit
                                                                    and ProcgSts.RetsMgmtProcessStep               = Executed.RetsMgmtProcessStep
                                                                    and (
                                                                       (
                                                                         ProcgSts.ReturnsReferenceDocument         = Executed.ReturnsDocument
                                                                         and ProcgSts.ReturnsReferenceDocumentItem = Executed.ReturnsDocumentItem
                                                                       )
                                                                       or ProcgSts.ReturnsReferenceDocument        = ''
                                                                     )

{
      //Key

  key ProcgSts.RetsMgmtProcess,
  key ProcgSts.RetsMgmtProcessItem,
  key ProcgSts.RetsMgmtProcItmQtySplit,
  key ProcgSts.RetsMgmtProcessStep,

      //Reference Document

  key Executed.ReturnsReferenceDocumentType,
  key Executed.ReturnsReferenceDocument,
  key Executed.ReturnsReferenceDocumentItem,

      ProcgSts.ReturnsDocument,
      ProcgSts.RetsMgmtProcStepExecStatus,

      case when ProcgSts.RetsMgmtProcessStep = Executed.RetsMgmtProcessStep
        then 'X' -- ->'Execution of this step has already been started -> step contained in msr_d_executed'
        else '' -- ->'This step has not yet been executed  -> still has to be created'
      end  as RetsMgmtProcStepIsExecuted

}
where
  Executed.ReturnsDocumentStatus = ''

Learn More