UPO_INT_WCVD_UOM

@AbapCatalog.sqlViewName: 'UPOS_WCVD_UOM'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.serviceQuality: #X
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #MASTER
@EndUserText.label: 'Integration view for WCVD'
define view UPO_INT_WCVD_UOM
  as select distinct from UPOV_COMMINGLED_WC as commingled
    inner join            upot_int_nobj      as WL_Label    on WL_Label.converted_label = commingled.wl_no
    inner join            gho_iflot_ext      as wellID      on wellID.gho_wc_ref_id = WL_Label.tplnr
    inner join            upot_int_no_vd     as upo_no_vd   on upo_no_vd.tplnr = wellID.tplnr
    left outer join       upoc_int_sts_cde   as status_code on  status_code.netobj_type      = upo_no_vd.gho_netobj_type
                                                            and status_code.netobj_stat_code = upo_no_vd.netobj_status
{

  key cast(commingled.wl_no as oiu_wl_no)                  as WL_NO,
  key upo_no_vd.wc_no                                      as WC_NO,
      upo_no_vd.tplnr,
      tstmp_to_dats(upo_no_vd.effective_from,
                       'UTC',
                       $session.client,'NULL')             as EFF_FROM_DT,

      tstmp_to_dats(upo_no_vd.effective_to,
                         'UTC',
                         $session.client,'NULL')           as EFF_TO_DT,
      upo_no_vd.gho_netobj_type,
      cast(' '   as oib_hvcls)                             as HVCLS, //Heating value class (calorific value class)

      cast(' '   as oiu_crud_type_cd)                      as CRUD_TYPE_CD, //Crude type code

      upo_no_vd.op_fl                                      as OP_FL, //Operated flag

      cast(' '   as oiu_cyc_contn_fl)                      as CONTN_FL, //Continuous Flag

      cast('0000000000'   as oiu_wl_count)                 as WL_COUNT, //Well count

      upo_no_vd.prd_mth_cd                                 as PRD_MTH_CD, //Producing method code

      cast( upo_no_vd.gho_wellclass_id as oiu_wl_class_cd) as WL_CLASS_CD, //Well class code

      upo_no_vd.bukrs                                      as BUKRS, //Company Code

      upo_no_vd.cost_centre                                as COST_CENTER, //PRA Cost Center

      upo_no_vd.operator                                   as OPERATOR, //Operator

      cast( status_code.status_cd_pra as oiu_wc_status_cd) as STATUS_CD,
      cast('' as ps_posnr)                                 as PSPNR, //WBS Element

      cast(0   as oiu_ext_loss_pc)                         as EXT_LOSS_PC, //Ext. Loss Percentage

      ''                                                   as OIU_CRUSER, //Name of Person who Created the Object

      cast('0' as tzntstmps)                               as OIU_TIMESTAMP //UTC Time Stamp in Short Form (YYYYMMDDhhmmss)



}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"UPOV_COMMINGLED_WC",
"GHO_IFLOT_EXT",
"UPOC_INT_STS_CDE",
"UPOT_INT_NOBJ",
"UPOT_INT_NO_VD"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/