R_ServiceRequestTP

@AccessControl: {
  authorizationCheck: #MANDATORY,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@VDM: {
  viewType: #TRANSACTIONAL,
  lifecycle.contract.type: #SAP_INTERNAL_API
}
@Metadata:
{
  ignorePropagatedAnnotations: true
}

@EndUserText.label: 'Service Request - TP'
@ObjectModel: {
  sapObjectNodeType.name: 'ServiceRequest',
  semanticKey: ['ServiceRequest'],
  representativeKey: 'ServiceRequest',
   usageType: {dataClass:      #TRANSACTIONAL,
                serviceQuality: #C,
                sizeCategory:   #L}
}
define root view entity R_ServiceRequestTP
  as select from I_ServiceDocumentEnhcd
  association [0..1] to I_StatusObjectUUIDStatus as _SrvcReqStatus on  $projection.ServiceRequestUUID = _SrvcReqStatus.StatusObjectUUID
                                                                   and (
                                                                      _SrvcReqStatus.StatusCode       = 'I1002'
                                                                      or _SrvcReqStatus.StatusCode    = 'I1003'
                                                                      or _SrvcReqStatus.StatusCode    = 'I1004'
                                                                      or _SrvcReqStatus.StatusCode    = 'I1005'
                                                                    )
                                                                   and _SrvcReqStatus.StatusIsActive  = 'X'
{
  key ServiceDocument                          as ServiceRequest,
      @ObjectModel.foreignKey.association: '_ServiceObjType'
      ServiceObjectType,
      ServiceDocumentType                      as ServiceRequestType,
      ServiceDocumentUUID                      as ServiceRequestUUID,
      ServiceDocumentDescription               as ServiceRequestDescription,
      Language,
      ServiceDocumentPriority,
      BusinessActivityCategory                 as ServiceDocumentCategory,
      RequestedServiceStartDateTime,
      RequestedServiceEndDateTime,
      ServiceFirstResponseByDateTime,
      ServiceDueByDateTime,
      PurchaseOrderByCustomer,
      CustomerPurchaseOrderDate,
      RecommendedServicePriority,
      ServiceDocumentUrgency                   as ServiceRequestUrgency,
      ServiceDocumentImpact                    as ServiceRequestImpact,
      ServiceDocumentProblemCategory           as ServiceRequestProblemCategory,

      @Semantics.booleanIndicator
      ServiceDocumentIsRejected                as ServiceRequestIsCanceled,

      ServiceDocChangedDateTime,

      @Semantics.booleanIndicator
      cast( case _SrvcReqStatus.StatusCode
      when 'I1005' then 'X'
      else ' '
      end     as   xfeld preserving type     ) as ServiceRequestIsCompleted,

      SalesOrganization,
      DistributionChannel,
      Division,
      SalesOffice,
      SalesGroup,
      SoldToParty,
      ContactPerson                            as ServiceRequestReporter,
      SalesOrganizationOrgUnitID,
      ServiceOrganization,
      SalesOfficeOrgUnitID,
      SalesGroupOrgUnitID,
      // Associations

      _ServiceObjType
}
where
  ServiceObjectType = 'BUS2000223' // Service Request

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_SERVICEDOCUMENTENHCD",
"I_STATUSOBJECTUUIDSTATUS"
],
"ASSOCIATED":
[
"I_CUSTMGMTBUSOBJTYPE"
],
"BASE":
[
"I_SERVICEDOCUMENTENHCD"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/