atov_calm_release_status

@AbapCatalog.sqlViewName: 'ATO_V_CALM_RELE'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Release status of ATO transports for CALM'
define view atov_calm_release_status
  as select from ato_cmn_requests as cmn_request
    inner join   e070v            as request on request.trkorr = cmn_request.request
{
  cmn_request.request                                  as collection_id,
  cast( 1 as ato_collection_version )                  as version,
  cmn_request.ato_cmn_transport_type                   as transport_type,

  cast(
    case request.trstatus
    when 'R' then 'RELEASED'
    when 'N' then 'RELEASED'
    else 'MODIFIABLE'
    end as ato_deploy_action_status )                  as status,

  cmn_request.changed_at                               as last_changed_at, //TODO: AS4DATE and AS4TIME from E070V instead?

  request.as4user                                      as last_changed_by,
  cast( request.as4text as ato_collection_description) as description
}
where
  cmn_request.ato_cmn_transport_type <> 'EXT'

union all select from ato_col_versions as col_Version
  inner join          ato_cols         as collection on collection.collection_id = col_Version.collection_id
{
  col_Version.collection_id,
  col_Version.version,
  cast( 'EXT' as ato_cmn_transport_type ) as transport_type,

  cast (
    case col_Version.status
    when 'E' then 'RELEASED'
    else 'MODIFIABLE'
    end as ato_deploy_action_status )     as status,

  col_Version.last_changed_at,
  col_Version.last_changed_by,
  collection.description_text             as description
}
where
  col_Version.timestamp = 0
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"ATO_CMN_REQUESTS",
"ATO_COLS",
"ATO_COL_VERSIONS",
"E070V"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/