R_WrntyClaimVersionTP

@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Warranty Claim Version Processing'
@VDM:{
      viewType: #TRANSACTIONAL,
      lifecycle.contract.type: #SAP_INTERNAL_API
}
@ObjectModel:{
  representativeKey: 'WrntyVersionUUID',
  usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #L
   }
}

@AbapCatalog.extensibility: {
  extensible: true,
  elementSuffix: 'WTV',
  allowNewDatasources: false,
  dataSources: ['_ExtensionWrntyVers'],
  quota: {
    maximumFields: 238,
    maximumBytes: 2240
  }
}
define view entity R_WrntyClaimVersionTP
  as select from I_WrntyClaimVersion
  composition [1..*] of R_WrntyClaimItemTP             as _WrntyClaimItem
  composition [1..*] of R_WrntyClaimVersionPricingTP   as _WrntyClaimVersionPricing
  association        to parent R_WrntyClaimTP                 as _WrntyClaimHeader on  $projection.WrntyClaimHeaderUUID = _WrntyClaimHeader.WrntyClaimHeaderUUID
  association [0..1] to P_WrntySuplrClaimVersionMax    as _maxSuplrVersion         on  _maxSuplrVersion.WrntyClaimHeaderUUID = $projection.WrntyClaimHeaderUUID
                                                                                   and _maxSuplrVersion.WrntyVersionNumber   = $projection.WrntyVersionNumber
  association [0..1] to P_WarrantyCustClaimVersionMax  as _maxCustVersion          on  _maxCustVersion.WrntyClaimHeaderUUID = $projection.WrntyClaimHeaderUUID
                                                                                   and _maxCustVersion.WrntyVersionNumber   = $projection.WrntyVersionNumber
  association [1..1] to I_WrntyClaimDecisionCode       as _DecisionCode            on  $projection.WrntyDecisionCode = _DecisionCode.WarrantyClaimItemDecisionCode
  association [1..1] to I_WarrantyClaimVersionCategory as _ClaimCategory           on  $projection.WarrantyClaimVersionCategory = _ClaimCategory.WarrantyClaimVersionCategory
  association [0..1] to I_WrntyClaimProcessingStatus as _SuplrProcessingStatus on $projection.WrntySuplrClmProcessingStatus = _SuplrProcessingStatus.WrntyClaimProcessingStatus 
                                                                               and $projection.WarrantyClaimVersionCategory = _SuplrProcessingStatus.WarrantyClaimVersionCategory
                                                                               and $projection.WarrantyClaimVersionIsActive = 'X'
  association [0..1] to I_WrntyClaimProcessingStatus as _CustProcessingStatus on $projection.WrntyCustClmProcessingStatus = _CustProcessingStatus.WrntyClaimProcessingStatus 
                                                                               and $projection.WarrantyClaimVersionCategory = _CustProcessingStatus.WarrantyClaimVersionCategory
                                                                               and $projection.WarrantyClaimVersionIsActive = 'X'
  association [1..1] to E_WarrantyClaimVersion         as _ExtensionWrntyVers               on  $projection.WrntyVersionUUID = _ExtensionWrntyVers.WrntyVersionUUID
  
{
  key WrntyVersionUUID,
      WrntyClaimHeaderUUID,
      case
      when _CustProcessingStatus.WarrantyClaimVersionCategory is null then ' '
      else 'X' end                as WrntyClmVersIsActvCustVersion,
//      case

//      when _maxSuplrVersion.WrntyVersionNumber is null  then ' '

//      else 'X' end                as WrntyClmVersIsActvSuplrVersion,

      case
      when  _SuplrProcessingStatus.WarrantyClaimVersionCategory  is null  then ' '
      else 'X' end                as WrntyClmVersIsActvSuplrVersion,
      WrntyVersionNumber,
      WarrantyClaimVersionCategory,
      WrntyDecisionCode,
      WarrantyClaimVersionPartner,
      WrntyClaimVersionPartnerRole,
      WarrantyClaimVersionIsActive,
      WrntyBillingDocumentDate,
      WrntyDocumentCondition,
      WrntyCurrencyCode,
      WrntyPriceExchangeRateDate,
      WrntyExchangeRateForPrice,
      WrntyNumberPrecedingVersion as WrntyClmPrecedingVersionNmbr,
      SalesOrganization,
      DistributionChannel,
      Division,
      WrntyVersionForReversePosting,
      PurchasingOrganization,
      WarrantyVersionPricingStatus,
      WrntyVersIsReldForShipgToPart,
      WarrantyVersionRprstvID,
      WarrantyClaimChangeDateTime,
      WrntyClaimCreationDate,
      CreatedByUser,
      WrntyClaimChangedDate,
      LastChangedByUser,
      WarrantyClaimVersionText,
      WrntyCustClmProcessingStatus,
      WrntySuplrClmProcessingStatus,
      /* Composition */
      _WrntyClaimHeader,
//      _Header,

      _WrntyClaimItem,
      _WrntyClaimVersionPricing,
      _Customer,
      _Supplier,
//      _Extension,

      _DecisionCode,
      _ClaimCategory

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_WRNTYCLAIMPROCESSINGSTATUS",
"I_WRNTYCLAIMVERSION"
],
"ASSOCIATED":
[
"I_CUSTOMER",
"I_SUPPLIER",
"I_WARRANTYCLAIMVERSIONCATEGORY",
"I_WRNTYCLAIMDECISIONCODE",
"R_WRNTYCLAIMITEMTP",
"R_WRNTYCLAIMTP",
"R_WRNTYCLAIMVERSIONPRICINGTP"
],
"BASE":
[
"I_WRNTYCLAIMVERSION"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/