ARS_APIS_RELEASED_C1_OR_GROUPS

//*************************************************

// The view returns objects that have been released for the C1 contract or are in an available release group.

//

// Element Definition:

//   - TADIR_OBJECT: Object directory type of the released object as defined in table TADIR (example: DDLS for a Data Definition)

//   - TADIR_OBJ_NAME: Object directory name of the released object as defined in table TADIR (example: I_CURRENCY)

//   - OBJECT_TYPE: Sub-object type of the released object (example: CDS_STOB for a CDS Entity)

//     These sub-object types are defined in object type group RELEASABLE_OBJECT_TYPES (transaction SOTG)

//   - OBJECT_KEY: Sub-object name of the releasd object (example: I_Currency)

//   - STATE: Release state, with the values

//       'RELEASED'   Released   (available as IF_ARS_API_CONSTANTS=>CS_STATE-RELEASED)

//       'DEPRECATED' Deprecated (available as IF_ARS_API_CONSTANTS=>CS_STATE-DEPRECATED)

//     If the state is RELEASED, then

//       - consumption of the object is allowed

//     If the state is DEPRECATED, then

//       - new consumptions of the object are forbidden

//       - existing consumptions are syntactically still correct

//       - and the object behaves as before

//   - STATE_DESCRIPTION: State description

//   - SUCCESSOR_CLASSIFICATION: Successor classification for deprecated objects, with the values

//       '0'  None     (available as IF_ARS_API_CONSTANTS=>CS_SUCCESSOR_CLASSIFICATION-NONE)

//       '1'  One      (available as IF_ARS_API_CONSTANTS=>CS_SUCCESSOR_CLASSIFICATION-ONE)

//       'N'  Multiple (available as IF_ARS_API_CONSTANTS=>CS_SUCCESSOR_CLASSIFICATION-MULTIPLE)

//   The following fields are filled only if a deprecated object has exactly one successor (i.e. SUCCESSOR_CLASSIFICATION = '1'):

//   - SUCCESSOR_TADIR_OBJECT: type of main object of the successor object as defined in the TADIR table,

//   - SUCCESSOR_TADIR_OBJECT_NAME: key of the successor object. Together with SUCCESSOR_TADIR_OBJECT, identifies a successor object uniquely,

//   - SUCCESSOR_OBJECT_TYPE: type of the subobject of the successor object,

//   - SUCCESSOR_OBJECT_KEY: key of the subobject of the successor object. Together with SUCCESSOR_OBJECT_TYPE, identifies a successor subobject uniquely.

//   If there are multiple successors, they need to be retrieved using CDS view ARS_API_SUCCESSORS_FOR_C1

//*************************************************

@AbapCatalog.sqlViewName: 'ARS_API_C1_GRPS'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_ALLOWED
@EndUserText.label: 'APIs Released for C1 Contract or Groups'
define view ARS_APIS_RELEASED_C1_OR_GROUPS
  as select from ARS_APIS_RELEASED_FOR_C1 as api
{
  api.tadir_object,
  api.tadir_obj_name,
  api.object_type,
  api.object_key,
  cast(api.state as abap.char(184)) as state,
  api.state_description,
  api.successor_classification,
  api.successor_tadir_object,
  api.successor_tadir_obj_name,
  api.successor_object_type,
  api.successor_object_key,
  api.decommissioning_date
}

union select distinct from ARS_APIS as api
association [0..1] to ARS_RELEASE_STATE_DESCRIPTIONS as _text on _text.state = 'RELEASED'
{
  api.tadir_object,
  api.tadir_obj_name,
  api.object_type,
  api.object_key,
  'RELEASED'        as state,
  _text.description as state_description,
  ''                as successor_classification,
  ''                as successor_tadir_object,
  ''                as successor_tadir_obj_name,
  ''                as successor_object_type,
  ''                as successor_object_key,
  ''                as decommissioning_date
}
where
       api.attribute = 'RELEASE_GROUP'
  and(
       api.value     = 'YY1_'
    or api.value     = 'YY2_'
    or api.value     = 'YY3_'
    or api.value     = 'ZZ1_'
    or api.value     = 'DEFAULT'
  )