R_SrvcContrTmplItemLongTextTP

@EndUserText.label: 'Service Contract Template Item Text - TP'
@VDM: {
  viewType: #TRANSACTIONAL,
  lifecycle.contract.type: #SAP_INTERNAL_API
}

@AccessControl: {
  authorizationCheck: #MANDATORY,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}

@Metadata: {
  ignorePropagatedAnnotations: true
}

@ObjectModel: {
   dataCategory: #TEXT,
   usageType: { dataClass:      #TRANSACTIONAL,
                serviceQuality: #C,
                sizeCategory:   #L
              }
}
define view entity R_SrvcContrTmplItemLongTextTP as select from I_ServiceDocumentLongText as ServiceItemText
    inner join   I_ServiceDocumentItem as ServiceContractTemplateItem on  ServiceItemText.ServiceDocument   = ServiceContractTemplateItem.ServiceDocument
                                                          and ServiceItemText.ServiceDocumentItem           = ServiceContractTemplateItem.ServiceDocumentItem
                                                          and ServiceItemText.TextObjectCategory            = 'CRM_ORDERI'
                                                          and ServiceContractTemplateItem.ServiceObjectType = 'BUS2000112'

  association to parent R_SrvcContrTmplItemTP as _Item on  $projection.ServiceContractTemplate     = _Item.ServiceContractTemplate
                                                       and $projection.ServiceContractTemplateItem = _Item.ServiceContractTemplateItem                                                      
  //added for strict

  association to R_ServiceContractTemplateTP  as _ServiceContractTemplate on $projection.ServiceContractTemplate = _ServiceContractTemplate.ServiceContractTemplate

{
  key ServiceContractTemplateItem.ServiceDocument as ServiceContractTemplate,
  key ServiceContractTemplateItem.ServiceDocumentItem as ServiceContractTemplateItem,
  key ServiceItemText.TextObjectType,
      @Semantics.language:true
  key ServiceItemText.Language,
  key ServiceItemText.SrvcDocLogTextIdentifier,
  
      ServiceItemText.ServiceDocumentLongTextUUID,
      ServiceItemText.ServiceObjectType,

      ServiceItemText.TextObjectCategory,
      
      ServiceItemText.SrvcDocLongTextMimeType,
      @Semantics.text:true
      ServiceItemText.ServiceDocumentLongText  as SrvcContrTmplItemLongText,

      ServiceItemText.ReferenceTextObjectCategory,
      ServiceItemText.ReferenceTextObjectType,
      ServiceItemText.ReferenceLongTextKey,
      ServiceItemText.ReferenceServiceObjectType,
      ServiceItemText.ReferenceServiceDocument,
      ServiceItemText.ReferenceServiceDocumentItem,

      
      ServiceItemText.SrvcDocLongTxtCreationDateTime,
      ServiceItemText.SrvcDocLongTextCreatedByUser,
      ServiceItemText.SrvcDocLongTextChangedDateTime,
      ServiceItemText.SrvcDocLongTextChangedByUser,

      /* Associations */
      ServiceItemText._Language,
      ServiceItemText._ReferenceTextObjectCategory,
      ServiceItemText._ReferenceTextObjectType,
      ServiceItemText._TextObjectCategory,
      ServiceItemText._TextObjectType,
      
      _Item,
      _ServiceContractTemplate
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_SERVICEDOCUMENTITEM",
"I_SERVICEDOCUMENTLONGTEXT"
],
"ASSOCIATED":
[
"I_LANGUAGE",
"I_TEXTOBJECTCATEGORY",
"I_TEXTOBJECTTYPE",
"R_SERVICECONTRACTTEMPLATETP",
"R_SRVCCONTRTMPLITEMTP"
],
"BASE":
[
"I_SERVICEDOCUMENTLONGTEXT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/