R_ServiceConfirmationTP

@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@VDM: {
  viewType: #TRANSACTIONAL,
  lifecycle.contract.type: #SAP_INTERNAL_API
}
@Metadata:
{
  ignorePropagatedAnnotations: true
}

@EndUserText.label: 'Service Confirmation - TP'
@ObjectModel: {
  sapObjectNodeType.name: 'ServiceConfirmation',
  semanticKey: ['ServiceConfirmation'],
  representativeKey: 'ServiceConfirmation',
  usageType: {dataClass:      #TRANSACTIONAL,
              serviceQuality: #C,
              sizeCategory:   #L }
    }

define root view entity R_ServiceConfirmationTP
  as select from I_ServiceDocumentEnhcd

  composition [0..*] of R_ServiceConfirmationItemTP as _ServiceConfirmationItemTP
  composition [0..*] of R_SrvcConfPartnerTP         as _SrvcConfPartnerTP
  composition [0..*] of R_SrvcConfRefObjectTP       as _SrvcConfReferenceObjectTP
  composition [0..*] of R_SrvcConfFUPBillgDocTP     as _BillingDocumentFollowupTP
  //composition [0..*] of R_SrvcConfFUPGoodsMvtTP     as _GoodsMovementFollowupTP

  composition [0..*] of R_SrvcConfFUPTimeSheetTP    as _TimeSheetFollowupTP
  composition [0..*] of R_SrvcConfPriceElementTP    as _SrvcConfPriceElementTP
  composition [0..*] of R_SrvcConfAppointmentTP     as _SrvcConfAppointmentTP
  composition [0..*] of R_SrvcConfDurationTP        as _SrvcConfDurationTP
  composition [0..*] of R_SrvcConfUserStatusTP      as _SrvcConfUserStatusTP
  composition [0..*] of R_SrvcConfLongTextTP        as _SrvcConfLongTextTP

  association [0..1] to I_CustMgmtExtRefID          as _CustMgmtExtRef  on  $projection.ServiceConfirmation      = _CustMgmtExtRef.CustMgmtDocument
                                                                        and $projection.ServiceObjectType        = _CustMgmtExtRef.CustMgmtObjectType
                                                                        and _CustMgmtExtRef.CustMgmtExtRefIDType = '0014'

  association [0..1] to R_SrvcDocDocumentFlow       as _RefServiceOrder on  $projection.ServiceConfirmationUUID          = _RefServiceOrder.ServiceDocumentUUID
                                                                        and _RefServiceOrder.PrdcssrSuccssrDocObjectType = 'BUS2000116'
                                                                        and _RefServiceOrder.ServiceObjectType           = 'BUS2000117'

  association [0..1] to I_StatusObjectUUIDStatus    as _SrvcConfStatus  on  $projection.ServiceConfirmationUUID = _SrvcConfStatus.StatusObjectUUID
                                                                        and (
                                                                           _SrvcConfStatus.StatusCode           = 'I1002' //IsNew

                                                                           or _SrvcConfStatus.StatusCode        = 'I1003' //InProcess

                                                                           or _SrvcConfStatus.StatusCode        = 'I1005' //Completed

                                                                         )
                                                                        and _SrvcConfStatus.StatusIsActive      = 'X'

  association [0..1] to I_StatusObjectUUIDStatus    as _StatusCancelled on  $projection.ServiceConfirmationUUID = _StatusCancelled.StatusObjectUUID
                                                                        and _StatusCancelled.StatusCode         = 'I1096'

  //! Extensibility support

  association [0..1] to E_ServiceDocument           as _Extension       on  $projection.ServiceObjectType   = _Extension.ServiceCategory
                                                                        and $projection.ServiceConfirmation = _Extension.ServiceOrder

{
       //Administrative Fields

  key  ServiceDocument                                                             as ServiceConfirmation,
       @ObjectModel.foreignKey.association: '_ServiceDocumentType'
       ServiceDocumentType                                                         as ServiceConfirmationType,
       ServiceDocumentUUID                                                         as ServiceConfirmationUUID,
       ServiceDocumentDescription                                                  as ServiceConfirmationDescription,
       Language,
       //PostingDate,"not included for 2105

       ServiceDocCreationDateTime,
       ServiceDocChangedDateTime,
       ServiceDocumentCreatedByUser,
       ServiceDocumentChangedByUser,
       @ObjectModel.foreignKey.association: '_ServiceObjType'
       ServiceObjectType,

       RequestedServiceStartDateTime,
       RequestedServiceEndDateTime,
//       ErlstRequestedDeliveryDateTime,


       //Partners

       @ObjectModel.foreignKey.association: '_SoldToParty'
       SoldToParty,
       @ObjectModel.foreignKey.association: '_ShipToParty'
       ShipToParty,
       @ObjectModel.foreignKey.association: '_BillToParty'
       BillToParty,
       @ObjectModel.foreignKey.association: '_PayerParty'
       PayerParty,
       @ObjectModel.foreignKey.association: '_ContactPerson'
       ContactPerson                                                               as ContactPersonBusinessPartnerId,
       @ObjectModel.foreignKey.association: '_RespEmployee'
       ResponsibleEmployee                                                         as RespEmployeeBusinessPartnerId,
       @ObjectModel.foreignKey.association: '_ServiceEmployee'
       ServiceEmployee,

       //Organizational Data

       @ObjectModel.foreignKey.association: '_SalesOrganization'
       SalesOrganization,
       @ObjectModel.foreignKey.association: '_DistributionChannel'
       DistributionChannel,
       @ObjectModel.foreignKey.association: '_Division'
       Division,
       @ObjectModel.foreignKey.association: '_SalesOffice'
       SalesOffice,
       @ObjectModel.foreignKey.association: '_SalesGroup'
       SalesGroup,
       //CRM Org units

       //these feilds are only ON PREMISE

       @Feature: 'BF:API_FULLSCOPE'
       //       @ObjectModel.foreignKey.association: '_SalesOrganizationOrgUnit'

       @ObjectModel.foreignKey.association: '_SalesOrganizationOrgUnit_2'
       SalesOrganizationOrgUnitID,
       @Feature: 'BF:API_FULLSCOPE'
       //       @ObjectModel.foreignKey.association: '_SalesOfficeOrgUnit'

       @ObjectModel.foreignKey.association: '_SalesOfficeOrgUnit_2'
       SalesOfficeOrgUnitID,
       @Feature: 'BF:API_FULLSCOPE'
       //       @ObjectModel.foreignKey.association: '_SalesGroupOrgUnit'

       @ObjectModel.foreignKey.association: '_SalesGroupOrgUnit_2'
       SalesGroupOrgUnitID,
       @Feature: 'BF:API_FULLSCOPE'
       //       @ObjectModel.foreignKey.association: '_ServiceOrganizationOrgUnit'

       @ObjectModel.foreignKey.association: '_ServiceOrganizationOrgUnit_2'
       ServiceOrganization,
       //Service team fields

       RespyMgmtServiceTeam,
       //_ServiceTeamHeader.TeamName                                                 as RespyMgmtServiceTeamName,

       _ServiceTeamHeader.RespyMgmtGlobalTeamID                                    as RespyMgmtGlobalTeamID,

       //Status

       cast( case _SrvcConfStatus.StatusCode
       when 'I1002' then 'X'
       else ' '
       end                  as   xfeld preserving type     )                       as ServiceConfirmationIsNew,
       //       cast( case _SrvcConfStatus.StatusCode

       //       when 'I1003' then 'X'

       //       else ' '

       //       end                  as   xfeld preserving type     )                       as ServiceConfirmationIsInProcess,

       cast( case _SrvcConfStatus.StatusCode
       when 'I1005' then 'X'
       else ' '
       end                  as   xfeld preserving type     )                       as ServiceConfirmationIsCompleted,
       _StatusCancelled.StatusIsActive                                             as ServiceConfirmationIsCanceled,
       ServiceDocumentStatus                                                       as ServiceConfirmationStatus,
       ServiceDocIsReleasedForBilling                                              as SrvcConfReldForBillingStatus,
       ServiceDocBillingStatus                                                     as SrvcConfBillingStatus,

       ServiceConfirmationIsFinal,

       @Semantics.booleanIndicator
       ServiceDocumentHasError                                                     as ServiceConfirmationHasError,
       SrvcDocTransferStatus,
       SrvcDocRejectionStatus,

       //Service specific fields

       @ObjectModel.foreignKey.association: '_ServiceDocumentPriority'
       ServiceDocumentPriority,

       //Pricing fields

       @ObjectModel.foreignKey.association: '_TransactionCurrency'
       TransactionCurrency,
       @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
       ServiceDocGrossAmount,
       @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
       ServiceDocNetAmount,
       @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
       ServiceDocTaxAmount,
       PricingDocument,

       //Sales fields

       PurchaseOrderByCustomer,
       CustomerPurchaseOrderDate,

       //Reference documents

       _CustMgmtExtRef.CustMgmtExtRefID                                            as SrvcConfExtReference,
       cast( _RefServiceOrder.CustMgmtPrdcssrTransactionKey as crmt_object_id_db ) as ReferenceServiceOrder,

       //Shipping

       ShippingCondition,

       //Associations

       _ServiceDocumentType,
       _SoldToParty,
       _ShipToParty,
       _BillToParty,
       _PayerParty,
       _ContactPerson,
       _RespEmployee,
       _ServiceEmployee,
       _SalesOrganization,
       _DistributionChannel,
       _Division,
       _SalesOffice,
       _SalesGroup,

       @API.element.releaseState: #DEPRECATED
       @API.element.successor: '_SalesOrganizationOrgUnit_2'
       _SalesOrganizationOrgUnit,
       @API.element.releaseState: #DEPRECATED
       @API.element.successor: '_SalesOfficeOrgUnit_2'
       _SalesOfficeOrgUnit,
       @API.element.releaseState: #DEPRECATED
       @API.element.successor: '_SalesGroupOrgUnit_2'
       _SalesGroupOrgUnit,
       @API.element.releaseState: #DEPRECATED
       @API.element.successor: '_ServiceOrganizationOrgUnit_2'
       _ServiceOrganizationOrgUnit,

       _SalesOrganizationOrgUnit_2,
       _SalesOfficeOrgUnit_2,
       _SalesGroupOrgUnit_2,
       _ServiceOrganizationOrgUnit_2,
       _ServiceDocumentPriority,
       _TransactionCurrency,
       _ServiceObjType,
       _ServiceConfirmationItemTP,
       _SrvcConfReferenceObjectTP,
       _SrvcConfPriceElementTP,
       _SrvcConfPartnerTP,
       _BillingDocumentFollowupTP,
       _TimeSheetFollowupTP,
       _SrvcConfAppointmentTP,
       _SrvcConfDurationTP,
       _SrvcConfUserStatusTP,
       _SrvcConfLongTextTP,
       _StatusCancelled



}
where
  ServiceObjectType = 'BUS2000117' // Service Confirmation

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CUSTMGMTEXTREFID",
"I_RESPYMGMTTEAMHEADERDETAIL",
"I_SERVICEDOCUMENTENHCD",
"I_STATUSOBJECTUUIDSTATUS",
"R_SRVCDOCDOCUMENTFLOW"
],
"ASSOCIATED":
[
"I_BUSINESSPARTNER",
"I_CURRENCY",
"I_CUSTMGMTBUSOBJTYPE",
"I_DISTRIBUTIONCHANNEL",
"I_DIVISION",
"I_SALESGROUP",
"I_SALESOFFICE",
"I_SALESORGANIZATION",
"I_SALESORGANIZATIONUNIT",
"I_SERVICEDOCUMENTPRIORITY",
"I_SERVICEDOCUMENTTYPE",
"I_SRVCMGMTORGANIZATIONUNIT",
"I_STATUSOBJECTUUIDSTATUS",
"R_SERVICECONFIRMATIONITEMTP",
"R_SRVCCONFAPPOINTMENTTP",
"R_SRVCCONFDURATIONTP",
"R_SRVCCONFFUPBILLGDOCTP",
"R_SRVCCONFFUPTIMESHEETTP",
"R_SRVCCONFLONGTEXTTP",
"R_SRVCCONFPARTNERTP",
"R_SRVCCONFPRICEELEMENTTP",
"R_SRVCCONFREFOBJECTTP",
"R_SRVCCONFUSERSTATUSTP"
],
"BASE":
[
"I_SERVICEDOCUMENTENHCD"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/