R_TrdgDocBusProcCategoryText

@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Business Process Cat of Trdg Doc - Text'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.dataCategory: #TEXT
@ObjectModel.modelingPattern: #LANGUAGE_DEPENDENT_TEXT
@ObjectModel.representativeKey: 'TrdgDocBusProcessCategory'
@ObjectModel.supportedCapabilities: [#CDS_MODELING_ASSOCIATION_TARGET,
                                     #CDS_MODELING_DATA_SOURCE,
                                     #LANGUAGE_DEPENDENT_TEXT,
                                     #SEARCHABLE_ENTITY,
                                     #SQL_DATA_SOURCE]
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.dataClass: #META
@ObjectModel.usageType.sizeCategory: #S
@Search.searchable: true
@VDM.lifecycle.contract.type:#SAP_INTERNAL_API
@VDM.viewType: #BASIC
define view entity R_TrdgDocBusProcCategoryText
  as select from dd07t
  association        to parent R_TrdgDocBusProcCategory as _TrdgDocBusProcCategory on $projection.TrdgDocBusProcessCategory = _TrdgDocBusProcCategory.TrdgDocBusProcessCategory
  association [0..1] to I_Language                        as _Language               on $projection.Language = _Language.Language
{
      @ObjectModel.foreignKey.association: '_Language'
      @Semantics.language: true
  key cast( dd07t.ddlanguage as spras preserving type )               as Language,
      @ObjectModel.foreignKey.association: '_TrdgDocBusProcCategory'
      @ObjectModel.text.element: ['TrdgDocBusProcessCategoryName']
  key cast( dd07t.domvalue_l as wb2_bus_proc_cat )                    as TrdgDocBusProcessCategory,
      @Analytics.hidden: true
      @Consumption.hidden: true
      dd07t.domvalue_l                                                as DomainValue,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #LOW
      @Semantics.text: true
      cast( ddtext as wb2_bus_process_category_name  preserving type) as TrdgDocBusProcessCategoryName,
      _TrdgDocBusProcCategory,
      _Language
}
where
      dd07t.domname  = 'WB2_USE_CASE_TYPE'
  and dd07t.as4local = 'A'
  and dd07t.as4vers  = '0000'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"DD07T"
],
"ASSOCIATED":
[
"I_LANGUAGE",
"R_TRDGDOCBUSPROCCATEGORY"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/