S_POWorkFlowRecipientVH

@AbapCatalog.sqlViewName: 'SPOPPWFL'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@Search.searchable: true
@EndUserText.label: 'People Picker for Purchase Order Approver'
@ObjectModel: {
    semanticKey: 'UserID',
    representativeKey: 'UserID',
    usageType.serviceQuality: #C,
    usageType.sizeCategory: #L,
    usageType.dataClass: #MIXED
}
define view S_POWorkFlowRecipientVH
  as select distinct from I_BusinessUser  as _User   
 inner join I_WorkforcePerson             as _WorkforcePerson     on _WorkforcePerson.BusinessPartnerUUID   = _User.BusinessPartnerUUID
 inner join I_PersonWorkAgreement_1       as _PersonWorkAgreement on _PersonWorkAgreement.Person            =  _WorkforcePerson.Person
 inner join I_PersonWorkAgrmtOrglDetails  as _EmployOrgDet        on _EmployOrgDet.PersonWorkAgreement      = _PersonWorkAgreement.PersonWorkAgreement 
 inner join I_PersonWorkAgrmtStatus       as _EmployStatDet       on  _EmployOrgDet.PersonWorkAgreement     = _EmployStatDet.PersonWorkAgreement
                                                                  and _EmployStatDet.StartDate              <= _EmployOrgDet.EndDate
                                                                  and _EmployStatDet.EndDate                >= _EmployOrgDet.StartDate
  association [0..1] to S_POUsersToAuthProfile as _PotentialApprovers on _User.UserID = _PotentialApprovers.UserID

{
   @ObjectModel.text.element: 'FullName'
   @Search: { defaultSearchElement: true, ranking: #MEDIUM }
   key _User.UserID                      as UserID,
   @Semantics.text: true
   @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.7 }
   _User.PersonFullName                  as FullName,
   @Semantics.text: true
   @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.7 }
   _User.PersonFullName                  as EmployeeFullName,
   cast( _User.BPIdentificationNumber    as mmpur_employee_id ) as Employee,
   _PotentialApprovers
}
where _EmployOrgDet.StartDate          <= $session.system_date
  and _EmployOrgDet.EndDate            >= $session.system_date
  and _EmployStatDet.WorkAgreementStatus = '1'   
  and _User.IsBusinessPurposeCompleted = ''
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BUSINESSUSER",
"I_PERSONWORKAGREEMENT_1",
"I_PERSONWORKAGRMTORGLDETAILS",
"I_PERSONWORKAGRMTSTATUS",
"I_WORKFORCEPERSON"
],
"ASSOCIATED":
[
"S_POUSERSTOAUTHPROFILE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/