R_ServiceContractTemplateTP

@AccessControl: {
  authorizationCheck: #MANDATORY,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@VDM: {
  viewType: #TRANSACTIONAL,
  lifecycle.contract.type: #SAP_INTERNAL_API
}
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.sapObjectNodeType.name: 'ServiceContractTemplate'
@ObjectModel: {
  semanticKey: ['ServiceContractTemplate'],
  representativeKey: 'ServiceContractTemplate',
  usageType: {dataClass:      #TRANSACTIONAL,
              serviceQuality: #C,
              sizeCategory:   #L}
}

@EndUserText.label: 'Service Contract Template - TP'

define root view entity R_ServiceContractTemplateTP
  as select from I_ServiceDocumentEnhcd

  association [0..1] to I_StatusObjectUUIDStatus    as _SrvcContrTmplStatus       on  $projection.ServiceContractTemplateUUID =       _SrvcContrTmplStatus.StatusObjectUUID
                                                                                  and _SrvcContrTmplStatus.StatusCode         between 'I1002' and 'I1005'
                                                                                  and _SrvcContrTmplStatus.StatusIsActive     =       'X'

  association [1]    to I_ServiceDocumentStatusText as _ServiceDocumentStatusText on  $projection.SrvcContrTmplStatus     = _ServiceDocumentStatusText.ServiceDocumentStatus
                                                                                  and _ServiceDocumentStatusText.Language = $session.system_language

  association [0..1] to I_SrvcDocDurationUnitText   as _SrvcDocDurationUnitText   on  $projection.SrvcContrDurationUnit   = _SrvcDocDurationUnitText.SrvcDocDurationUnit
                                                                                  and _SrvcDocDurationUnitText.Language = $session.system_language

  association [0..1] to I_ServiceDocErrorStatusText as _SrvcDocErrorStatusText    on  $projection.ServiceDocumentHasError             = _SrvcDocErrorStatusText.ServiceDocumentHasError
                                                                                  and _SrvcDocErrorStatusText.ServiceDocumentHasError = 'X'
                                                                                  and _SrvcDocErrorStatusText.Language                = $session.system_language

  association [0..1] to R_SrvcContrTmplDurationTP   as _SrvcContrTmplDurationTP   on  $projection.ServiceContractTemplate = _SrvcContrTmplDurationTP.ServiceContractTemplate
                                                                                  and _SrvcContrTmplDurationTP.SrvcDocDurationType = 'CONTDURA'

  association [0..1] to I_BusinessPartner           as _ResponsibleEmployee       on  $projection.RespEmployeeBusinessPartnerId = _ResponsibleEmployee.BusinessPartner

  association [0..1] to E_ServiceDocument           as _ServiceDocumentExt        on  $projection.ServiceObjectType       = _ServiceDocumentExt.ServiceCategory
                                                                                  and $projection.ServiceContractTemplate = _ServiceDocumentExt.ServiceOrder
  
  association [0..1] to I_UnitOfMeasure             as _SrvcContrTmplDurnUnit     on  $projection.SrvcContrDurationUnitSAPCode = _SrvcContrTmplDurnUnit.UnitOfMeasure
  
  composition [0..*] of R_SrvcContrTmplItemTP       as _Item
  
  composition [0..*] of R_SrvcContrTmplLongTextTP   as _LongText

{

  key ServiceDocument                                    as ServiceContractTemplate,

      @ObjectModel.foreignKey.association: '_ServiceObjType'
      ServiceObjectType,
      @ObjectModel.foreignKey.association: '_ServiceDocumentType'
      ServiceDocumentType                                as ServiceContractTemplateType,
      ServiceDocumentTemplateType,
      ServiceDocumentUUID                                as ServiceContractTemplateUUID,
      ServiceDocumentDescription                         as SrvcContrTmplDescription,

      Language,

      PostingDate,

      // Validity

      @Semantics.dateTime:true
      SrvcDocTmplValdtyStartDateTime                     as SrvcContrTmplValdtyStrtDteTime,
      @Semantics.dateTime:true
      SrvcDocTmplValdtyEndDateTime                       as SrvcContrTmplValdtyEndDateTime,
      
      cast( tstmp_to_dats( SrvcDocTmplValdtyStartDateTime,
          abap_system_timezone( $session.client,'NULL' ),
          $session.client,
          'NULL' ) as crms4_created_on preserving type ) as SrvcDocTmplValidityStartDate,
      cast( tstmp_to_dats( SrvcDocTmplValdtyEndDateTime,
          abap_system_timezone( $session.client,'NULL' ),
          $session.client,
          'NULL' ) as crms4_created_on preserving type ) as SrvcDocTmplValidityEndDate,

      // Duration

      _SrvcContrTmplDurationTP.SrvcDocDurationValue         as SrvcContrDuration,
      _SrvcContrTmplDurationTP.SrvcDocDurationUnit          as SrvcContrDurationUnit,
      _SrvcContrTmplDurationTP.SrvcDocDurationUnitSAPCode   as SrvcContrDurationUnitSAPCode,

      // Administrative fields

      ServiceDocCreationDateTime,
      ServiceDocChangedDateTime,
      ServiceDocumentCreatedByUser,
      ServiceDocumentChangedByUser,

      // Responsibile employee

      @ObjectModel.foreignKey.association: '_ResponsibleEmployee'
      ResponsibleEmployee                                as RespEmployeeBusinessPartnerId,

      // Life cycle status

      @Semantics.booleanIndicator: true
      cast( case _SrvcContrTmplStatus.StatusCode
          when 'I1002' then 'X' else ' '
      end as xfeld preserving type )                     as SrvcContrTmplIsNew,
      @Semantics.booleanIndicator: true
      cast( case _SrvcContrTmplStatus.StatusCode
          when 'I1003' then 'X' else ' '
      end as xfeld preserving type )                     as SrvcContrTmplIsInProcess,
      @Semantics.booleanIndicator: true
      cast( case _SrvcContrTmplStatus.StatusCode
          when 'I1004' then 'X' else ' '
      end as xfeld preserving type )                     as SrvcContrTmplIsReleased,
      @Semantics.booleanIndicator: true
      cast( case _SrvcContrTmplStatus.StatusCode
          when 'I1005' then 'X' else ' '
      end as xfeld preserving type )                     as SrvcContrTmplIsCompleted,

      ServiceDocumentStatus                              as SrvcContrTmplStatus,

      // Error status

      @Semantics.booleanIndicator: true
      cast( ServiceDocumentHasError
          as xfeld preserving type )                     as ServiceDocumentHasError,
      case ServiceDocumentHasError
          when 'X' then 1 else 0
      end                                                as SrvcContrErrStsCriticality,

      // Organiztion

      SalesOrganization,
      SalesOffice,
      SalesGroup,
      DistributionChannel,
      Division,
      SalesOrganizationOrgUnitID,
      SalesOfficeOrgUnitID,
      SalesGroupOrgUnitID,
      ServiceOrganization,
      
      // Reference

      PurchaseOrderByCustomer,
      CustomerPurchaseOrderDate,

      // Associations

      _ServiceDocumentType,
      _ServiceObjType,
      _ResponsibleEmployee,
      _SrvcContrTmplDurationTP,
      _SrvcDocDurationUnitText,
      _SrvcContrTmplStatus,
      _ServiceDocumentStatusText,
      _SrvcDocErrorStatusText,
      _SrvcContrTmplDurnUnit,
      _Item,
      _LongText

}
where
      ServiceObjectType = 'BUS2000112'
  and ServiceDocumentTemplateType != ''
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_SERVICEDOCUMENTENHCD",
"I_STATUSOBJECTUUIDSTATUS",
"R_SRVCCONTRTMPLDURATIONTP"
],
"ASSOCIATED":
[
"I_BUSINESSPARTNER",
"I_CUSTMGMTBUSOBJTYPE",
"I_SERVICEDOCERRORSTATUSTEXT",
"I_SERVICEDOCUMENTSTATUSTEXT",
"I_SERVICEDOCUMENTTYPE",
"I_SRVCDOCDURATIONUNITTEXT",
"I_STATUSOBJECTUUIDSTATUS",
"I_UNITOFMEASURE",
"R_SRVCCONTRTMPLDURATIONTP",
"R_SRVCCONTRTMPLITEMTP",
"R_SRVCCONTRTMPLLONGTEXTTP"
],
"BASE":
[
"I_SERVICEDOCUMENTENHCD"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/