R_SlsSchedgAgrmtTextTP

@VDM: {
  lifecycle.contract.type: #SAP_INTERNAL_API,
  viewType: #TRANSACTIONAL
}
@ObjectModel: {
    usageType: {
        dataClass: #TRANSACTIONAL,
        serviceQuality: #C,
        sizeCategory: #L
    }
}
@ObjectModel.semanticKey: ['SalesSchedulingAgreement', 'Language', 'LongTextID']
@Metadata.ignorePropagatedAnnotations: true
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel.dataCategory:#TEXT
@EndUserText.label: 'Sales Scheduling Agreement - Text TP'
define view entity R_SlsSchedgAgrmtTextTP
  as select from P_SalesDocumentText( P_SAPClient : $session.client ) as SlsSchedgAgrmtText

    inner join   I_SalesDocumentBasic                                 as SalesDocumentBasic on SalesDocumentBasic.SalesDocument        = SlsSchedgAgrmtText.SalesDocument
                                                                                            and(
                                                                                              SalesDocumentBasic.SDDocumentCategory    = 'E'
                                                                                              or SalesDocumentBasic.SDDocumentCategory = 'F'
                                                                                            )
    inner join   I_SalesDocumentType                                  as SalesDocumentType  on SalesDocumentBasic.SalesDocumentType = SalesDocumentType.SalesDocumentType
  association        to parent R_SalesSchedgAgrmtTP   as _SalesSchedulingAgreement    on  $projection.SalesSchedulingAgreement = _SalesSchedulingAgreement.SalesSchedulingAgreement

  association [0..*] to I_TextDeterminationProcedItem as _TextDeterminationProcedItem on  $projection.TextDeterminationProcedure          = _TextDeterminationProcedItem.TextDeterminationProcedure
                                                                                      and $projection.LongTextID                          = _TextDeterminationProcedItem.LongTextID
                                                                                      and _TextDeterminationProcedItem.TextObjectCategory = 'VBBK'

  association [0..1] to I_Language                    as _Language                    on  $projection.LanguageForEdit = _Language.Language
  association [0..1] to I_SDDocumentLongTextID        as _LongTextID                  on  $projection.LongTextIDForEdit = _LongTextID.LongTextID

{
  key cast(SlsSchedgAgrmtText.SalesDocument as vdm_sales_schedg_agrmt preserving type) as SalesSchedulingAgreement,
      
      @Semantics.language:true
  key SlsSchedgAgrmtText.Language,
  key SlsSchedgAgrmtText.LongTextID,
      @ObjectModel.foreignKey.association: '_LongTextID'
      @ObjectModel.editableFieldFor: 'LongTextID'
      SlsSchedgAgrmtText.LongTextID                                                    as LongTextIDForEdit,
      @ObjectModel.foreignKey.association: '_Language'
      @ObjectModel.editableFieldFor: 'Language'
      @Semantics.language:true
      SlsSchedgAgrmtText.Language                                                      as LanguageForEdit,
      @Semantics.text:true
      SlsSchedgAgrmtText.LongText,
      @Consumption.hidden: true
      SalesDocumentType.TextDeterminationProcedure,
      _TextDeterminationProcedItem.TextDeterminationProcedureItem                      as TextDeterminationProcedureItem,

      // For Access control

      @Consumption.hidden: true
      _SalesSchedulingAgreement.SalesSchedgAgrmtType,
      @Consumption.hidden: true
      _SalesSchedulingAgreement.SalesOrganization,
      @Consumption.hidden: true
      _SalesSchedulingAgreement.DistributionChannel,
      @Consumption.hidden: true
      _SalesSchedulingAgreement.OrganizationDivision,
      // Exposed associations

      _SalesSchedulingAgreement,
      _Language,
      _LongTextID
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_SALESDOCUMENTBASIC",
"I_SALESDOCUMENTTYPE",
"I_TEXTDETERMINATIONPROCEDITEM",
"R_SALESSCHEDGAGRMTTP"
],
"ASSOCIATED":
[
"I_LANGUAGE",
"I_SDDOCUMENTLONGTEXTID",
"R_SALESSCHEDGAGRMTTP"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/