R_SrvcOrdItemLongTextTP

@EndUserText.label: 'Notes Item view for Service Order'
@VDM: {
  viewType: #TRANSACTIONAL,
  lifecycle.contract.type: #SAP_INTERNAL_API
}

@AccessControl: {
  authorizationCheck: #MANDATORY,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}

@Metadata: {
  ignorePropagatedAnnotations: true
}

@ObjectModel: {
   usageType: {dataClass:      #TRANSACTIONAL,
                serviceQuality: #C,
                sizeCategory:   #L}
}

define view entity R_SrvcOrdItemLongTextTP
  as select from I_ServiceDocumentLongText as ServiceItemText
    inner join   I_ServiceDocumentItem     as ServiceOrderItem on  ServiceItemText.ServiceDocument                 = ServiceOrderItem.ServiceDocument
                                                               and ServiceItemText.ServiceDocumentItem             = ServiceOrderItem.ServiceDocumentItem
                                                               and ServiceItemText.TextObjectCategory              = 'CRM_ORDERI'
                                                               and ServiceOrderItem.ServiceObjectType              = 'BUS2000116'
                                                               and ServiceOrderItem.ServiceDocumentItemIsQuotation is initial
                                                               and ServiceOrderItem.ServiceDocumentTemplateType    is initial
  association        to parent R_ServiceOrderItemTP as _ServiceOrderItemTP on  $projection.ServiceOrder     = _ServiceOrderItemTP.ServiceOrder
                                                                           and $projection.ServiceOrderItem = _ServiceOrderItemTP.ServiceOrderItem
  association [1..1] to R_ServiceOrderTP            as _ServiceOrderTP     on  $projection.ServiceOrder = _ServiceOrderTP.ServiceOrder

{
  key ServiceOrderItem.ServiceDocument        as ServiceOrder,
  key ServiceOrderItem.ServiceDocumentItem    as ServiceOrderItem,
  key ServiceItemText.TextObjectType,
  key ServiceItemText.Language,
  key ServiceItemText.SrvcDocLogTextIdentifier,
   ServiceItemText.ServiceDocumentLongTextUUID,

      
      // ServiceOrderItem.ServiceObjectType,


      ServiceItemText.TextObjectCategory,
      

      ServiceItemText.SrvcDocLongTextMimeType,
      @Semantics.text:true
      ServiceItemText.ServiceDocumentLongText as ServiceOrderItemLongText,

      ServiceItemText.ReferenceTextObjectCategory,
      ServiceItemText.ReferenceTextObjectType,
      ServiceItemText.ReferenceLongTextKey,
      ServiceItemText.ReferenceServiceObjectType,
      ServiceItemText.ReferenceServiceDocument,
      ServiceItemText.ReferenceServiceDocumentItem,

      ServiceItemText.SrvcDocLongTxtCreationDateTime,
      ServiceItemText.SrvcDocLongTextCreatedByUser,
      ServiceItemText.SrvcDocLongTextChangedDateTime,
      ServiceItemText.SrvcDocLongTextChangedByUser,

      /* Associations */
      ServiceItemText._Language,
      ServiceItemText._ReferenceTextObjectCategory,
      ServiceItemText._ReferenceTextObjectType,
      ServiceItemText._TextObjectCategory,
      ServiceItemText._TextObjectType,
      _ServiceOrderItemTP,
      _ServiceOrderTP
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_SERVICEDOCUMENTITEM",
"I_SERVICEDOCUMENTLONGTEXT"
],
"ASSOCIATED":
[
"I_LANGUAGE",
"I_TEXTOBJECTCATEGORY",
"I_TEXTOBJECTTYPE",
"R_SERVICEORDERITEMTP",
"R_SERVICEORDERTP"
],
"BASE":
[
"I_SERVICEDOCUMENTLONGTEXT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/