fiscds_mref_doc_01

@AbapCatalog.sqlViewName: 'FISV_MREF_DOC_01'
@EndUserText.label: 'Document with Multi-Referenced Invoice'
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL

define view fiscds_mref_doc_01
  as select from fiscds_mref_invoice as a
    inner join            bkpf                as b on  a.bukrs = b.bukrs
                                                   and a.gjahr = b.gjahr
                                                   and a.xblnr = b.xblnr
    inner join            I_GLAccountLineItem      as c on  b.bukrs = c.CompanyCode
                                                   and b.gjahr = c.LedgerFiscalYear
                                                   and b.belnr = c.AccountingDocument
  {
    a.bukrs,
    a.gjahr,
    a.xblnr,
    c.Ledger                                            as rldnr,
    c.SourceLedger                                      as rldnr_pers,
    c.LedgerGLLineItem                                  as docln,
    b.belnr,
    c.FinancialAccountType                              as koart,
    b.bldat,
    b.blart,
    b.cpudt as CreationDate,
    b.budat,
    c.AssignmentReference                               as zuonr,
    c.AccountingDocCreatedByUser                        as usnam,
    c.PostingKey                                        as bschl,
    c.AmountInCompanyCodeCurrency                       as hsl,
    c.CompanyCodeCurrency                               as rhcur,
    c.AmountInTransactionCurrency                       as wsl,
    c.TransactionCurrency                               as rwcur,
    c.AmountInFunctionalCurrency,
    c.FunctionalCurrency,
    c.ChartOfAccounts                                   as ktopl,
    c.GLAccount                                         as racct,
    c.SpecialGLCode                                     as umskz,
    case c.FinancialAccountType
        when 'D' then c.Customer
        when 'K' then c.Supplier
    end                                                                      as wakonto,
    b.stblg,
    b.stgrd
  }
  where
         b.stblg = ''
    and(
         c.FinancialAccountType = 'D'
      or c.FinancialAccountType = 'K'
    )

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"FISCDS_MREF_INVOICE",
"I_GLACCOUNTLINEITEM",
"BKPF"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/