UPOV_PR_PF

@AbapCatalog.sqlViewName: 'UPOS_PR_PF'
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.serviceQuality: #X
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #MASTER
@EndUserText.label: 'Platform'
// get non-migrated PRA platforms

define view UPOV_PR_PF as select from    UPOV_PR_PF_PRA   as nonmig_platforms
  left outer join upot_int_entity  as Platform_No on  Platform_No.converted_label = nonmig_platforms.pf_no
                                                    and Platform_No.gho_pe_type = 'PLATFORM'
{
  key nonmig_platforms.pf_no,
      nonmig_platforms.first_prd_dt,
      nonmig_platforms.instl_dt,
      nonmig_platforms.pf_name,
      nonmig_platforms.shtxt,
      nonmig_platforms.lat_no,
      nonmig_platforms.lat_dir_cd,
      nonmig_platforms.lng_no,
      nonmig_platforms.lng_dir_cd,
      nonmig_platforms.rte_u,
      nonmig_platforms.rte,
      nonmig_platforms.type_cd,
      nonmig_platforms.watr_dph_u,
      nonmig_platforms.watr_dph,
      nonmig_platforms.location_cd,
      nonmig_platforms.pf_grp,
      nonmig_platforms.docnr,
      nonmig_platforms.docyr,
      nonmig_platforms.oiu_cruser,
      nonmig_platforms.oiu_timestamp
}
where
 Platform_No.converted_label is null
union
select from  UPOV_PR_PF_UOM
{
  key PF_NO,        //Platform No

      FIRST_PRD_DT, //First Production Date

      INSTL_DT,     //Installation Date

      PF_NAME,      //Platform Name

      SHTXT,        //Description

      LAT_NO,       //Latitude Number

      LAT_DIR_CD,   //Latitude Direction Code

      LNG_NO,       //Longitude

      LNG_DIR_CD,   //Longitude Direction Code

      RTE_U,        //Rotary Table Elevation Unit

      RTE,          //Rotary Table Elevation

      TYPE_CD,      //Platform Type

      WATR_DPH_U,   //Water Depth Unit

      WATR_DPH,     //Water Depth

      LOCATION_CD,  //Location CD

      PF_GRP,       //Platform Group

      DOCNR,        //Platform Document No

      DOCYR,        //Document Years

      OIU_CRUSER,   // Name of Person Who Created Object

      OIU_TIMESTAMP // UTC Time Stamp in Short Form (YYYYMMDDhhmmss)

}     
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"UPOV_PR_PF_PRA",
"UPOV_PR_PF_UOM",
"UPOT_INT_ENTITY"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/