ARS_ADT_ACTIVE_APIS

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_ALLOWED
@EndUserText.label: 'sdfdsfdsf'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #X,
  sizeCategory: #S,
  dataClass: #MIXED
}
define view entity ARS_ADT_ACTIVE_APIS
  // Objects without API catalog assignment

  as select from    ARS_RUNTIME_API_STATE      as api
    left outer join ARS_API_CATALOG_ASSIGNMENT as assignment on  assignment.tadir_object   = api.object_type
                                                             and assignment.tadir_obj_name = api.object_name
                                                             and assignment.object_type    = api.sub_object_type
                                                             and assignment.object_key     = api.sub_object_name
{
  key api.object_type,
  key api.object_name,
  key api.sub_object_type,
  key api.sub_object_name,
  key api.compatibility_contract,
      api.release_state,
      api.use_in_key_user_apps,
      api.use_in_sap_cloud_platform
}
where
  assignment.api_catalog_id is null

// Objects with API catalog assignment, where the API catalog has state ON

union all select from ARS_RUNTIME_API_STATE        as api
  inner join          ARS_API_CAT_OBJECTS_STATE_ON as assignment on  assignment.object_type     = api.object_type
                                                                 and assignment.object_name     = api.object_name
                                                                 and assignment.sub_object_type = api.sub_object_type
                                                                 and assignment.sub_object_name = api.sub_object_name
{
  key api.object_type,
  key api.object_name,
  key api.sub_object_type,
  key api.sub_object_name,
  key api.compatibility_contract,
      api.release_state,
      api.use_in_key_user_apps,
      api.use_in_sap_cloud_platform
}