v_dpr_bp_entity_view

@AbapCatalog.sqlViewName: 'V_DPR_BP_ENTITY'

@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #MASTER

@EndUserText.label: 'Generic entities for business partner guid'
define view v_dpr_bp_entity_view as
  
  --Abstract Role logic
  select from dpr_bupa_link   as dp
   inner join cgpl_hierarchy  as ch on dp.participant_guid = ch.guid
   inner join dpr_entity_link as el on el.participant_guid = ch.up
   {
    ch.up as participant_guid,
    el.entity_guid,
    el.responsible,
    dp.bupa_guid,
    el.entity_type,
    el.client,
    dp.planstart,
    dp.planfinish
   }
  
  union
  --Concrete Role logic
  select from dpr_bupa_link   as dp
   inner join dpr_entity_link as el on el.participant_guid = dp.participant_guid
   {
    el.participant_guid as participant_guid,
    el.entity_guid,
    el.responsible,
    dp.bupa_guid,
    el.entity_type,
    el.client,
    dp.planstart,
    dp.planfinish
   }  
  
 /*+[internal] {
"BASEINFO":
{
"FROM":
[
"CGPL_HIERARCHY",
"DPR_BUPA_LINK",
"DPR_ENTITY_LINK"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"VERSION":0
}
}*/