I_AVAILABLECAPACITYSHIFT

CDS View

Available Capacity Shift

I_AVAILABLECAPACITYSHIFT is a CDS View in S/4HANA. Available Capacity Shift. It contains 14 fields. 5 CDS views read from this table.

Used by 5 CDS view(s) 14 fields

CDS Views using this table (5)

ViewTypeJoinVDMDescription
/VSCEW/A_WorkCenterShift view_entity from Workcenter shifts data
P_RSHAvailableCapacityShift view from CONSUMPTION Work Center Capacity Shifts
P_RSHWCCapacityDefinition view left_outer CONSUMPTION Work Center Capacity Definition
P_WorkCenterCapacityDefinition view left_outer COMPOSITE Work Center Capacity Definition
P_WrkCtrAvailableCapShift view_entity from COMPOSITE Work Center Available Capacity Shift

Fields (14)

KeyField CDS FieldsUsed in Views
KEY AvailableCapacityShift AvailableCapacityShift 1
KEY AvailableCapacityType AvailableCapacityType 1
KEY CapacityInternalID CapacityInternalID 1
KEY ValidityEndDate ShiftValidityEndDate,ValidityEndDate 2
KEY WeekDay WeekDay 1
BreakDurationInSeconds BreakDurationInSeconds 1
CapacityEndTimeID CapacityEndTimeID 1
CapacityNumberOfCapacities CapacityNumberOfCapacities 1
CapacityPlanUtilizationPercent CapacityPlanUtilizationPercent 1
CapacityStartTimeID CapacityStartTimeID 1
OperatingDurationInSeconds OperatingDurationInSeconds 1
ShiftDefinition ShiftDefinition 1
TotOperatingDurationInSeconds TotOperatingDurationInSeconds 1
WorkDayRule WorkDayRule 1 
@AbapCatalog.sqlViewName: 'IPPAVAILCAPSHIFT'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@Analytics.dataCategory: #DIMENSION
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.allowExtensions: true
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION
@ObjectModel.supportedCapabilities: [#ANALYTICAL_DIMENSION, #CDS_MODELING_ASSOCIATION_TARGET, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE]
@ObjectModel.representativeKey: 'AvailableCapacityShift'
@ObjectModel.usageType: {serviceQuality: #A, sizeCategory: #L, dataClass: #TRANSACTIONAL}
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #BASIC
@EndUserText.label: 'Available Capacity Shift'

/*+[hideWarning] { "IDS" : [ "CALCULATED_FIELD_CHECK", "KEY_CHECK" ]  } */
define view I_AvailableCapacityShift
  as select from kapa as kapa

  association [1..1] to I_Capacity              as _Capacity              on $projection.CapacityInternalID = _Capacity.CapacityInternalID
  association [1..1] to I_AvailableCapacityType as _AvailableCapacityType on $projection.AvailableCapacityType = _AvailableCapacityType.AvailableCapacityType
  association [1..1] to I_CalendarDate          as _EndDate               on $projection.ValidityEndDate = _EndDate.CalendarDate
  association [1..1] to I_WeekDay               as _WeekDay               on $projection.WeekDay = _WeekDay.WeekDay
  association [0..1] to I_WorkDayRule           as _WorkDayRule           on $projection.WorkDayRule = _WorkDayRule.WorkDayRule
  association [0..*] to I_ShiftDefinition       as _ShiftDefinition       on $projection.ShiftDefinition  = _ShiftDefinition.ShiftDefinition 
{
      @ObjectModel.foreignKey.association: '_Capacity'  
   key kapa.kapid as CapacityInternalID,
      @ObjectModel.foreignKey.association: '_AvailableCapacityType'
  key kapa.versn as AvailableCapacityType,
      @ObjectModel.foreignKey.association: '_EndDate'
  key kapa.datub as ValidityEndDate,
      @ObjectModel.foreignKey.association: '_WeekDay'
  key cast(substring (kapa.tagnr, 3, 1) as vdm_weekday) as WeekDay,
      -- representative key
  key kapa.schnr as AvailableCapacityShift,

      // Attributes

      kapa.anzhl as CapacityNumberOfCapacities,
      @ObjectModel.foreignKey.association: '_WorkDayRule'
      cast(kapa.fabtg as workdayrule preserving type) as WorkDayRule,
      kapa.tprog as ShiftDefinition,  

      // Times and Durations

      kapa.ngrad as CapacityPlanUtilizationPercent,
      kapa.begzt as CapacityStartTimeID,
      kapa.endzt as CapacityEndTimeID,
      kapa.einzt as OperatingDurationInSeconds,
      kapa.pause as BreakDurationInSeconds,
      kapa.kapaz as TotOperatingDurationInSeconds,

      // Associations

      _Capacity,
      _AvailableCapacityType,
      _EndDate,
      _WeekDay,
      _WorkDayRule,
      _ShiftDefinition
};

Learn More