A_WORKCENTERCAPPPLINEOP
Queued Operations Capacity
A_WORKCENTERCAPPPLINEOP is a CDS View in S/4HANA. Queued Operations Capacity. It contains 37 fields. 1 CDS views read from this table.
CDS Views using this table (1)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| A_WorkCenterCapDayOp | view | from | COMPOSITE | Daily Operations Capacity |
Fields (37)
| Key | Field | CDS Fields | Used in Views |
|---|---|---|---|
| KEY | CapacityInternalID | CapacityInternalID | 1 |
| KEY | CapacityRequirement | CapacityRequirement | 1 |
| KEY | Material | Material | 1 |
| KEY | MRPController | MRPController | 1 |
| KEY | Operation | Operation | 1 |
| KEY | OrderID | OrderID | 1 |
| KEY | Plant | Plant | 1 |
| KEY | WorkCenter | WorkCenter | 1 |
| BaseUnit | BaseUnit | 1 | |
| CapacityRequirementOrigin | CapacityRequirementOrigin | 1 | |
| CapacityRequirementsAreDtmnd | CapacityRequirementsAreDtmnd | 1 | |
| CapacityRequirementUnit | CapacityRequirementUnit | 1 | |
| OperationLatestEndDate | OperationLatestEndDate | 1 | |
| OperationLatestEndTime | OperationLatestEndTime | 1 | |
| OperationLatestStartDate | OperationLatestStartDate | 1 | |
| OperationLatestStartTime | OperationLatestStartTime | 1 | |
| OperationPlanningStatusCode | OperationPlanningStatusCode | 1 | |
| OperationPlanningStatusText | OperationPlanningStatusText | 1 | |
| OpLtstSchedldProcgStrtDte | OpLtstSchedldProcgStrtDte | 1 | |
| OpLtstSchedldProcgStrtTme | OpLtstSchedldProcgStrtTme | 1 | |
| OpLtstSchedldTrdwnStrtDte | OpLtstSchedldTrdwnStrtDte | 1 | |
| OpLtstSchedldTrdwnStrtTme | OpLtstSchedldTrdwnStrtTme | 1 | |
| OrderFirmingStatusText | OrderFirmingStatusText | 1 | |
| OrderInternalID | OrderInternalID | 1 | |
| OrderPlannedTotalQty | OrderPlannedTotalQty | 1 | |
| OrderStatusCode | OrderStatusCode | 1 | |
| OrderStatusText | OrderStatusText | 1 | |
| OrderType | OrderType | 1 | |
| OrderTypeName | OrderTypeName | 1 | |
| ProductionVersion | ProductionVersion | 1 | |
| RemainingCapReqOpSegProcgDurn | RemainingCapReqOpSegProcgDurn | 1 | |
| RemainingCapReqOpSegSetupDurn | RemainingCapReqOpSegSetupDurn | 1 | |
| RemainingCapReqOpSegTrdwnDurn | RemainingCapReqOpSegTrdwnDurn | 1 | |
| WorkCenterCategoryCode | WorkCenterCategoryCode | 1 | |
| WorkCenterDesc | WorkCenterDesc | 1 | |
| WorkCenterInternalID | WorkCenterInternalID | 1 | |
| WorkCenterResponsible | WorkCenterResponsible | 1 |
@AbapCatalog.sqlViewName: 'AWCCAPPPLINEOP'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #NOT_REQUIRED
@ObjectModel.usageType: {serviceQuality: #D, sizeCategory: #XL, dataClass: #TRANSACTIONAL}
@VDM.viewType: #COMPOSITE
@Metadata.ignorePropagatedAnnotations: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Queued Operations Capacity'
@VDM.lifecycle.contract.type:#PUBLIC_REMOTE_API
define view A_WorkCenterCapPplineOp as
select distinct from I_WorkCenterCapPplineOp as WrkCtrCapPplineOp
association [0..*] to A_WorkCenterCapOrderPerBucket as _WorkCenterOrders
on $projection.Plant = _WorkCenterOrders.Plant
and $projection.MRPController = _WorkCenterOrders.MRPController
and $projection.WorkCenter = _WorkCenterOrders.WorkCenter
and $projection.WorkCenterInternalID = _WorkCenterOrders.WorkCenterInternalID
and $projection.CapacityInternalID = _WorkCenterOrders.CapacityInternalID
and $projection.Material = _WorkCenterOrders.Material
association [0..*] to I_WorkCenterText as _WorkCenterText on $projection.WorkCenterInternalID = _WorkCenterText.WorkCenterInternalID
association [0..*] to I_PlannedOrderTypeText as _PlannedOrderText on $projection.OrderType = _PlannedOrderText.PlannedOrderType
association [0..*] to I_OrderTypeText as _WorkOrderText on $projection.OrderType = _WorkOrderText.OrderType
association [0..*] to I_OrderCategoryText as _WorkOrderCategoryText on $projection.OrderCategory = _WorkOrderCategoryText.OrderCategory
association [0..*] to I_PlannedOrderCategoryText as _PlannedOrderCategoryText on $projection.OrderCategory = _PlannedOrderCategoryText.PlannedOrderCategory
association [0..*] to I_CapEvalCapRqmtStsText as _OprPlanningText on $projection.OperationPlanningStatusCode = _OprPlanningText.CapacityRequirementStatusCode
association [0..*] to I_SystemStatusText as _OrderStatusText on $projection.OrderStatusCode = _OrderStatusText.SystemStatus
association [0..*] to I_CapEvalFirmingStsText as _FirmingStatusText on WrkCtrCapPplineOp.OrderFirmingStatusCode = _FirmingStatusText.OrderFirmingStatusCode
{
key WrkCtrCapPplineOp.Plant,
key WrkCtrCapPplineOp.MRPController,
key WrkCtrCapPplineOp.WorkCenter,
key WrkCtrCapPplineOp.CapacityInternalID,
key WrkCtrCapPplineOp.CapacityRequirement,
key WrkCtrCapPplineOp.Material,
key WrkCtrCapPplineOp.OrderID,
key WrkCtrCapPplineOp.Operation,
_WorkCenterText[1:Language=$session.system_language].WorkCenterText as WorkCenterDesc,
WrkCtrCapPplineOp.WorkCenterResponsible,
WrkCtrCapPplineOp.WorkCenterCategoryCode,
WrkCtrCapPplineOp.WorkCenterInternalID,
WrkCtrCapPplineOp.CapacityRequirementOrigin,
@Semantics.unitOfMeasure: true
WrkCtrCapPplineOp.CapacityRequirementUnit,
WrkCtrCapPplineOp.OrderType,
case WrkCtrCapPplineOp.CapacityRequirementOrigin
when '1'
then _WorkOrderText[1:Language=$session.system_language].OrderTypeName
when '2'
then _PlannedOrderText[1:Language=$session.system_language].PlannedOrderTypeName
else ''
end as OrderTypeName,
WrkCtrCapPplineOp.OrderCategory,
case WrkCtrCapPplineOp.CapacityRequirementOrigin
when '1'
then _WorkOrderCategoryText[1:Language=$session.system_language].OrderCategoryName
when '2'
then _PlannedOrderCategoryText[1:Language=$session.system_language].PlannedOrderCategoryName
else ''
end as OrderCategoryName,
@Semantics.unitOfMeasure: true
cast(WrkCtrCapPplineOp.BaseUnit as meins) as BaseUnit,
@Semantics.quantity.unitOfMeasure: 'BaseUnit'
WrkCtrCapPplineOp.OrderPlannedTotalQty,
WrkCtrCapPplineOp.ProductionVersion,
WrkCtrCapPplineOp.OperationPlanningStatusCode,
_OprPlanningText[1:Language=$session.system_language].CapacityRequirementStatusText as OperationPlanningStatusText,
cast(WrkCtrCapPplineOp.OperationLatestStartDate as char8) as OperationLatestStartDate,
cast(WrkCtrCapPplineOp.OperationLatestStartTime as char6) as OperationLatestStartTime,
cast(WrkCtrCapPplineOp.OperationLatestEndDate as char8) as OperationLatestEndDate,
cast(WrkCtrCapPplineOp.OperationLatestEndTime as char6) as OperationLatestEndTime,
WrkCtrCapPplineOp.OrderStatusCode,
_OrderStatusText[1:Language=$session.system_language].SystemStatusName as OrderStatusText,
_OrderStatusText[1:Language=$session.system_language].SystemStatusShortName as OrderStatusShortText,
cast(WrkCtrCapPplineOp.OrderFirmingStatusCode as char1) as OrderFirmingStatusCode,
_FirmingStatusText[1:Language=$session.system_language].OrderFirmingStatusText as OrderFirmingStatusText,
cast(WrkCtrCapPplineOp.OpLtstSchedldProcgStrtDte as char8) as OpLtstSchedldProcgStrtDte,
cast(WrkCtrCapPplineOp.OpLtstSchedldProcgStrtTme as char6) as OpLtstSchedldProcgStrtTme,
cast(WrkCtrCapPplineOp.OpLtstSchedldTrdwnStrtDte as char8) as OpLtstSchedldTrdwnStrtDte,
cast(WrkCtrCapPplineOp.OpLtstSchedldTrdwnStrtTme as char6) as OpLtstSchedldTrdwnStrtTme,
@Semantics.quantity.unitOfMeasure: 'CapacityRequirementUnit'
WrkCtrCapPplineOp.RemainingCapReqOpSegSetupDurn,
@Semantics.quantity.unitOfMeasure: 'CapacityRequirementUnit'
WrkCtrCapPplineOp.RemainingCapReqOpSegProcgDurn,
@Semantics.quantity.unitOfMeasure: 'CapacityRequirementUnit'
WrkCtrCapPplineOp.RemainingCapReqOpSegTrdwnDurn,
WrkCtrCapPplineOp.CapacityRequirementsAreDtmnd,
@Semantics.quantity.unitOfMeasure: 'CapacityRequirementUnit'
WrkCtrCapPplineOp.CapacityRequirementsAreDtmnd as RemainingCapReqExecutionDurn,
WrkCtrCapPplineOp.OrderInternalID,
_WorkCenterOrders
}
where WrkCtrCapPplineOp.Sequence = '000000'or
WrkCtrCapPplineOp.OrderCategory = '30'