R_TrdgDocPurposeText

@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.viewType: #BASIC
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@EndUserText.label: 'Purpose of Trading Document - Text'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.dataCategory: #TEXT
@ObjectModel.modelingPattern: #LANGUAGE_DEPENDENT_TEXT
@ObjectModel.representativeKey: 'TrdgDocPurpose'
@ObjectModel.supportedCapabilities: 
[ #CDS_MODELING_ASSOCIATION_TARGET,
  #CDS_MODELING_DATA_SOURCE,
  #LANGUAGE_DEPENDENT_TEXT,
  #SEARCHABLE_ENTITY,
  #SQL_DATA_SOURCE]
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.dataClass: #META
@ObjectModel.usageType.sizeCategory: #S
@Search.searchable: true
define view entity R_TrdgDocPurposeText
  as select from dd07t
  association        to parent R_TrdgDocPurpose as _TrdgDocPurpose on $projection.TrdgDocPurpose = _TrdgDocPurpose.TrdgDocPurpose
  association [0..1] to I_Language              as _Language       on $projection.Language = _Language.Language
{
      @ObjectModel.foreignKey.association: '_Language'
      @Semantics.language: true
  key cast( dd07t.ddlanguage as spras preserving type ) as Language,
      @ObjectModel.foreignKey.association: '_TrdgDocPurpose'
      @ObjectModel.text.element: ['TrdgDocPurposeName']
  key cast( dd07t.domvalue_l as wb2_tc_purpose )        as TrdgDocPurpose,
      @Consumption.hidden: true
      dd07t.domvalue_l                                  as DomainValue,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #LOW
      @Semantics.text: true
      @Consumption.filter.hidden: true
      @UI.textArrangement: #TEXT_ONLY
      dd07t.ddtext                                      as TrdgDocPurposeName,

      _TrdgDocPurpose,
      _Language
}
where
      dd07t.domname  = 'WB2_TC_PURPOSE'
  and dd07t.as4local = 'A'
  and dd07t.as4vers  = '0000'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"DD07T"
],
"ASSOCIATED":
[
"I_LANGUAGE",
"R_TRDGDOCPURPOSE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/