R_SalesContractItemTextTP

@VDM: {
  lifecycle.contract.type: #SAP_INTERNAL_API,
  viewType: #TRANSACTIONAL
}

@ObjectModel: {
    usageType: {
        dataClass: #TRANSACTIONAL,
        serviceQuality: #C,
        sizeCategory: #L
    }
}

@ObjectModel.semanticKey: ['SalesContract', 'SalesContractItem', 'Language', 'LongTextID']

@Metadata.ignorePropagatedAnnotations: true

@AccessControl.authorizationCheck: #CHECK

@EndUserText.label: 'Sales Contract Item - Text TP'
define view entity R_SalesContractItemTextTP
  as select from P_SalesDocumentItemText( P_SAPClient : $session.client ) as SalesContractItemText

    inner join   I_SalesDocumentItemBasic                                 as SalesDocumentItemBasic    on  SalesDocumentItemBasic.SalesDocument      = SalesContractItemText.SalesDocument
                                                                                                       and SalesDocumentItemBasic.SalesDocumentItem  = SalesContractItemText.SalesDocumentItem
                                                                                                       and SalesDocumentItemBasic.SDDocumentCategory = 'G'

    inner join   I_SalesDocumentItemCategory                              as SalesDocumentItemCategory on SalesDocumentItemCategory.SalesDocumentItemCategory = SalesDocumentItemBasic.SalesDocumentItemCategory

  association        to parent R_SalesContractItemTP  as _Item                        on  $projection.SalesContract     = _Item.SalesContract
                                                                                      and $projection.SalesContractItem = _Item.SalesContractItem

  association [0..*] to I_TextDeterminationProcedItem as _TextDeterminationProcedItem on  $projection.TextDeterminationProcedure          = _TextDeterminationProcedItem.TextDeterminationProcedure
                                                                                      and $projection.LongTextID                          = _TextDeterminationProcedItem.LongTextID
                                                                                      and _TextDeterminationProcedItem.TextObjectCategory = 'VBBP'

  association [1..1] to R_SalesContractTP             as _SalesContract               on  $projection.SalesContract = _SalesContract.SalesContract

  association [0..1] to I_Language                    as _Language                    on  $projection.LanguageForEdit = _Language.Language

  association [0..1] to I_SDDocumentItemLongTextID    as _LongTextID                  on  $projection.LongTextIDForEdit = _LongTextID.LongTextID

{
  key cast(SalesContractItemText.SalesDocument as sales_contract preserving type)          as SalesContract,

  key cast(SalesContractItemText.SalesDocumentItem as sales_contract_item preserving type) as SalesContractItem,

  key SalesContractItemText.Language,

  key SalesContractItemText.LongTextID,

      @ObjectModel.foreignKey.association: '_LongTextID'
      SalesContractItemText.LongTextID                                                     as LongTextIDForEdit,

      @ObjectModel.foreignKey.association: '_Language'
      SalesContractItemText.Language                                                       as LanguageForEdit,

      SalesContractItemText.LongText,

      @Consumption.hidden: true
      SalesDocumentItemCategory.TextDeterminationProcedure,

      _TextDeterminationProcedItem.TextDeterminationProcedureItem                          as TextDeterminationProcedureItem,

      //    For Access control

      @Consumption.hidden: true
      SalesDocumentItemBasic.SalesDocumentType                                             as SalesContractType,
      @Consumption.hidden: true
      SalesDocumentItemBasic.OrganizationDivision,
      @Consumption.hidden: true
      SalesDocumentItemBasic.SalesOrganization,
      @Consumption.hidden: true
      SalesDocumentItemBasic.DistributionChannel,

      //     Exposed associations

      _Item,
      _SalesContract,
      _Language,
      _LongTextID
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_SALESDOCUMENTITEMBASIC",
"I_SALESDOCUMENTITEMCATEGORY",
"I_TEXTDETERMINATIONPROCEDITEM"
],
"ASSOCIATED":
[
"I_LANGUAGE",
"I_SDDOCUMENTITEMLONGTEXTID",
"R_SALESCONTRACTITEMTP",
"R_SALESCONTRACTTP"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/