R_SrcgProjNegotiationQuotation

@EndUserText.label: 'Quotation for Srcg Project Negotiation'

@VDM.viewType: #BASIC
@VDM.lifecycle.contract.type:#SAP_INTERNAL_API
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.preserveKey:true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@AbapCatalog.sqlViewName: 'RSRCGNGNQTN'
@AbapCatalog.compiler.compareFilter:true
@ObjectModel:{
               usageType.dataClass: #TRANSACTIONAL,
               usageType.serviceQuality: #A,
               usageType.sizeCategory: #L,
               semanticKey: ['SrcgProjNegttnQuotationUUID'],
               representativeKey: 'SrcgProjNegttnQuotationUUID'   }

define view R_SrcgProjNegotiationQuotation
  as select from mmsrcgpngnqtn

  association [1..1] to R_SourcingProjectNegotiation  as _SourcingProjectNegotiation  on  $projection.SourcingProjectNegotiationUUID = _SourcingProjectNegotiation.SourcingProjectNegotiationUUID
  association [0..*] to R_SrcgProjNegttnQuotationItem as _SrcgProjNegttnQuotationItem on  $projection.SrcgProjNegttnQuotationUUID = _SrcgProjNegttnQuotationItem.SrcgProjNegttnQuotationUUID
  association [1..1] to R_SourcingProjectQuotation    as _SourcingProjectQuotation    on  $projection.SourcingProjectQuotationUUID = _SourcingProjectQuotation.SourcingProjectQuotationUUID
  association [1..1] to R_SourcingProjectQuotation    as _SPNegttnRevisedQuotation    on  $projection.SourcingProjectNegotiationUUID           =  _SPNegttnRevisedQuotation.SourcingProjectNegotiationUUID
                                                                                      and $projection.SourcingProjectQuotation                 =  _SPNegttnRevisedQuotation.SourcingProjectQuotation
                                                                                      and _SPNegttnRevisedQuotation.SrcgProjQtnLifecycleStatus <> '04' // Not in Revision

  association [0..1] to I_BusinessPartner             as _BusinessPartner             on  $projection.Bidder = _BusinessPartner.BusinessPartner

{

  key srcgprojnegttnquotationuuid                            as SrcgProjNegttnQuotationUUID,
      sourcingprojectnegotiationuuid                         as SourcingProjectNegotiationUUID,
      sourcingprojectquotationuuid                           as SourcingProjectQuotationUUID,
      sourcingprojectquotation                               as SourcingProjectQuotation,
      srcgprojquotationversion                               as SrcgProjQuotationVersion,
      bidder                                                 as Bidder,
      @Semantics.amount.currencyCode: 'DocumentCurrency'
      srcgprojnegttntotaltargetamt                           as SrcgProjNegttnTotalTargetAmt,
      @Semantics.currencyCode: true
      documentcurrency                                       as DocumentCurrency,
      _SPNegttnRevisedQuotation.SourcingProjectQuotationUUID as SPQtnForNegttnLtstVersionUUID,

      _SourcingProjectNegotiation,
      _SrcgProjNegttnQuotationItem,
      _SourcingProjectQuotation,
      _SPNegttnRevisedQuotation,
      _BusinessPartner

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"R_SOURCINGPROJECTQUOTATION",
"MMSRCGPNGNQTN"
],
"ASSOCIATED":
[
"I_BUSINESSPARTNER",
"R_SOURCINGPROJECTNEGOTIATION",
"R_SOURCINGPROJECTQUOTATION",
"R_SRCGPROJNEGTTNQUOTATIONITEM"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/