m_v_inforecord_sos

@ClientDependent
@AbapCatalog.sqlViewName: 'CDS_M_INFREC_SOS'
@EndUserText.label: 'MM-PUR: CDS View for SOS'
@AccessControl.authorizationCheck: #CHECK

@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #MIXED

@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA')

/***********************************************************************************************************/
/*   MM-PUR: Purchasing Info Record for MRP                                                                      */
/***********************************************************************************************************/
define view m_v_inforecord_sos
  as

  select from       M_V_Inforecord_Basic as eina
    inner join      eine                 as eine on eine.infnr = eina.infnr
    inner join      marc                 as marc on eina.matnr = marc.matnr
                                                 and(
      marc.werks                                               = eine.werks
      or eine.werks                                            = ''
    ) --EINE w/o WERKS is valid in all plants of the material
    inner join      scal_tt_date         as d    on  eina.lifab <= d.calendardate
                                                 and eina.lifbi >= d.calendardate
    left outer join eord                 as eord on  eord.vdatu <= d.calendardate
                                                 and eord.bdatu >= d.calendardate
                                                 and eina.lifnr =  eord.lifnr
                                                 and eina.matnr =  eord.matnr
                                                 and marc.werks =  eord.werks
                                                 and eord.ebeln =  ''
    inner join      lfa1                 as lfa1 on eina.lifnr = lfa1.lifnr
    inner join      lfm1                 as lfm1 on  eina.lifnr = lfm1.lifnr
                                                 and eine.ekorg = lfm1.ekorg
{

  eina.matnr                                    as matnr,
  marc.werks                                    as werks,
  eina.lifnr,
  d.calendardate                                as validitydate,
  eina.infnr,
  cast(coalesce (eord.ebeln,'') as evrtn)       as ebeln,
  cast(coalesce (eord.ebelp,'00000') as evrtp)  as ebelp,
  cast(coalesce (eord.zeord,'00000') as dzeord) as zeord,
  cast(case
    when eord.autet is null
      then eine.aut_source
    else
      case
        when eord.autet = '' then ''
        else 'X'
      end
  end as aut_source)                            as aut_source,
  cast(coalesce (eord.notkz,'') as ordsp)       as notkz,
  case eine.minbm
    when 0 then eine.minbm
    else
     case eina.umren
       when 0 then eine.minbm
       else division((eine.minbm * eina.umrez), eina.umren, 3)
     end
  end                                           as bstmi,
  case eine.bstma
    when 0 then cast('9999999999' as abap.dec(13,3))
    else
     case eina.umren
       when 0 then eine.bstma
       else division((eine.bstma * eina.umrez), eina.umren, 3)
     end
  end                                           as bstma,
  cast('I' as bstyp)                            as bstyp,
  cast('' as pstyp)                             as pstyp,
  eine.ekorg                                    as ekorg,
  eine.ekgrp                                    as ekgrp,
  eine.esokz                                    as esokz,
  cast('' as lgort_d)                           as lgort,
  cast ('' as reswk)                            as reswk,
  cast ('' as reslo)                            as reslo,
  marc.webaz                                    as webaz,
  eine.aplfz                                    as plifz,
  eine.verid                                    as verid,
  cast (coalesce (eord.flifn,'') as flifn)      as flifn,
  cast('' as emlif)                             as emlif,
  cast('' as lblkz)                             as lblkz,
  cast('' as lphis)                             as lphis,
  eine.rdprf                                    as rdprf,
  eine.netpr                                    as netpr,
  eine.waers                                    as waers,
  eine.peinh                                    as peinh,
  cast (coalesce (eord.eortp,'') as eortp)      as eortp,
  cast (coalesce (eord.meins,'') as bstme)      as meins,
  cast (coalesce (eord.sobkz,'') as sobkz)      as sobkz,
  case eine.werks
    when '' then cast( 2 as abap.int1 )
    else cast( 1 as abap.int1 )
  end                                           as priority
}
where
      eina.loekz =  ''
  and eine.loekz =  ''
  and lfa1.loevm =  ''
  and lfm1.loevm =  ''
  and lfa1.sperm =  ''
  and lfm1.sperm =  ''
  and eina.matnr <> ''                
 /*+[internal] {
"BASEINFO":
{
"FROM":
[
"M_V_INFORECORD_BASIC",
"EINE",
"EORD",
"LFA1",
"LFM1",
"MARC",
"SCAL_TT_DATE"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/