fins_rev_rec_alloc

@AbapCatalog.sqlViewName: 'FINS_RR_ALLOC'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Read data from FINS_TRR_ALLOC'

@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #MIXED

//View which reads allocation data for bundled sales document item

//Selects from FINS_TRR_ALLOC and VBAP / DFKK_VT_I


define view fins_rev_rec_alloc
  as select
    a.sales_order,
    a.sales_order_item,
    a.project,
    a.wbs_element,
    a.vtkey,
    a.vtpos,
    a.solution_order_id,
    @Semantics.currencyCode
    a.currency,
    p.ifrs15_relevance as bundling_indicator,
    @Semantics.amount.currencyCode: 'a.currency'
    sum(a.trans_price) as trans_price,
    @Semantics.amount.currencyCode: 'a.currency'
    sum(a.ssp)         as ssp,
    @Semantics.amount.currencyCode: 'a.currency'
    sum(a.alloc_revn)  as alloc_revn,
    @Semantics.amount.currencyCode: 'a.currency'
    sum(a.billed_revn) as billed_revn
  from         fins_trr_alloc as a
    inner join vbap           as p on  p.vbeln = a.sales_order
                                   and p.posnr = a.sales_order_item
  group by
    a.sales_order,
    a.sales_order_item,
    a.project,
    a.wbs_element,
    a.vtkey,
    a.vtpos,
    a.solution_order_id,
    a.currency,
    p.ifrs15_relevance

  union all select
    a.sales_order,
    a.sales_order_item,
    a.project,
    a.wbs_element,
    a.vtkey,
    a.vtpos,
    a.solution_order_id,
    @Semantics.currencyCode
    a.currency,
    pci.bundling       as bundling_indicator,
    @Semantics.amount.currencyCode: 'a.currency'
    sum(a.trans_price) as trans_price,
    @Semantics.amount.currencyCode: 'a.currency'
    sum(a.ssp)         as ssp,
    @Semantics.amount.currencyCode: 'a.currency'
    sum(a.alloc_revn)  as alloc_revn,
    @Semantics.amount.currencyCode: 'a.currency'
    sum(a.billed_revn) as billed_revn
  from         fins_trr_alloc as a
    inner join dfkk_vt_i      as pci on  pci.vtkey = a.vtkey
                                     and pci.vtpos = a.vtpos
  group by
    a.sales_order,
    a.sales_order_item,
    a.project,
    a.wbs_element,
    a.vtkey,
    a.vtpos,
    a.solution_order_id,
    a.currency,
    pci.bundling;
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"DFKK_VT_I",
"FINS_TRR_ALLOC",
"VBAP"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/