fac_cds_fh

@AbapCatalog.sqlViewName: 'FACV_FH'
//@AbapCatalog.compiler.compareFilter: true

@AccessControl.authorizationCheck: #CHECK
///@AccessControl.authorizationCheck: #CHECK

@AccessControl.privilegedAssociations:  [ '_Node' ]
@EndUserText.label: 'Flexible Hierarchy'

@ObjectModel.usageType: {
  dataClass: #MASTER,
  serviceQuality: #D,
  sizeCategory: #XL
}
@Search.searchable: true
@ObjectModel.representativeKey: 'FlexibleHierarchy'

define view fac_cds_fh
  as select from    hrrp_dir_n
    inner join      flexhier_dir on  hrrp_dir_n.hryid_42 = flexhier_dir.hryid
                                 and hrrp_dir_n.hryvalto = flexhier_dir.hryvalto
                                 and hrrp_dir_n.mandt    = flexhier_dir.mandt
                                 and hrrp_dir_n.mandt    = $session.client
    left outer join hrrp_typt    on  hrrp_dir_n.hrytyp = hrrp_typt.hrytyp
                                 and hrrp_typt.spras   = $session.system_language
  association [1..*] to fac_cds_fht     as _Text on  hrrp_dir_n.hryid_42 = _Text.FlexibleHierarchy
                                                 and hrrp_dir_n.hryvalto = _Text.ValidityEndDate

  association [0..*] to fac_cds_fh_node as _Node on  $projection.FlexibleHierarchy = _Node.FlexibleHierarchy
                                                 and $projection.ValidityEndDate   = _Node.ValidityEndDate
{
         @Search: { defaultSearchElement:  true, ranking: #HIGH, fuzzinessThreshold: 0.8 }
         //@ObjectModel.text.association: 'FlexibleHierarchyName'

         @ObjectModel.text.element: ['FlexibleHierarchyName']
  key    hrrp_dir_n.hryid_42                                                as FlexibleHierarchy,
         @VDM.lifecycle.status:    #DEPRECATED
  key    cast( '000000000000001' as hryversn preserving type )              as HierarchyVersion,
  key    hrrp_dir_n.hryvalto                                                as ValidityEndDate,

         hrrp_dir_n.hrysid                                                  as HierarchyShortID,
         hrrp_dir_n.hryvalfrom                                              as ValidityStartDate,
         hrrp_dir_n.hrytyp                                                  as HierarchyType,
         hrrp_dir_n.upduser                                                 as LastChangedByUser,
         @Consumption.filter.selectionType:#INTERVAL
         hrrp_dir_n.updtime                                                 as LastChangeTime,
         flexhier_dir.fhcrtnuser                                            as CreatedByUser,
         flexhier_dir.fhcrtntime                                            as CreationTime,
         flexhier_dir.fhsequence                                            as HierarchyRawSequence,
         flexhier_dir.fhfilter                                              as HierarchyRawFilter,
         hrrp_typt.text                                                     as HierarchyTypeText,
         @Search: { defaultSearchElement:  true, ranking: #LOW, fuzzinessThreshold: 0.8}
         _Text[1:Language = $session.system_language].FlexibleHierarchyName as FlexibleHierarchyName,
         _Node
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"FAC_CDS_FHT",
"FLEXHIER_DIR",
"HRRP_DIR_N",
"HRRP_TYPT"
],
"ASSOCIATED":
[
"FAC_CDS_FHT",
"FAC_CDS_FH_NODE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/